git.gag.com Git - debian/tar/blob - m4/wcwidth.m4

   1 # wcwidth.m4 serial 18
   2 dnl Copyright (C) 2006-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_WCWIDTH],
   8 [
   9   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  11
  12   dnl Persuade glibc <wchar.h> to declare wcwidth().
  13   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  14
  15   AC_REQUIRE([gt_TYPE_WCHAR_T])
  16   AC_REQUIRE([gt_TYPE_WINT_T])
  17
  18   AC_CHECK_HEADERS_ONCE([wchar.h])
  19   AC_CHECK_FUNCS_ONCE([wcwidth])
  20
  21   AC_CHECK_DECLS([wcwidth], [], [], [
  22 /* AIX 3.2.5 declares wcwidth in <string.h>. */
  23 #include <string.h>
  24 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
  25    <wchar.h>.
  26    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
  27    before <wchar.h>.  */
  28 #include <stddef.h>
  29 #include <stdio.h>
  30 #include <time.h>
  31 #include <wchar.h>
  32 ])
  33   if test $ac_cv_have_decl_wcwidth != yes; then
  34     HAVE_DECL_WCWIDTH=0
  35   fi
  36
  37   if test $ac_cv_func_wcwidth = yes; then
  38     dnl On MacOS X 10.3, wcwidth(0x0301) (COMBINING ACUTE ACCENT) returns 1.
  39     dnl On OSF/1 5.1, wcwidth(0x200B) (ZERO WIDTH SPACE) returns 1.
  40     dnl This leads to bugs in 'ls' (coreutils).
  41     AC_CACHE_CHECK([whether wcwidth works reasonably in UTF-8 locales],
  42       [gl_cv_func_wcwidth_works],
  43       [
  44         AC_RUN_IFELSE(
  45           [AC_LANG_SOURCE([[
  46 #include <locale.h>
  47 /* AIX 3.2.5 declares wcwidth in <string.h>. */
  48 #include <string.h>
  49 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
  50    <wchar.h>.
  51    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
  52    before <wchar.h>.  */
  53 #include <stddef.h>
  54 #include <stdio.h>
  55 #include <time.h>
  56 #include <wchar.h>
  57 #if !HAVE_DECL_WCWIDTH
  58 extern
  59 # ifdef __cplusplus
  60 "C"
  61 # endif
  62 int wcwidth (int);
  63 #endif
  64 int main ()
  65 {
  66   int result = 0;
  67   if (setlocale (LC_ALL, "fr_FR.UTF-8") != NULL)
  68     {
  69       if (wcwidth (0x0301) > 0)
  70         result |= 1;
  71       if (wcwidth (0x200B) > 0)
  72         result |= 2;
  73     }
  74   return result;
  75 }]])],
  76           [gl_cv_func_wcwidth_works=yes],
  77           [gl_cv_func_wcwidth_works=no],
  78           [
  79 changequote(,)dnl
  80            case "$host_os" in
  81                      # Guess yes on glibc and AIX 7 systems.
  82              *-gnu* | aix[7-9]*) gl_cv_func_wcwidth_works="guessing yes";;
  83              *)                  gl_cv_func_wcwidth_works="guessing no";;
  84            esac
  85 changequote([,])dnl
  86           ])
  87       ])
  88     case "$gl_cv_func_wcwidth_works" in
  89       *yes) ;;
  90       *no) REPLACE_WCWIDTH=1 ;;
  91     esac
  92   fi
  93   if test $ac_cv_func_wcwidth != yes || test $REPLACE_WCWIDTH = 1; then
  94     AC_LIBOBJ([wcwidth])
  95   fi
  96   if test $ac_cv_func_wcwidth != yes || test $REPLACE_WCWIDTH = 1 \
  97      || test $HAVE_DECL_WCWIDTH = 0; then
  98     gl_REPLACE_WCHAR_H
  99   fi
 100   dnl We don't substitute HAVE_WCWIDTH. We assume that if the system does not
 101   dnl have the wcwidth function, then it does not declare it.
 102 ])