git.gag.com Git - debian/amanda/blob - config/amanda/version.m4

   1 # Amanda version handling macros
   2
   3 AC_DEFUN([AMANDA_VERSION],
   4 [
   5     AMANDA_GET_SVN_INFO
   6     AMANDA_GET_GIT_INFO
   7
   8     if test -f FULL_VERSION; then
   9         VERSION=`cat FULL_VERSION`
  10     else if test -f $srcdir/FULL_VERSION; then
  11         VERSION=`cat $srcdir/FULL_VERSION`
  12     else
  13         VERSION=`cat $srcdir/VERSION`
  14     fi
  15     fi
  16     AC_MSG_NOTICE("version: $VERSION")
  17 ])
  18
  19 # SYNOPSIS
  20 #
  21 #   AMANDA_SNAPSHOT_STAMP
  22 #
  23 # DESCRIPTION
  24 #
  25 #   If srcdir contains a file named SNAPSHOT, with a line matching
  26 #       Snapshot Date: [0-9]*
  27 #   then set add the date to VERSION and set
  28 #   SNAPSHOT_STAMP=SNAPSHOT.
  29 #
  30 AC_DEFUN([AMANDA_SNAPSHOT_STAMP],
  31 [
  32     if test -f "$srcdir/SNAPSHOT"; then
  33       cat < "$srcdir/SNAPSHOT"
  34     changequote(,)
  35       snapdate=`sed -n '/^Snapshot Date: \([0-9]*\)/ s//\1/p' < $srcdir/SNAPSHOT`
  36     changequote([,])
  37       test -z "$snapdate" || VERSION="$VERSION-$snapdate"
  38       SNAPSHOT_STAMP=SNAPSHOT
  39     else
  40       SNAPSHOT_STAMP=
  41     fi
  42     AC_SUBST(SNAPSHOT_STAMP)
  43 ])
  44
  45 # SYNOPSIS
  46 #
  47 #   AMANDA_SPLIT_VERSION
  48 #
  49 # DESCRIPTION
  50 #
  51 #   Set the version number of this release of Amanda from the VERSION
  52 #   string, which is set in AM_INIT_AUTOMAKE.  Sets VERSION_MAJOR,
  53 #   VERSION_MINOR, VERSION_PATCH, and VERSION_COMMENT to the
  54 #   corresponding components of VERSION.  These four variables are
  55 #   also AC_DEFINE'd
  56 #
  57 AC_DEFUN([AMANDA_SPLIT_VERSION],
  58 [
  59     changequote(,)
  60     VERSION_MAJOR=`expr "$VERSION" : '\([0-9]*\)'`
  61     VERSION_MINOR=`expr "$VERSION" : '[0-9]*\.\([0-9]*\)'`
  62     if test -z "$VERSION_MINOR"; then
  63         VERSION_MINOR=0
  64         VERSION_PATCH=0
  65         VERSION_COMMENT=\"`expr "$VERSION" : '[0-9]*\(.*\)'`\"
  66     else
  67         VERSION_PATCH=`expr "$VERSION" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
  68         if test -z "$VERSION_PATCH"; then
  69             VERSION_PATCH=0
  70             VERSION_COMMENT=\"`expr "$VERSION" : '[0-9]*\.[0-9]*\(.*\)'`\"
  71         else
  72             VERSION_COMMENT=\"`expr "$VERSION" : '[0-9]*\.[0-9]*\.[0-9]*\(.*\)'`\"
  73         fi
  74     fi
  75     changequote([,])
  76
  77     AC_SUBST(VERSION_MAJOR)
  78     AC_SUBST(VERSION_MINOR)
  79     AC_SUBST(VERSION_PATCH)
  80     AC_SUBST(VERSION_COMMENT)
  81
  82     AC_DEFINE_UNQUOTED([VERSION_MAJOR], [$VERSION_MAJOR], [major Amanda version number])
  83     AC_DEFINE_UNQUOTED([VERSION_MINOR], [$VERSION_MINOR], [minor Amanda version number])
  84     AC_DEFINE_UNQUOTED([VERSION_PATCH], [$VERSION_PATCH], [Amanda patch number])
  85     AC_DEFINE_UNQUOTED([VERSION_COMMENT], [$VERSION_COMMENT], [Amanda version information beyond patch])
  86 ])
  87
  88 # SYNOPSIS
  89 #
  90 #   AMANDA_WITH_SUFFIXES
  91 #
  92 # DESCRIPTION
  93 #
  94 #   Deprectated --with-suffixes option.
  95 #
  96 AC_DEFUN([AMANDA_WITH_SUFFIXES],
  97 [
  98     AC_ARG_WITH(suffixes, [], [
  99         AMANDA_MSG_WARN([** --with-suffixes is deprecated])
 100     ])
 101 ])