git.gag.com Git - debian/amanda/blob - config/amanda/compress.m4

   1 # SYNOPSIS
   2 #
   3 #   AMANDA_CHECK_COMPRESSION
   4 #
   5 # OVERVIEW
   6 #
   7 #   Find a suitable compression program and define the following:
   8 #
   9 #    - COMPRESS_PATH
  10 #    - COMPRESS_SUFFIX
  11 #    - COMPRESS_FAST_OPT
  12 #    - COMPRESS_BEST_OPT
  13 #    - UNCOMPRESS_PATH
  14 #    - UNCOMPRESS_OPT
  15 #    - HAVE_GZIP
  16 #
  17 AC_DEFUN([AMANDA_CHECK_COMPRESSION],
  18 [
  19     AC_REQUIRE([AMANDA_PROG_CAT])
  20     AC_REQUIRE([AMANDA_PROG_COMPRESS])
  21     AC_REQUIRE([AMANDA_PROG_GZIP])
  22
  23     if test "$GZIP"; then
  24         AC_DEFINE(HAVE_GZIP,1,
  25             [Define if Amanda is using the gzip program. ])
  26         COMPRESS_PATH="$GZIP"
  27         COMPRESS_SUFFIX=".gz"
  28         COMPRESS_FAST_OPT="--fast"
  29         COMPRESS_BEST_OPT="--best"
  30         UNCOMPRESS_PATH="$GZIP"
  31         UNCOMPRESS_OPT="-dc"
  32     else
  33         if test "$COMPRESS"; then
  34             COMPRESS_PATH="$COMPRESS"
  35             COMPRESS_SUFFIX=".Z"
  36             COMPRESS_FAST_OPT="-f"
  37             COMPRESS_BEST_OPT="-f"
  38             UNCOMPRESS_PATH="$COMPRESS"
  39             UNCOMPRESS_OPT="-dc"
  40         else
  41             # If we have to use cat, we don't define COMPRESS_FAST_OPT,
  42             # COMPRESS_BEST_OPT, or UNCOMPRESS_OPT as "" since cat will look
  43             # look for a file by the name of "".
  44             # XXX is the above true? --dustin
  45
  46             AMANDA_MSG_WARN([Cannot find either gzip or compress.  Using cat.])
  47             COMPRESS_PATH="$CAT"
  48             COMPRESS_SUFFIX=""
  49             COMPRESS_FAST_OPT=""
  50             COMPRESS_BEST_OPT=""
  51             UNCOMPRESS_PATH="$CAT"
  52             UNCOMPRESS_OPT=""
  53         fi
  54     fi
  55
  56     AC_DEFINE_UNQUOTED(COMPRESS_PATH,"$COMPRESS_PATH",
  57         [Define to the exact path to the gzip or the compress program. ])
  58     AC_DEFINE_UNQUOTED(COMPRESS_SUFFIX,"$COMPRESS_SUFFIX",
  59         [Define to the suffix for the COMPRESS_PATH compression program. ])
  60     AC_DEFINE_UNQUOTED(COMPRESS_FAST_OPT,"$COMPRESS_FAST_OPT",
  61         [Define as the command line option for fast compression. ])
  62     AC_DEFINE_UNQUOTED(COMPRESS_BEST_OPT,"$COMPRESS_BEST_OPT",
  63         [Define as the command line option for best compression. ])
  64     AC_DEFINE_UNQUOTED(UNCOMPRESS_PATH,"$UNCOMPRESS_PATH",
  65         [Define as the exact path to the gzip or compress command. ])
  66     AC_DEFINE_UNQUOTED(UNCOMPRESS_OPT,"$UNCOMPRESS_OPT",
  67         [Define as any optional arguments to get UNCOMPRESS_PATH to uncompress. ])
  68
  69     # Empty GZIP so that make dist works.
  70     GZIP=
  71 ])