git.gag.com Git - debian/tar/blob - m4/fchdir.m4

   1 # fchdir.m4 serial 15
   2 dnl Copyright (C) 2006-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FCHDIR],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
  11   AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
  12
  13   AC_CHECK_DECLS_ONCE([fchdir])
  14   if test $ac_cv_have_decl_fchdir = no; then
  15     HAVE_DECL_FCHDIR=0
  16   fi
  17
  18   AC_CHECK_FUNCS_ONCE([fchdir])
  19   if test $ac_cv_func_fchdir = no; then
  20     HAVE_FCHDIR=0
  21     AC_LIBOBJ([fchdir])
  22     gl_PREREQ_FCHDIR
  23     AC_DEFINE([REPLACE_FCHDIR], [1],
  24       [Define to 1 if gnulib's fchdir() replacement is used.])
  25     dnl We must also replace anything that can manipulate a directory fd,
  26     dnl to keep our bookkeeping up-to-date.  We don't have to replace
  27     dnl fstatat, since no platform has fstatat but lacks fchdir.
  28     REPLACE_OPENDIR=1
  29     REPLACE_CLOSEDIR=1
  30     REPLACE_DUP=1
  31     gl_REPLACE_OPEN
  32     gl_REPLACE_CLOSE
  33     gl_REPLACE_DUP2
  34     dnl dup3 is already unconditionally replaced
  35     gl_REPLACE_FCNTL
  36     gl_REPLACE_DIRENT_H
  37     AC_CACHE_CHECK([whether open can visit directories],
  38       [gl_cv_func_open_directory_works],
  39       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
  40 ]], [return open(".", O_RDONLY) < 0;])],
  41         [gl_cv_func_open_directory_works=yes],
  42         [gl_cv_func_open_directory_works=no],
  43         [gl_cv_func_open_directory_works="guessing no"])])
  44     if test "$gl_cv_func_open_directory_works" != yes; then
  45       AC_DEFINE([REPLACE_OPEN_DIRECTORY], [1], [Define to 1 if open() should
  46 work around the inability to open a directory.])
  47       REPLACE_FSTAT=1
  48     fi
  49   fi
  50 ])
  51
  52 # Prerequisites of lib/fchdir.c.
  53 AC_DEFUN([gl_PREREQ_FCHDIR], [:])