git.gag.com Git - debian/tar/blob - m4/fseeko.m4

   1 # fseeko.m4 serial 11
   2 dnl Copyright (C) 2007-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FSEEKO],
   8 [
   9   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  10   AC_REQUIRE([gl_HAVE_FSEEKO])
  11   AC_REQUIRE([gl_STDIN_LARGE_OFFSET])
  12
  13   AC_CHECK_DECLS_ONCE([fseeko])
  14   if test $ac_cv_have_decl_fseeko = no; then
  15     HAVE_DECL_FSEEKO=0
  16   fi
  17
  18   if test $gl_cv_func_fseeko = no; then
  19     HAVE_FSEEKO=0
  20     gl_REPLACE_FSEEKO
  21   else
  22     if test $gl_cv_var_stdin_large_offset = no; then
  23       gl_REPLACE_FSEEKO
  24     fi
  25   fi
  26 ])
  27
  28 dnl Tests whether fseeko is available.
  29 dnl Result is gl_cv_func_fseeko.
  30 AC_DEFUN([gl_HAVE_FSEEKO],
  31 [
  32   AC_REQUIRE([AC_PROG_CC])
  33
  34   dnl Persuade glibc <stdio.h> to declare fseeko().
  35   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  36
  37   AC_CACHE_CHECK([for fseeko], [gl_cv_func_fseeko],
  38     [
  39       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
  40 ]], [fseeko (stdin, 0, 0);])],
  41         [gl_cv_func_fseeko=yes], [gl_cv_func_fseeko=no])
  42     ])
  43 ])
  44
  45 AC_DEFUN([gl_REPLACE_FSEEKO],
  46 [
  47   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  48   AC_REQUIRE([gl_HAVE_FSEEKO])
  49   if test $gl_cv_func_fseeko = yes; then
  50     REPLACE_FSEEKO=1
  51   fi
  52   AC_LIBOBJ([fseeko])
  53   dnl If we are also using the fseek module, then fseek needs replacing, too.
  54   m4_ifdef([gl_REPLACE_FSEEK], [gl_REPLACE_FSEEK])
  55 ])
  56
  57 dnl Code shared by fseeko and ftello.  Determine if large files are supported,
  58 dnl but stdin does not start as a large file by default.
  59 AC_DEFUN([gl_STDIN_LARGE_OFFSET],
  60   [
  61     AC_CACHE_CHECK([whether stdin defaults to large file offsets],
  62       [gl_cv_var_stdin_large_offset],
  63       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]],
  64 [[#if defined __SL64 && defined __SCLE /* cygwin */
  65   /* Cygwin 1.5.24 and earlier fail to put stdin in 64-bit mode, making
  66      fseeko/ftello needlessly fail.  This bug was fixed in 1.5.25, and
  67      it is easier to do a version check than building a runtime test.  */
  68 # include <cygwin/version.h>
  69 # if CYGWIN_VERSION_DLL_COMBINED < CYGWIN_VERSION_DLL_MAKE_COMBINED (1005, 25)
  70   choke me
  71 # endif
  72 #endif]])],
  73         [gl_cv_var_stdin_large_offset=yes],
  74         [gl_cv_var_stdin_large_offset=no])])
  75 ])