git.gag.com Git - debian/amanda/blob - config/amanda/libs.m4

   1 # OVERVIEW
   2 #
   3 #   This file contains macros that search for specific libraries that are
   4 #   required or utilized by Amanda.
   5
   6 # SYNOPSIS
   7 #
   8 #   AMANDA_CHECK_LIBCURL
   9 #
  10 # OVERVIEW
  11 #
  12 #   Check for LIBCURL support.  Sets the shell variable HAVE_CURL to "yes" or
  13 #   "no" depending on the result of the test.  If CURL is found, the necessary
  14 #   compiler flags are added, and a few other type checks are performed.
  15 #
  16 #   Note that libcurl itself defines a number of useful symbols as well; see
  17 #   the libcurl distribution for details.
  18 #
  19 AC_DEFUN([AMANDA_CHECK_LIBCURL], [
  20     LIBCURL_CHECK_CONFIG(yes, 7.10.0, HAVE_CURL=yes, HAVE_CURL=no)
  21     if test x"$HAVE_CURL" = x"yes"; then
  22         AMANDA_ADD_LIBS($LIBCURL)
  23         AMANDA_ADD_CPPFLAGS($LIBCURL_CPPFLAGS)
  24
  25         AMANDA_CHECK_TYPE([curl_off_t], [off_t], [curl/curl.h])
  26         case "$host" in
  27             *sun-solaris2*) # Solaris, all versions.
  28             # we extract the -L flags and translate them to -R flags, as required
  29             # by the runtime linker.
  30             if test -n "$_libcurl_config"; then
  31                 curlflags=`$_libcurl_config --libs 2>/dev/null`
  32                 for flag in curlflags; do
  33                     case $flag in
  34                         -L*) LDFLAGS="$LDFLAGS "`echo "x$flag" | sed -e 's/^x-L/-R/'`;;
  35                     esac
  36                 done
  37             fi
  38             ;;
  39         esac
  40     fi
  41
  42 ])
  43
  44 # SYNOPSIS
  45 #
  46 #   AMANDA_CHECK_HMAC
  47 #
  48 # OVERVIEW
  49 #
  50 #   Check for HMAC support in -lcrypto.  If found, the shell
  51 #   variable HAVE_HMAC will be set to 'yes'.  The appropriate one of
  52 #   HAVE_OPENSSL_HMAC_H, HAVE_CRYPTO_HMAC_H, and HAVE_HMAC_H are also
  53 #   defined via AC_CHECK_HEADERS.
  54 #
  55 AC_DEFUN([AMANDA_CHECK_HMAC], [
  56     HAVE_HMAC=yes
  57     AC_CHECK_LIB([crypto], [HMAC_CTX_init], [], [HAVE_HMAC=no])
  58
  59     found_hmac_h=no
  60     AC_CHECK_HEADERS([openssl/hmac.h crypto/hmac.h hmac.h],
  61                     [found_hmac_h=yes; break])
  62     if test x"$found_hmac_h" != x"yes"; then
  63         HAVE_HMAC=no
  64     fi
  65 ])
  66
  67 # SYNOPSIS
  68 #
  69 #   AMANDA_CHECK_NET_LIBS
  70 #
  71 # OVERIVEW
  72 #
  73 #   Check for the libraries we'll need to use sockets, etc.
  74 #
  75 AC_DEFUN([AMANDA_CHECK_NET_LIBS], [
  76     # Make sure we don't use -lnsl and -lsun on Irix systems.
  77     case "$host" in
  78         *sgi-irix*)
  79                             AC_CHECK_LIB(socket,main)
  80                             ;;
  81         *)
  82                             AC_CHECK_LIB(resolv,main)
  83                             AC_CHECK_LIB(nsl,main)
  84                             AC_CHECK_LIB(socket,main)
  85                             AC_CHECK_LIB(sun,main)
  86                             ;;
  87     esac
  88 ])
  89
  90 # SYNOPSIS
  91 #
  92 #   AMANDA_CHECK_GLIB
  93 #
  94 # OVERVIEW
  95 #
  96 #   Search for glib.  This is basically a wrapper for AM_PATH_GLIB_2_0, with
  97 #   the addition of system-specific configuration to convince Amanda to compile
  98 #   "out of the box" on more boxes.
  99 #
 100 AC_DEFUN([AMANDA_CHECK_GLIB], [
 101     AC_ARG_VAR(GLIB_CFLAGS, [CFLAGS to build with glib; disables use of pkg-config; must specify all GLIB_ vars])
 102     AC_ARG_VAR(GLIB_LIBS, [libraries to build with glib; disables use of pkg-config; must specify all GLIB_vars])
 103     AC_ARG_VAR(GLIB_GENMARSHAL, [genmarshal binary to use with glib; disables use of pkg-config; must specify all GLIB_ vars])
 104     AC_ARG_VAR(GOBJECT_QUERY, [gobject_query binary to use with glib; disables use of pkg-config; must specify all GLIB_ vars])
 105     AC_ARG_VAR(GLIB_MKENUMS, [mkenums binary to use with glib; disables use of pkg-config; must specify all GLIB_ vars])
 106
 107     # if any of the precious variables are set, disable the pkg-config run.
 108     # Further, if any is specified, all must be specified.
 109     explicit_glib=no
 110     test x"$GLIB_CFLAGS" = x"" || explicit_glib=yes
 111     test x"$GLIB_LIBS" = x"" || explicit_glib=yes
 112     test x"$GLIB_GENMARSHAL" = x"" || explicit_glib=yes
 113     test x"$GOBJECT_QUERY" = x"" || explicit_glib=yes
 114     test x"$GLIB_MKENUMS" = x"" || explicit_glib=yes
 115
 116     if test x"$explicit_glib" = x"no"; then
 117         # search for pkg-config, which the glib configuration uses, adding a few
 118         # system-specific search paths.
 119         AC_PATH_PROG(PKG_CONFIG, pkg-config, [], $LOCSYSPATH:/opt/csw/bin:/usr/local/bin:/opt/local/bin)
 120
 121         case "$host" in
 122             sparc-sun-solaris2.8) # Solaris 8
 123                 # give the linker a runtime search path; pkg-config doesn't supply this.
 124                 # Users could also specify this with LD_LIBRARY_PATH to both ./configure
 125                 # and make.  Adding this support here makes straight './configure; make'
 126                 # "just work" on Solaris 8
 127                 if test -n "$PKG_CONFIG"; then
 128                     glib_R_flag=`$PKG_CONFIG glib-2.0 --libs-only-L 2>/dev/null | sed -e 's/-L/-R/g'`
 129                     LDFLAGS="$LDFLAGS $glib_R_flag"
 130                 fi
 131                 ;;
 132         esac
 133
 134         AM_PATH_GLIB_2_0(2.2.0,,[
 135             AC_MSG_ERROR(glib not found or too old; See http://wiki.zmanda.com/index.php/Installation for help)
 136         ], gmodule gobject gthread)
 137     else
 138         # Confirm that all GLIB_ variables are set
 139         if test ! x"$GLIB_CFLAGS" = x"" && \
 140            test ! x"$GLIB_LIBS" = x"" && \
 141            test ! x"$GLIB_GENMARSHAL" = x"" && \
 142            test ! x"$GOBJECT_QUERY" = x"" && \
 143            test ! x"$GLIB_MKENUMS" = x""; then
 144             :
 145         else
 146             AC_MSG_ERROR(Not all precious glib variables were set.)
 147         fi
 148     fi
 149
 150     # GLIB_CPPFLAGS is not set by autoconf, yet GLIB_CFLAGS contains what GLIB_CPPFLAGS should contain.
 151     AMANDA_ADD_CPPFLAGS($GLIB_CFLAGS)
 152     AMANDA_ADD_LIBS($GLIB_LIBS)
 153 ])
 154
 155 # LIBCURL_CHECK_CONFIG is from the libcurl
 156 # distribution and licensed under the BSD license:
 157 # Copyright (c) 1996 - 2007, Daniel Stenberg, <daniel@haxx.se>.
 158 #
 159 # All rights reserved.
 160 #
 161 # Permission to use, copy, modify, and distribute this software for any purpose
 162 # with or without fee is hereby granted, provided that the above copyright
 163 # notice and this permission notice appear in all copies.
 164 #
 165 # LIBCURL_CHECK_CONFIG ([DEFAULT-ACTION], [MINIMUM-VERSION],
 166 #                       [ACTION-IF-YES], [ACTION-IF-NO])
 167 # ----------------------------------------------------------
 168 #      David Shaw <dshaw@jabberwocky.com>   May-09-2006
 169 #
 170 # Checks for libcurl.  DEFAULT-ACTION is the string yes or no to
 171 # specify whether to default to --with-libcurl or --without-libcurl.
 172 # If not supplied, DEFAULT-ACTION is yes.  MINIMUM-VERSION is the
 173 # minimum version of libcurl to accept.  Pass the version as a regular
 174 # version number like 7.10.1. If not supplied, any version is
 175 # accepted.  ACTION-IF-YES is a list of shell commands to run if
 176 # libcurl was successfully found and passed the various tests.
 177 # ACTION-IF-NO is a list of shell commands that are run otherwise.
 178 # Note that using --without-libcurl does run ACTION-IF-NO.
 179 #
 180 # This macro #defines HAVE_LIBCURL if a working libcurl setup is
 181 # found, and sets @LIBCURL@ and @LIBCURL_CPPFLAGS@ to the necessary
 182 # values.  Other useful defines are LIBCURL_FEATURE_xxx where xxx are
 183 # the various features supported by libcurl, and LIBCURL_PROTOCOL_yyy
 184 # where yyy are the various protocols supported by libcurl.  Both xxx
 185 # and yyy are capitalized.  See the list of AH_TEMPLATEs at the top of
 186 # the macro for the complete list of possible defines.  Shell
 187 # variables $libcurl_feature_xxx and $libcurl_protocol_yyy are also
 188 # defined to 'yes' for those features and protocols that were found.
 189 # Note that xxx and yyy keep the same capitalization as in the
 190 # curl-config list (e.g. it's "HTTP" and not "http").
 191 #
 192 # Users may override the detected values by doing something like:
 193 # LIBCURL="-lcurl" LIBCURL_CPPFLAGS="-I/usr/myinclude" ./configure
 194 #
 195 # For the sake of sanity, this macro assumes that any libcurl that is
 196 # found is after version 7.7.2, the first version that included the
 197 # curl-config script.  Note that it is very important for people
 198 # packaging binary versions of libcurl to include this script!
 199 # Without curl-config, we can only guess what protocols are available,
 200 # or use curl_version_info to figure it out at runtime.
 201
 202 AC_DEFUN([LIBCURL_CHECK_CONFIG],
 203 [
 204   AH_TEMPLATE([LIBCURL_FEATURE_SSL],[Defined if libcurl supports SSL])
 205   AH_TEMPLATE([LIBCURL_FEATURE_KRB4],[Defined if libcurl supports KRB4])
 206   AH_TEMPLATE([LIBCURL_FEATURE_IPV6],[Defined if libcurl supports IPv6])
 207   AH_TEMPLATE([LIBCURL_FEATURE_LIBZ],[Defined if libcurl supports libz])
 208   AH_TEMPLATE([LIBCURL_FEATURE_ASYNCHDNS],[Defined if libcurl supports AsynchDNS])
 209   AH_TEMPLATE([LIBCURL_FEATURE_IDN],[Defined if libcurl supports IDN])
 210   AH_TEMPLATE([LIBCURL_FEATURE_SSPI],[Defined if libcurl supports SSPI])
 211   AH_TEMPLATE([LIBCURL_FEATURE_NTLM],[Defined if libcurl supports NTLM])
 212
 213   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTP],[Defined if libcurl supports HTTP])
 214   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTPS],[Defined if libcurl supports HTTPS])
 215   AH_TEMPLATE([LIBCURL_PROTOCOL_FTP],[Defined if libcurl supports FTP])
 216   AH_TEMPLATE([LIBCURL_PROTOCOL_FTPS],[Defined if libcurl supports FTPS])
 217   AH_TEMPLATE([LIBCURL_PROTOCOL_FILE],[Defined if libcurl supports FILE])
 218   AH_TEMPLATE([LIBCURL_PROTOCOL_TELNET],[Defined if libcurl supports TELNET])
 219   AH_TEMPLATE([LIBCURL_PROTOCOL_LDAP],[Defined if libcurl supports LDAP])
 220   AH_TEMPLATE([LIBCURL_PROTOCOL_DICT],[Defined if libcurl supports DICT])
 221   AH_TEMPLATE([LIBCURL_PROTOCOL_TFTP],[Defined if libcurl supports TFTP])
 222
 223   AC_ARG_WITH(libcurl,
 224      AC_HELP_STRING([--with-libcurl=PREFIX],
 225         [look for the curl library in PREFIX/lib and headers in PREFIX/include]),
 226      [_libcurl_with=$withval],[_libcurl_with=ifelse([$1],,[yes],[$1])])
 227
 228   if test "$_libcurl_with" != "no" ; then
 229
 230      AC_PROG_AWK
 231
 232      _libcurl_version_parse="eval $AWK '{split(\$NF,A,\".\"); X=256*256*A[[1]]+256*A[[2]]+A[[3]]; print X;}'"
 233
 234      _libcurl_try_link=yes
 235
 236      if test -d "$_libcurl_with" ; then
 237         LIBCURL_CPPFLAGS="-I$withval/include"
 238         _libcurl_ldflags="-L$withval/lib"
 239         AC_PATH_PROG([_libcurl_config],[curl-config],[],["$withval/bin"])
 240      else
 241         AC_PATH_PROG([_libcurl_config],[curl-config],[],[$PATH])
 242      fi
 243
 244      if test x$_libcurl_config != "x" ; then
 245         AC_CACHE_CHECK([for the version of libcurl],
 246            [libcurl_cv_lib_curl_version],
 247            [libcurl_cv_lib_curl_version=`$_libcurl_config --version | $AWK '{print $[]2}'`])
 248
 249         _libcurl_version=`echo $libcurl_cv_lib_curl_version | $_libcurl_version_parse`
 250         _libcurl_wanted=`echo ifelse([$2],,[0],[$2]) | $_libcurl_version_parse`
 251
 252         if test $_libcurl_wanted -gt 0 ; then
 253            AC_CACHE_CHECK([for libcurl >= version $2],
 254               [libcurl_cv_lib_version_ok],
 255               [
 256               if test $_libcurl_version -ge $_libcurl_wanted ; then
 257                  libcurl_cv_lib_version_ok=yes
 258               else
 259                  libcurl_cv_lib_version_ok=no
 260               fi
 261               ])
 262         fi
 263
 264         if test $_libcurl_wanted -eq 0 || test x$libcurl_cv_lib_version_ok = xyes ; then
 265            if test x"$LIBCURL_CPPFLAGS" = "x" ; then
 266               LIBCURL_CPPFLAGS=`$_libcurl_config --cflags`
 267            fi
 268            if test x"$LIBCURL" = "x" ; then
 269               LIBCURL=`$_libcurl_config --libs`
 270
 271               # This is so silly, but Apple actually has a bug in their
 272               # curl-config script.  Fixed in Tiger, but there are still
 273               # lots of Panther installs around.
 274               case "${host}" in
 275                  powerpc-apple-darwin7*)
 276                     LIBCURL=`echo $LIBCURL | sed -e 's|-arch i386||g'`
 277                  ;;
 278               esac
 279            fi
 280
 281            # All curl-config scripts support --feature
 282            _libcurl_features=`$_libcurl_config --feature`
 283
 284            # Is it modern enough to have --protocols? (7.12.4)
 285            if test $_libcurl_version -ge 461828 ; then
 286               _libcurl_protocols=`$_libcurl_config --protocols`
 287            fi
 288         else
 289            _libcurl_try_link=no
 290         fi
 291
 292         unset _libcurl_wanted
 293      fi
 294
 295      if test $_libcurl_try_link = yes ; then
 296
 297         # we didn't find curl-config, so let's see if the user-supplied
 298         # link line (or failing that, "-lcurl") is enough.
 299         LIBCURL=${LIBCURL-"$_libcurl_ldflags -lcurl"}
 300
 301         AC_CACHE_CHECK([whether libcurl is usable],
 302            [libcurl_cv_lib_curl_usable],
 303            [
 304            _libcurl_save_cppflags=$CPPFLAGS
 305            CPPFLAGS="$LIBCURL_CPPFLAGS $CPPFLAGS"
 306            _libcurl_save_libs=$LIBS
 307            LIBS="$LIBCURL $LIBS"
 308
 309            AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <curl/curl.h>]],[[
 310 /* Try and use a few common options to force a failure if we are
 311    missing symbols or can't link. */
 312 int x;
 313 curl_easy_setopt(NULL,CURLOPT_URL,NULL);
 314 x=CURL_ERROR_SIZE;
 315 x=CURLOPT_WRITEFUNCTION;
 316 x=CURLOPT_FILE;
 317 x=CURLOPT_ERRORBUFFER;
 318 x=CURLOPT_STDERR;
 319 x=CURLOPT_VERBOSE;
 320 ]])],[libcurl_cv_lib_curl_usable=yes],[libcurl_cv_lib_curl_usable=no])
 321
 322            CPPFLAGS=$_libcurl_save_cppflags
 323            LIBS=$_libcurl_save_libs
 324            unset _libcurl_save_cppflags
 325            unset _libcurl_save_libs
 326            ])
 327
 328         if test $libcurl_cv_lib_curl_usable = yes ; then
 329
 330            # Does curl_free() exist in this version of libcurl?
 331            # If not, fake it with free()
 332
 333            _libcurl_save_cppflags=$CPPFLAGS
 334            CPPFLAGS="$CPPFLAGS $LIBCURL_CPPFLAGS"
 335            _libcurl_save_libs=$LIBS
 336            LIBS="$LIBS $LIBCURL"
 337
 338            AC_CHECK_FUNC(curl_free,,
 339               AC_DEFINE(curl_free,free,
 340                 [Define curl_free() as free() if our version of curl lacks curl_free.]))
 341
 342            CPPFLAGS=$_libcurl_save_cppflags
 343            LIBS=$_libcurl_save_libs
 344            unset _libcurl_save_cppflags
 345            unset _libcurl_save_libs
 346
 347            AC_DEFINE(HAVE_LIBCURL,1,
 348              [Define to 1 if you have a functional curl library.])
 349            AC_SUBST(LIBCURL_CPPFLAGS)
 350            AC_SUBST(LIBCURL)
 351
 352            for _libcurl_feature in $_libcurl_features ; do
 353               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_feature_$_libcurl_feature),[1])
 354               eval AS_TR_SH(libcurl_feature_$_libcurl_feature)=yes
 355            done
 356
 357            if test "x$_libcurl_protocols" = "x" ; then
 358
 359               # We don't have --protocols, so just assume that all
 360               # protocols are available
 361               _libcurl_protocols="HTTP FTP FILE TELNET LDAP DICT"
 362
 363               if test x$libcurl_feature_SSL = xyes ; then
 364                  _libcurl_protocols="$_libcurl_protocols HTTPS"
 365
 366                  # FTPS wasn't standards-compliant until version
 367                  # 7.11.0
 368                  if test $_libcurl_version -ge 461568; then
 369                     _libcurl_protocols="$_libcurl_protocols FTPS"
 370                  fi
 371               fi
 372            fi
 373
 374            for _libcurl_protocol in $_libcurl_protocols ; do
 375               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_protocol_$_libcurl_protocol),[1])
 376               eval AS_TR_SH(libcurl_protocol_$_libcurl_protocol)=yes
 377            done
 378         else
 379            unset LIBCURL
 380            unset LIBCURL_CPPFLAGS
 381         fi
 382      fi
 383
 384      unset _libcurl_try_link
 385      unset _libcurl_version_parse
 386      unset _libcurl_config
 387      unset _libcurl_feature
 388      unset _libcurl_features
 389      unset _libcurl_protocol
 390      unset _libcurl_protocols
 391      unset _libcurl_version
 392      unset _libcurl_ldflags
 393   fi
 394
 395   if test x$_libcurl_with = xno || test x$libcurl_cv_lib_curl_usable != xyes ; then
 396      # This is the IF-NO path
 397      ifelse([$4],,:,[$4])
 398   else
 399      # This is the IF-YES path
 400      ifelse([$3],,:,[$3])
 401   fi
 402
 403   unset _libcurl_with
 404 ])dnl
 405