git.gag.com Git - debian/amanda/blob - config/amanda/version.m4

   1 # Amanda version handling macros
   2
   3 # SYNOPSIS
   4 #
   5 #   AMANDA_INIT_VERSION
   6 #
   7 # DESCRIPTION
   8 #
   9 #   Create a macro, AMANDA_F_VERSION using only m4 which can expand
  10 #   legally before AC_INIT.  AC_INIT requires the version to be a
  11 #   string not a shell variable. Include FULL_VERSION if it exists, otherwise
  12 #   use VERSION.  -I dirs are searched for FULL_VERSION and VERSION.
  13 #
  14 AC_DEFUN([AMANDA_INIT_VERSION],
  15 [
  16     m4_syscmd([test -f FULL_VERSION])
  17     m4_if(m4_sysval, [0],
  18     [
  19         m4_define([AMANDA_F_VERSION], m4_chomp(m4_include([FULL_VERSION])))
  20     ],
  21     [
  22         m4_define([AMANDA_F_VERSION], m4_chomp(m4_include([VERSION])))
  23
  24     ])
  25     VERSION=AMANDA_F_VERSION
  26 ])
  27
  28 AC_DEFUN([AMANDA_VERSION],
  29 [
  30     AMANDA_GET_SVN_INFO
  31     AMANDA_GET_GIT_INFO
  32
  33     AC_MSG_NOTICE("version: $VERSION")
  34 ])
  35
  36 # SYNOPSIS
  37 #
  38 #   AMANDA_SNAPSHOT_STAMP
  39 #
  40 # DESCRIPTION
  41 #
  42 #   If srcdir contains a file named SNAPSHOT, with a line matching
  43 #       Snapshot Date: [0-9]*
  44 #   then set add the date to VERSION and set
  45 #   SNAPSHOT_STAMP=SNAPSHOT.
  46 #
  47 AC_DEFUN([AMANDA_SNAPSHOT_STAMP],
  48 [
  49     if test -f "$srcdir/SNAPSHOT"; then
  50       cat < "$srcdir/SNAPSHOT"
  51     changequote(,)
  52       snapdate=`sed -n '/^Snapshot Date: \([0-9]*\)/ s//\1/p' < $srcdir/SNAPSHOT`
  53     changequote([,])
  54       test -z "$snapdate" || VERSION="$VERSION-$snapdate"
  55       SNAPSHOT_STAMP=SNAPSHOT
  56     else
  57       SNAPSHOT_STAMP=
  58     fi
  59     AC_SUBST(SNAPSHOT_STAMP)
  60 ])
  61
  62 # SYNOPSIS
  63 #
  64 #   AMANDA_SPLIT_VERSION
  65 #
  66 # DESCRIPTION
  67 #
  68 #   Set the version number of this release of Amanda from the VERSION
  69 #   string, which is set in AC_INIT.  Sets VERSION_MAJOR,
  70 #   VERSION_MINOR, VERSION_PATCH, and VERSION_COMMENT to the
  71 #   corresponding components of VERSION.  These four variables are
  72 #   also AC_DEFINE'd
  73 #
  74 AC_DEFUN([AMANDA_SPLIT_VERSION],
  75 [
  76     changequote(,)
  77     VERSION_MAJOR=`expr "$VERSION" : '\([0-9]*\)'`
  78     VERSION_MINOR=`expr "$VERSION" : '[0-9]*\.\([0-9]*\)'`
  79     if test -z "$VERSION_MINOR"; then
  80         VERSION_MINOR=0
  81         VERSION_PATCH=0
  82         VERSION_COMMENT=\"`expr "$VERSION" : '[0-9]*\(.*\)'`\"
  83     else
  84         VERSION_PATCH=`expr "$VERSION" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
  85         if test -z "$VERSION_PATCH"; then
  86             VERSION_PATCH=0
  87             VERSION_COMMENT=\"`expr "$VERSION" : '[0-9]*\.[0-9]*\(.*\)'`\"
  88         else
  89             VERSION_COMMENT=\"`expr "$VERSION" : '[0-9]*\.[0-9]*\.[0-9]*\(.*\)'`\"
  90         fi
  91     fi
  92     changequote([,])
  93
  94     AC_SUBST(VERSION_MAJOR)
  95     AC_SUBST(VERSION_MINOR)
  96     AC_SUBST(VERSION_PATCH)
  97     AC_SUBST(VERSION_COMMENT)
  98
  99     AC_DEFINE_UNQUOTED([VERSION_MAJOR], [$VERSION_MAJOR], [major Amanda version number])
 100     AC_DEFINE_UNQUOTED([VERSION_MINOR], [$VERSION_MINOR], [minor Amanda version number])
 101     AC_DEFINE_UNQUOTED([VERSION_PATCH], [$VERSION_PATCH], [Amanda patch number])
 102     AC_DEFINE_UNQUOTED([VERSION_COMMENT], [$VERSION_COMMENT], [Amanda version information beyond patch])
 103 ])
 104
 105 # SYNOPSIS
 106 #
 107 #   AMANDA_WITH_SUFFIXES
 108 #
 109 # DESCRIPTION
 110 #
 111 #   Deprectated --with-suffixes option.
 112 #
 113 AC_DEFUN([AMANDA_WITH_SUFFIXES],
 114 [
 115     AC_ARG_WITH(suffixes, [], [
 116         AMANDA_MSG_WARN([** --with-suffixes is deprecated])
 117     ])
 118 ])