git.gag.com Git - debian/tar/blob - m4/link.m4

   1 # link.m4 serial 5
   2 dnl Copyright (C) 2009-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_LINK],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_CHECK_FUNCS_ONCE([link])
  11   if test $ac_cv_func_link = no; then
  12     HAVE_LINK=0
  13     AC_LIBOBJ([link])
  14   else
  15     AC_CACHE_CHECK([whether link handles trailing slash correctly],
  16       [gl_cv_func_link_works],
  17       [touch conftest.a
  18        # Assume that if we have lstat, we can also check symlinks.
  19        if test $ac_cv_func_lstat = yes; then
  20          ln -s conftest.a conftest.lnk
  21        fi
  22        AC_RUN_IFELSE(
  23          [AC_LANG_PROGRAM(
  24            [[#include <unistd.h>
  25            ]],
  26            [[int result = 0;
  27              if (!link ("conftest.a", "conftest.b/"))
  28                result |= 1;
  29 #if HAVE_LSTAT
  30              if (!link ("conftest.lnk/", "conftest.b"))
  31                result |= 2;
  32 #endif
  33              return result;
  34            ]])],
  35          [gl_cv_func_link_works=yes], [gl_cv_func_link_works=no],
  36          [gl_cv_func_link_works="guessing no"])
  37        rm -f conftest.a conftest.b conftest.lnk])
  38     if test "$gl_cv_func_link_works" != yes; then
  39       REPLACE_LINK=1
  40       AC_LIBOBJ([link])
  41     fi
  42   fi
  43 ])