git.gag.com Git - debian/amanda/blob - config/amanda/compress.m4

   1 # SYNOPSIS
   2 #
   3 #   AMANDA_CHECK_COMPRESSION
   4 #
   5 # OVERVIEW
   6 #
   7 #   Find a suitable compression program and substitute and define the following:
   8 #
   9 #    - COMPRESS_PATH
  10 #    - COMPRESS_SUFFIX
  11 #    - COMPRESS_FAST_OPT
  12 #    - COMPRESS_BEST_OPT
  13 #    - UNCOMPRESS_PATH
  14 #    - UNCOMPRESS_OPT
  15 #    - HAVE_GZIP
  16 #
  17 AC_DEFUN([AMANDA_CHECK_COMPRESSION],
  18 [
  19     AC_REQUIRE([AMANDA_PROG_CAT])
  20     AC_REQUIRE([AMANDA_PROG_COMPRESS])
  21     AC_REQUIRE([AMANDA_PROG_GZIP])
  22
  23     HAVE_GZIP=
  24     if test "$GZIP"; then
  25         AC_DEFINE(HAVE_GZIP,1,
  26             [Define if Amanda is using the gzip program. ])
  27         HAVE_GZIP=1
  28         COMPRESS_PATH="$GZIP"
  29         COMPRESS_SUFFIX=".gz"
  30         COMPRESS_FAST_OPT="--fast"
  31         COMPRESS_BEST_OPT="--best"
  32         UNCOMPRESS_PATH="$GZIP"
  33         UNCOMPRESS_OPT="-dc"
  34     else
  35         if test "$COMPRESS"; then
  36             COMPRESS_PATH="$COMPRESS"
  37             COMPRESS_SUFFIX=".Z"
  38             COMPRESS_FAST_OPT="-f"
  39             COMPRESS_BEST_OPT="-f"
  40             UNCOMPRESS_PATH="$COMPRESS"
  41             UNCOMPRESS_OPT="-dc"
  42         else
  43             # If we have to use cat, we don't define COMPRESS_FAST_OPT,
  44             # COMPRESS_BEST_OPT, or UNCOMPRESS_OPT as "" since cat will look
  45             # look for a file by the name of "".
  46             # XXX is the above true? --dustin
  47
  48             AMANDA_MSG_WARN([Cannot find either gzip or compress.  Using cat.])
  49             COMPRESS_PATH="$CAT"
  50             COMPRESS_SUFFIX=""
  51             COMPRESS_FAST_OPT=""
  52             COMPRESS_BEST_OPT=""
  53             UNCOMPRESS_PATH="$CAT"
  54             UNCOMPRESS_OPT=""
  55         fi
  56     fi
  57
  58     AC_DEFINE_UNQUOTED(COMPRESS_PATH,"$COMPRESS_PATH",
  59         [Define to the exact path to the gzip or the compress program. ])
  60     AC_DEFINE_UNQUOTED(COMPRESS_SUFFIX,"$COMPRESS_SUFFIX",
  61         [Define to the suffix for the COMPRESS_PATH compression program. ])
  62     AC_DEFINE_UNQUOTED(COMPRESS_FAST_OPT,"$COMPRESS_FAST_OPT",
  63         [Define as the command line option for fast compression. ])
  64     AC_DEFINE_UNQUOTED(COMPRESS_BEST_OPT,"$COMPRESS_BEST_OPT",
  65         [Define as the command line option for best compression. ])
  66     AC_DEFINE_UNQUOTED(UNCOMPRESS_PATH,"$UNCOMPRESS_PATH",
  67         [Define as the exact path to the gzip or compress command. ])
  68     AC_DEFINE_UNQUOTED(UNCOMPRESS_OPT,"$UNCOMPRESS_OPT",
  69         [Define as any optional arguments to get UNCOMPRESS_PATH to uncompress. ])
  70
  71     AC_SUBST(COMPRESS_PATH)
  72     AC_SUBST(COMPRESS_SUFFIX)
  73     AC_SUBST(COMPRESS_FAST_OPT)
  74     AC_SUBST(COMPRESS_BEST_OPT)
  75     AC_SUBST(UNCOMPRESS_PATH)
  76     AC_SUBST(UNCOMPRESS_OPT)
  77     AC_SUBST(HAVE_GZIP)
  78
  79     # Empty GZIP so that make dist works.
  80     GZIP=
  81 ])