git.gag.com Git - debian/tar/blob - m4/locale-zh.m4

   1 # locale-zh.m4 serial 12
   2 dnl Copyright (C) 2003, 2005-2015 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 dnl Determine the name of a chinese locale with GB18030 encoding.
  10 AC_DEFUN([gt_LOCALE_ZH_CN],
  11 [
  12   AC_REQUIRE([AC_CANONICAL_HOST])
  13   AC_REQUIRE([AM_LANGINFO_CODESET])
  14   AC_CACHE_CHECK([for a transitional chinese locale], [gt_cv_locale_zh_CN], [
  15     AC_LANG_CONFTEST([AC_LANG_SOURCE([
  16 changequote(,)dnl
  17 #include <locale.h>
  18 #include <stdlib.h>
  19 #include <time.h>
  20 #if HAVE_LANGINFO_CODESET
  21 # include <langinfo.h>
  22 #endif
  23 #include <stdlib.h>
  24 #include <string.h>
  25 struct tm t;
  26 char buf[16];
  27 int main ()
  28 {
  29   const char *p;
  30   /* Check whether the given locale name is recognized by the system.  */
  31 #if (defined _WIN32 || defined __WIN32__) && !defined __CYGWIN__
  32   /* On native Windows, setlocale(category, "") looks at the system settings,
  33      not at the environment variables.  Also, when an encoding suffix such
  34      as ".65001" or ".54936" is specified, it succeeds but sets the LC_CTYPE
  35      category of the locale to "C".  */
  36   if (setlocale (LC_ALL, getenv ("LC_ALL")) == NULL
  37       || strcmp (setlocale (LC_CTYPE, NULL), "C") == 0)
  38     return 1;
  39 #else
  40   if (setlocale (LC_ALL, "") == NULL) return 1;
  41 #endif
  42   /* Check whether nl_langinfo(CODESET) is nonempty and not "ASCII" or "646".
  43      On Mac OS X 10.3.5 (Darwin 7.5) in the fr_FR locale, nl_langinfo(CODESET)
  44      is empty, and the behaviour of Tcl 8.4 in this locale is not useful.
  45      On OpenBSD 4.0, when an unsupported locale is specified, setlocale()
  46      succeeds but then nl_langinfo(CODESET) is "646". In this situation,
  47      some unit tests fail.
  48      On MirBSD 10, when an unsupported locale is specified, setlocale()
  49      succeeds but then nl_langinfo(CODESET) is "UTF-8".  */
  50 #if HAVE_LANGINFO_CODESET
  51   {
  52     const char *cs = nl_langinfo (CODESET);
  53     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0
  54         || strcmp (cs, "UTF-8") == 0)
  55       return 1;
  56   }
  57 #endif
  58 #ifdef __CYGWIN__
  59   /* On Cygwin, avoid locale names without encoding suffix, because the
  60      locale_charset() function relies on the encoding suffix.  Note that
  61      LC_ALL is set on the command line.  */
  62   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  63 #endif
  64   /* Check whether in a month name, no byte in the range 0x80..0x9F occurs.
  65      This excludes the UTF-8 encoding (except on MirBSD).  */
  66   t.tm_year = 1975 - 1900; t.tm_mon = 2 - 1; t.tm_mday = 4;
  67   if (strftime (buf, sizeof (buf), "%B", &t) < 2) return 1;
  68   for (p = buf; *p != '\0'; p++)
  69     if ((unsigned char) *p >= 0x80 && (unsigned char) *p < 0xa0)
  70       return 1;
  71   /* Check whether a typical GB18030 multibyte sequence is recognized as a
  72      single wide character.  This excludes the GB2312 and GBK encodings.  */
  73   if (mblen ("\203\062\332\066", 5) != 4)
  74     return 1;
  75   return 0;
  76 }
  77 changequote([,])dnl
  78       ])])
  79     if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  80       case "$host_os" in
  81         # Handle native Windows specially, because there setlocale() interprets
  82         # "ar" as "Arabic" or "Arabic_Saudi Arabia.1256",
  83         # "fr" or "fra" as "French" or "French_France.1252",
  84         # "ge"(!) or "deu"(!) as "German" or "German_Germany.1252",
  85         # "ja" as "Japanese" or "Japanese_Japan.932",
  86         # and similar.
  87         mingw*)
  88           # Test for the hypothetical native Windows locale name.
  89           if (LC_ALL=Chinese_China.54936 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  90             gt_cv_locale_zh_CN=Chinese_China.54936
  91           else
  92             # None found.
  93             gt_cv_locale_zh_CN=none
  94           fi
  95           ;;
  96         solaris2.8)
  97           # On Solaris 8, the locales zh_CN.GB18030, zh_CN.GBK, zh.GBK are
  98           # broken. One witness is the test case in gl_MBRTOWC_SANITYCHECK.
  99           # Another witness is that "LC_ALL=zh_CN.GB18030 bash -c true" dumps core.
 100           gt_cv_locale_zh_CN=none
 101           ;;
 102         *)
 103           # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
 104           # otherwise on Mac OS X 10.3.5 the LC_TIME=C from the beginning of the
 105           # configure script would override the LC_ALL setting. Likewise for
 106           # LC_CTYPE, which is also set at the beginning of the configure script.
 107           # Test for the locale name without encoding suffix.
 108           if (LC_ALL=zh_CN LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 109             gt_cv_locale_zh_CN=zh_CN
 110           else
 111             # Test for the locale name with explicit encoding suffix.
 112             if (LC_ALL=zh_CN.GB18030 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 113               gt_cv_locale_zh_CN=zh_CN.GB18030
 114             else
 115               # None found.
 116               gt_cv_locale_zh_CN=none
 117             fi
 118           fi
 119           ;;
 120       esac
 121     else
 122       # If there was a link error, due to mblen(), the system is so old that
 123       # it certainly doesn't have a chinese locale.
 124       gt_cv_locale_zh_CN=none
 125     fi
 126     rm -fr conftest*
 127   ])
 128   LOCALE_ZH_CN=$gt_cv_locale_zh_CN
 129   AC_SUBST([LOCALE_ZH_CN])
 130 ])