git.gag.com Git - fw/altos/blob - configure.ac

   1 dnl
   2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
   3 dnl
   4 dnl  This program is free software; you can redistribute it and/or modify
   5 dnl  it under the terms of the GNU General Public License as published by
   6 dnl  the Free Software Foundation; either version 2 of the License, or
   7 dnl  (at your option) any later version.
   8 dnl
   9 dnl  This program is distributed in the hope that it will be useful, but
  10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 dnl  General Public License for more details.
  13 dnl
  14 dnl  You should have received a copy of the GNU General Public License along
  15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
  16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17 dnl
  18 dnl Process this file with autoconf to create configure.
  19
  20 AC_PREREQ(2.57)
  21 AC_INIT([altos], 1.0.9.4)
  22 AC_CONFIG_SRCDIR([src/core/ao.h])
  23 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  24 AM_MAINTAINER_MODE
  25
  26 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
  27 AC_SUBST(VERSION_DASH)
  28
  29 dnl ==========================================================================
  30
  31 AM_CONFIG_HEADER(config.h)
  32
  33 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
  34         [Set freetts class path (default /usr/share/java)]),
  35         [FREETTS=$withval], [FREETTS=/usr/share/java])
  36
  37 AC_SUBST(FREETTS)
  38
  39 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
  40         [Set jfreechart class path (default /usr/share/java)]),
  41         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
  42
  43 AC_SUBST(JFREECHART)
  44
  45 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
  46         [Set jcommon class path (default /usr/share/java)]),
  47         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
  48
  49 AC_SUBST(JCOMMON)
  50
  51 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm-include=PATH],
  52         [Set jvm include path for jni builds (default searches in /usr/lib/jvm)]),
  53         [JVM_INCLUDE=$withval], [JVM_INCLUDE=auto])
  54
  55 if test "x$JVM_INCLUDE" = "xauto"; then
  56         AC_MSG_CHECKING([JVM include files])
  57         for jvm in default-java java-6-openjdk java-6-sun; do
  58                 if test "x$JVM_INCLUDE" = "xauto"; then
  59                         INCLUDE="/usr/lib/jvm/$jvm/include"
  60                         if test -f "$INCLUDE"/jni.h; then
  61                                 JVM_INCLUDE="$INCLUDE"
  62                         fi
  63                 fi
  64         done
  65         if test "x$JVM_INCLUDE" = "xauto"; then
  66                 AC_MSG_ERROR([no JVM include files found])
  67         fi
  68         AC_MSG_RESULT([$JVM_INCLUDE])
  69 fi
  70
  71 AC_SUBST(JVM_INCLUDE)
  72
  73 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
  74             [Set the directory to install the 'fat' distribution files to (defaults to not installing)]),
  75             [FATDIR=$withval], [FATDIR=none])
  76
  77 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
  78
  79 AC_SUBST(FATDIR)
  80
  81 AC_PROG_CC
  82 AC_PROG_INSTALL
  83 AC_PROG_LN_S
  84 AC_PROG_LIBTOOL
  85 PKG_PROG_PKG_CONFIG
  86
  87 CFLAGS="-g"
  88 WARN_CFLAGS=""
  89 if test "x$GCC" = "xyes"; then
  90         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
  91         -Wmissing-prototypes -Wmissing-declarations \
  92         -Wnested-externs -fno-strict-aliasing"
  93         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
  94         [Can use #warning in C files])
  95 fi
  96 AC_SUBST(WARN_CFLAGS)
  97
  98 AC_CHECK_PROG([HAVE_SDCC], [sdcc], yes, no)
  99 if test "x$HAVE_SDCC" = "xno"; then
 100         AC_MSG_ERROR([Please install sdcc to build AltOs])
 101 fi
 102
 103 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
 104 if test "x$HAVE_NICKLE" = "xno"; then
 105         AC_MSG_ERROR([Please install nickle to build AltOs])
 106 fi
 107
 108 AC_CHECK_LIB(readline, readline)
 109
 110 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
 111
 112 AC_OUTPUT([
 113 Makefile
 114 altosui/Makefile
 115 altosui/AltosVersion.java
 116 altosui/libaltos/Makefile
 117 ao-tools/Makefile
 118 ao-tools/lib/Makefile
 119 ao-tools/ao-rawload/Makefile
 120 ao-tools/ao-dbg/Makefile
 121 ao-tools/ao-bitbang/Makefile
 122 ao-tools/ao-eeprom/Makefile
 123 ao-tools/ao-list/Makefile
 124 ao-tools/ao-load/Makefile
 125 ao-tools/ao-telem/Makefile
 126 ao-utils/Makefile
 127 src/Version
 128 ])