git.gag.com Git - debian/tar/blob - m4/fdopendir.m4

   1 # serial 5
   2 # See if we need to provide fdopendir.
   3
   4 dnl Copyright (C) 2009-2011 Free Software Foundation, Inc.
   5 dnl This file is free software; the Free Software Foundation
   6 dnl gives unlimited permission to copy and/or distribute it,
   7 dnl with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Eric Blake.
  10
  11 AC_DEFUN([gl_FUNC_FDOPENDIR],
  12 [
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14   dnl FreeBSD 7.3 has the function, but failed to declare it.
  15   AC_CHECK_DECLS([fdopendir], [], [HAVE_DECL_FDOPENDIR=0], [[
  16 #include <dirent.h>
  17     ]])
  18   AC_CHECK_FUNCS_ONCE([fdopendir])
  19   if test $ac_cv_func_fdopendir = no; then
  20     AC_LIBOBJ([openat-proc])
  21     AC_LIBOBJ([fdopendir])
  22     gl_REPLACE_DIRENT_H
  23     HAVE_FDOPENDIR=0
  24   else
  25     AC_CACHE_CHECK([whether fdopendir works],
  26       [gl_cv_func_fdopendir_works],
  27       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  28 #include <dirent.h>
  29 #include <fcntl.h>
  30 #include <unistd.h>
  31 #if !HAVE_DECL_FDOPENDIR
  32 extern DIR *fdopendir (int);
  33 #endif
  34 ]], [int result = 0;
  35      int fd = open ("conftest.c", O_RDONLY);
  36      if (fd < 0) result |= 1;
  37      if (fdopendir (fd)) result |= 2;
  38      if (close (fd)) result |= 4;
  39      return result;])],
  40          [gl_cv_func_fdopendir_works=yes],
  41          [gl_cv_func_fdopendir_works=no],
  42          [gl_cv_func_fdopendir_works="guessing no"])])
  43     if test "$gl_cv_func_fdopendir_works" != yes; then
  44       REPLACE_FDOPENDIR=1
  45       gl_REPLACE_DIRENT_H
  46       AC_LIBOBJ([fdopendir])
  47     fi
  48   fi
  49 ])