git.gag.com Git - debian/tar/blob - m4/dirfd.m4

   1 # serial 19   -*- Autoconf -*-
   2
   3 dnl Find out how to get the file descriptor associated with an open DIR*.
   4
   5 # Copyright (C) 2001-2006, 2008-2011 Free Software Foundation, Inc.
   6 # This file is free software; the Free Software Foundation
   7 # gives unlimited permission to copy and/or distribute it,
   8 # with or without modifications, as long as this notice is preserved.
   9
  10 dnl From Jim Meyering
  11
  12 AC_DEFUN([gl_FUNC_DIRFD],
  13 [
  14   AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
  15   gl_REPLACE_DIRENT_H
  16
  17   dnl Persuade glibc <dirent.h> to declare dirfd().
  18   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  19
  20   AC_CHECK_FUNCS([dirfd])
  21   AC_CHECK_DECLS([dirfd], , ,
  22     [#include <sys/types.h>
  23      #include <dirent.h>])
  24   if test $ac_cv_have_decl_dirfd = no; then
  25     HAVE_DECL_DIRFD=0
  26   fi
  27
  28   AC_CACHE_CHECK([whether dirfd is a macro],
  29     gl_cv_func_dirfd_macro,
  30     [AC_EGREP_CPP([dirent_header_defines_dirfd], [
  31 #include <sys/types.h>
  32 #include <dirent.h>
  33 #ifdef dirfd
  34  dirent_header_defines_dirfd
  35 #endif],
  36        gl_cv_func_dirfd_macro=yes,
  37        gl_cv_func_dirfd_macro=no)])
  38
  39   # Use the replacement only if we have no function or macro with that name.
  40   if test $ac_cv_func_dirfd,$gl_cv_func_dirfd_macro = no,no; then
  41     if test $ac_cv_have_decl_dirfd = yes; then
  42       # If the system declares dirfd already, let's declare rpl_dirfd instead.
  43       REPLACE_DIRFD=1
  44     fi
  45     AC_LIBOBJ([dirfd])
  46     AC_CACHE_CHECK(
  47               [how to get the file descriptor associated with an open DIR*],
  48                    gl_cv_sys_dir_fd_member_name,
  49       [
  50         dirfd_save_CFLAGS=$CFLAGS
  51         for ac_expr in d_fd dd_fd; do
  52
  53           CFLAGS="$CFLAGS -DDIR_FD_MEMBER_NAME=$ac_expr"
  54           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  55              #include <sys/types.h>
  56              #include <dirent.h>]],
  57             [[DIR *dir_p = opendir("."); (void) dir_p->DIR_FD_MEMBER_NAME;]])],
  58             [dir_fd_found=yes]
  59           )
  60           CFLAGS=$dirfd_save_CFLAGS
  61           test "$dir_fd_found" = yes && break
  62         done
  63         test "$dir_fd_found" = yes || ac_expr=no_such_member
  64
  65         gl_cv_sys_dir_fd_member_name=$ac_expr
  66       ]
  67     )
  68     if test $gl_cv_sys_dir_fd_member_name != no_such_member; then
  69       AC_DEFINE_UNQUOTED([DIR_FD_MEMBER_NAME],
  70         $gl_cv_sys_dir_fd_member_name,
  71         [the name of the file descriptor member of DIR])
  72     fi
  73     AH_VERBATIM(DIR_TO_FD,
  74                 [#ifdef DIR_FD_MEMBER_NAME
  75 # define DIR_TO_FD(Dir_p) ((Dir_p)->DIR_FD_MEMBER_NAME)
  76 #else
  77 # define DIR_TO_FD(Dir_p) -1
  78 #endif
  79 ])
  80   fi
  81 ])