git.gag.com Git - debian/tar/blob - m4/locale-ja.m4

   1 # locale-ja.m4 serial 12
   2 dnl Copyright (C) 2003, 2005-2015 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 dnl Determine the name of a japanese locale with EUC-JP encoding.
  10 AC_DEFUN([gt_LOCALE_JA],
  11 [
  12   AC_REQUIRE([AC_CANONICAL_HOST])
  13   AC_REQUIRE([AM_LANGINFO_CODESET])
  14   AC_CACHE_CHECK([for a traditional japanese locale], [gt_cv_locale_ja], [
  15     AC_LANG_CONFTEST([AC_LANG_SOURCE([
  16 changequote(,)dnl
  17 #include <locale.h>
  18 #include <time.h>
  19 #if HAVE_LANGINFO_CODESET
  20 # include <langinfo.h>
  21 #endif
  22 #include <stdlib.h>
  23 #include <string.h>
  24 struct tm t;
  25 char buf[16];
  26 int main ()
  27 {
  28   const char *p;
  29   /* Check whether the given locale name is recognized by the system.  */
  30 #if (defined _WIN32 || defined __WIN32__) && !defined __CYGWIN__
  31   /* On native Windows, setlocale(category, "") looks at the system settings,
  32      not at the environment variables.  Also, when an encoding suffix such
  33      as ".65001" or ".54936" is specified, it succeeds but sets the LC_CTYPE
  34      category of the locale to "C".  */
  35   if (setlocale (LC_ALL, getenv ("LC_ALL")) == NULL
  36       || strcmp (setlocale (LC_CTYPE, NULL), "C") == 0)
  37     return 1;
  38 #else
  39   if (setlocale (LC_ALL, "") == NULL) return 1;
  40 #endif
  41   /* Check whether nl_langinfo(CODESET) is nonempty and not "ASCII" or "646".
  42      On Mac OS X 10.3.5 (Darwin 7.5) in the fr_FR locale, nl_langinfo(CODESET)
  43      is empty, and the behaviour of Tcl 8.4 in this locale is not useful.
  44      On OpenBSD 4.0, when an unsupported locale is specified, setlocale()
  45      succeeds but then nl_langinfo(CODESET) is "646". In this situation,
  46      some unit tests fail.
  47      On MirBSD 10, when an unsupported locale is specified, setlocale()
  48      succeeds but then nl_langinfo(CODESET) is "UTF-8".  */
  49 #if HAVE_LANGINFO_CODESET
  50   {
  51     const char *cs = nl_langinfo (CODESET);
  52     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0
  53         || strcmp (cs, "UTF-8") == 0)
  54       return 1;
  55   }
  56 #endif
  57 #ifdef __CYGWIN__
  58   /* On Cygwin, avoid locale names without encoding suffix, because the
  59      locale_charset() function relies on the encoding suffix.  Note that
  60      LC_ALL is set on the command line.  */
  61   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  62 #endif
  63   /* Check whether MB_CUR_MAX is > 1.  This excludes the dysfunctional locales
  64      on Cygwin 1.5.x.  */
  65   if (MB_CUR_MAX == 1)
  66     return 1;
  67   /* Check whether in a month name, no byte in the range 0x80..0x9F occurs.
  68      This excludes the UTF-8 encoding (except on MirBSD).  */
  69   t.tm_year = 1975 - 1900; t.tm_mon = 2 - 1; t.tm_mday = 4;
  70   if (strftime (buf, sizeof (buf), "%B", &t) < 2) return 1;
  71   for (p = buf; *p != '\0'; p++)
  72     if ((unsigned char) *p >= 0x80 && (unsigned char) *p < 0xa0)
  73       return 1;
  74   return 0;
  75 }
  76 changequote([,])dnl
  77       ])])
  78     if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  79       case "$host_os" in
  80         # Handle native Windows specially, because there setlocale() interprets
  81         # "ar" as "Arabic" or "Arabic_Saudi Arabia.1256",
  82         # "fr" or "fra" as "French" or "French_France.1252",
  83         # "ge"(!) or "deu"(!) as "German" or "German_Germany.1252",
  84         # "ja" as "Japanese" or "Japanese_Japan.932",
  85         # and similar.
  86         mingw*)
  87           # Note that on native Windows, the Japanese locale is
  88           # Japanese_Japan.932, and CP932 is very different from EUC-JP, so we
  89           # cannot use it here.
  90           gt_cv_locale_ja=none
  91           ;;
  92         *)
  93           # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
  94           # otherwise on Mac OS X 10.3.5 the LC_TIME=C from the beginning of the
  95           # configure script would override the LC_ALL setting. Likewise for
  96           # LC_CTYPE, which is also set at the beginning of the configure script.
  97           # Test for the AIX locale name.
  98           if (LC_ALL=ja_JP LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  99             gt_cv_locale_ja=ja_JP
 100           else
 101             # Test for the locale name with explicit encoding suffix.
 102             if (LC_ALL=ja_JP.EUC-JP LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 103               gt_cv_locale_ja=ja_JP.EUC-JP
 104             else
 105               # Test for the HP-UX, OSF/1, NetBSD locale name.
 106               if (LC_ALL=ja_JP.eucJP LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 107                 gt_cv_locale_ja=ja_JP.eucJP
 108               else
 109                 # Test for the IRIX, FreeBSD locale name.
 110                 if (LC_ALL=ja_JP.EUC LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 111                   gt_cv_locale_ja=ja_JP.EUC
 112                 else
 113                   # Test for the Solaris 7 locale name.
 114                   if (LC_ALL=ja LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
 115                     gt_cv_locale_ja=ja
 116                   else
 117                     # Special test for NetBSD 1.6.
 118                     if test -f /usr/share/locale/ja_JP.eucJP/LC_CTYPE; then
 119                       gt_cv_locale_ja=ja_JP.eucJP
 120                     else
 121                       # None found.
 122                       gt_cv_locale_ja=none
 123                     fi
 124                   fi
 125                 fi
 126               fi
 127             fi
 128           fi
 129           ;;
 130       esac
 131     fi
 132     rm -fr conftest*
 133   ])
 134   LOCALE_JA=$gt_cv_locale_ja
 135   AC_SUBST([LOCALE_JA])
 136 ])