git.gag.com Git - debian/amanda/blob - config/amanda/summary.m4

   1 # OVERVIEW/BACKGROUND
   2 #
   3 #   This file creates an end-of-run summary of the Amanda configuration.
   4 #
   5
   6 # SYNOPSIS
   7 #
   8 #   AMANDA_INIT_SUMMARY()
   9 #
  10 # DESCRIPTION
  11 #
  12 #   Set up for producing a summary.  This should be called early in the configure
  13 #   process
  14 #
  15 AC_DEFUN([AMANDA_INIT_SUMMARY],
  16 [
  17     # initialize warnings file
  18     rm -f config.warnings
  19 ])
  20
  21 # SYNOPSIS
  22 #
  23 #   AMANDA_MSG_WARN()
  24 #
  25 # DESCRIPTION
  26 #
  27 #   Like AC_MSG_WARN, but also adds the message to the summary
  28 #
  29 AC_DEFUN([AMANDA_MSG_WARN], [
  30     AC_MSG_WARN([$1])
  31     AMANDA_ADD_WARNING([$1])
  32 ])
  33
  34 # SYNOPSIS
  35 #
  36 #   AMANDA_ADD_WARNING_QUOTED(warning-text) #if text already quoted
  37 #   AMANDA_ADD_WARNING(warning-text)        #if text not quoted
  38 #
  39 # DESCRIPTION
  40 #
  41 #   Add the given text to the warnings summary
  42 #
  43 AC_DEFUN([AMANDA_ADD_WARNING_QUOTED], [
  44     cat <<AAW_EOF >>config.warnings
  45 $1
  46 AAW_EOF])
  47
  48 AC_DEFUN([AMANDA_ADD_WARNING], [
  49 AMANDA_ADD_WARNING_QUOTED([_AS_QUOTE([$1])])
  50 ])
  51
  52 # SYNOPSIS
  53 #
  54 #   AMANDA_SHOW_SUMMARY()
  55 #
  56 # DESCRIPTION
  57 #
  58 #   Output the configuration summary.
  59 #
  60 AC_DEFUN([AMANDA_SHOW_SUMMARY], [
  61     AMANDA_SHOW_FLAGS_SUMMARY
  62     AMANDA_SHOW_COMPONENTS_SUMMARY
  63     AMANDA_SHOW_IPV6_SUMMARY
  64     AMANDA_SHOW_DOCUMENTATION_SUMMARY
  65     AMANDA_SHOW_DIRS_SUMMARY
  66     if test -f config.warnings; then
  67         echo "WARNINGS:"
  68         cat config.warnings | sed -e 's/^/  /g'
  69         rm config.warnings
  70     fi
  71 ])