git.gag.com Git - debian/gnuradio/blob - configure.ac

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2007,2008,2009 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_INIT
  21 AC_PREREQ(2.57)
  22 AM_CONFIG_HEADER(config.h)
  23 AC_CONFIG_SRCDIR([gnuradio-core/src/lib/runtime/gr_vmcircbuf.cc])
  24
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_TARGET
  28
  29 AM_INIT_AUTOMAKE(gnuradio,3.2.2)
  30
  31 DEFINES=""
  32 AC_SUBST(DEFINES)
  33
  34 dnl Remember if the user explicity set CFLAGS
  35 if test -n "${CFLAGS}"; then
  36   user_set_cflags=yes
  37 fi
  38 dnl Remember if the user explicity set CXXFLAGS
  39 if test -n "${CXXFLAGS}"; then
  40   user_set_cxxflags=yes
  41 fi
  42
  43
  44 LF_CONFIGURE_CC
  45 LF_CONFIGURE_CXX
  46 GR_LIB64                dnl check for lib64 suffix after choosing compilers
  47
  48
  49 dnl The three macros above are known to override CFLAGS if the user
  50 dnl didn't specify them.  Though I'm sure somebody thought this was
  51 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  52 dnl selected files.  Thus we "undo" the damage here...
  53 dnl
  54 dnl If the user specified CFLAGS, we use them.
  55 dnl See Makefile.common for the rest of the magic.
  56 if test "$user_set_cflags" != yes; then
  57   autoconf_default_CFLAGS="$CFLAGS"
  58   CFLAGS=""
  59 fi
  60 AC_SUBST(autoconf_default_CFLAGS)
  61
  62
  63 dnl The three macros above are known to override CXXFLAGS if the user
  64 dnl didn't specify them.  Though I'm sure somebody thought this was
  65 dnl a good idea, it makes it hard to use other than -g -O2 when compiling
  66 dnl selected files.  Thus we "undo" the damage here...
  67 dnl
  68 dnl If the user specified CXXFLAGS, we use them.  Otherwise when compiling
  69 dnl the output of swig use use -O1 if we're using g++.
  70 dnl See Makefile.common for the rest of the magic.
  71 if test "$user_set_cxxflags" != yes; then
  72   autoconf_default_CXXFLAGS="$CXXFLAGS"
  73   CXXFLAGS=""
  74   if test "$GXX" = yes; then
  75     case "$host_cpu" in
  76         powerpc*)
  77            dnl "-O1" is broken on the PPC for some reason
  78            dnl (at least as of g++ 4.1.1)
  79            swig_CXXFLAGS="-g1 -O2 -Wno-strict-aliasing -Wno-parentheses"
  80         ;;
  81         *)
  82         swig_CXXFLAGS="-g -O1 -Wno-strict-aliasing -Wno-parentheses"
  83         ;;
  84     esac
  85   fi
  86 fi
  87 AC_SUBST(autoconf_default_CXXFLAGS)
  88 AC_SUBST(swig_CXXFLAGS)
  89
  90 dnl add ${prefix}/lib${gr_libdir_suffix}/pkgconfig to the head of the PKG_CONFIG_PATH
  91 if test x${PKG_CONFIG_PATH} = x; then
  92     PKG_CONFIG_PATH=${prefix}/lib${gr_libdir_suffix}/pkgconfig
  93 else
  94     PKG_CONFIG_PATH=${prefix}/lib${gr_libdir_suffix}/pkgconfig:${PKG_CONFIG_PATH}
  95 fi
  96 export PKG_CONFIG_PATH
  97
  98 LF_SET_WARNINGS
  99 GR_SET_GPROF
 100 GR_SET_PROF
 101 AM_PROG_AS
 102 AC_PROG_LN_S
 103 AC_PROG_MAKE_SET
 104 AC_PROG_INSTALL
 105
 106 # AC_PROG_MKDIR_P
 107 # is a backport of autoconf-2.60's AC_PROG_MKDIR_P.
 108 # Remove this macro when we can assume autoconf >= 2.60.
 109 m4_ifdef([AC_PROG_MKDIR_P], [], [
 110   AC_DEFUN([AC_PROG_MKDIR_P],
 111     [AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
 112      MKDIR_P='$(mkdir_p)'
 113      AC_SUBST([MKDIR_P])])
 114 ])
 115 AC_PROG_MKDIR_P
 116
 117 AC_PATH_PROG([RM_PROG], [rm])
 118
 119 AC_LIBTOOL_WIN32_DLL
 120 dnl AC_DISABLE_SHARED   dnl don't build shared libraries
 121 AC_ENABLE_SHARED        dnl do build shared libraries
 122 AC_DISABLE_STATIC       dnl don't build static libraries
 123 m4_ifdef([LT_INIT],[LT_INIT],[AC_PROG_LIBTOOL])
 124 GR_FORTRAN
 125
 126 GR_NO_UNDEFINED         dnl do we need the -no-undefined linker flag
 127 GR_SCRIPTING
 128
 129 AC_CHECK_PROG([XMLTO],[xmlto],[yes],[])
 130 AM_CONDITIONAL([HAS_XMLTO], [test x$XMLTO = xyes])
 131
 132 dnl Checks for libraries.
 133 AC_CHECK_LIB(socket,socket)
 134
 135 dnl check for omnithreads (will soon be removed)
 136 GR_OMNITHREAD
 137
 138 dnl Set the c++ compiler that we use for the build system when cross compiling
 139 if test x$CXX_FOR_BUILD = x
 140 then
 141   if test x$cross_compiling = xno; then
 142     CXX_FOR_BUILD=${CXX}
 143   else
 144     CXX_FOR_BUILD=g++
 145   fi
 146 fi
 147 AC_SUBST(CXX_FOR_BUILD)
 148
 149 dnl Check for SysV shm (mandatory)
 150 dnl FIXME this is no longer mandatory.  Check the macro.
 151 GR_SYSV_SHM
 152
 153 dnl Checks for header files.
 154 AC_HEADER_STDC
 155 AC_HEADER_SYS_WAIT
 156 AC_CHECK_HEADERS(fcntl.h limits.h strings.h time.h sys/ioctl.h sys/time.h unistd.h)
 157 AC_CHECK_HEADERS(linux/ppdev.h dev/ppbus/ppi.h sys/mman.h sys/select.h sys/types.h)
 158 AC_CHECK_HEADERS(sys/resource.h stdint.h sched.h signal.h sys/syscall.h malloc.h)
 159 AC_CHECK_HEADERS(netinet/in.h)
 160 AC_CHECK_HEADERS(windows.h)
 161 AC_CHECK_HEADERS(vec_types.h)
 162
 163 dnl Checks for typedefs, structures, and compiler characteristics.
 164 AC_C_CONST
 165 AC_C_INLINE
 166 AC_TYPE_SIZE_T
 167 AC_HEADER_TIME
 168 AC_C_BIGENDIAN([GR_ARCH_BIGENDIAN=1],[GR_ARCH_BIGENDIAN=0])
 169 AC_SUBST(GR_ARCH_BIGENDIAN)
 170 AC_STRUCT_TM
 171
 172 dnl Checks for library functions.
 173 AC_FUNC_ALLOCA
 174 GR_CHECK_MEMALIGN
 175 AC_FUNC_SETVBUF_REVERSED
 176 AC_FUNC_VPRINTF
 177 AC_CHECK_FUNCS([mmap select socket strcspn strerror strspn getpagesize sysconf])
 178 AC_CHECK_FUNCS([snprintf gettimeofday nanosleep sched_setscheduler])
 179 AC_CHECK_FUNCS([modf sqrt sigaction sigprocmask pthread_sigmask])
 180 AC_CHECK_FUNCS([sched_setaffinity])
 181
 182 AC_CHECK_LIB(m, sincos, [AC_DEFINE([HAVE_SINCOS],[1],[Define to 1 if your system has `sincos'.])])
 183 AC_CHECK_LIB(m, sincosf,[AC_DEFINE([HAVE_SINCOSF],[1],[Define to 1 if your system has `sincosf'.])])
 184 AC_CHECK_LIB(m, sinf, [AC_DEFINE([HAVE_SINF],[1],[Define to 1 if your system has `sinf'.])])
 185 AC_CHECK_LIB(m, cosf, [AC_DEFINE([HAVE_COSF],[1],[Define to 1 if your system has `cosf'.])])
 186 AC_CHECK_LIB(m, trunc, [AC_DEFINE([HAVE_TRUNC],[1],[Define to 1 if your system has `trunc'.])])
 187 AC_CHECK_LIB(m, exp10, [AC_DEFINE([HAVE_EXP10],[1],[Define to 1 if your system has 'exp10'.])])
 188 AC_CHECK_LIB(m, log2, [AC_DEFINE([HAVE_LOG2],[1],[Define to 1 if your system has 'log2'.])])
 189 #AC_FUNC_MKTIME
 190
 191 AH_BOTTOM([
 192 #ifndef HAVE_TRUNC
 193 #include <math.h>
 194 inline static double trunc(double x)
 195 {
 196   return x >= 0 ? floor(x) : ceil(x);
 197 }
 198 #endif
 199
 200 #ifndef HAVE_EXP10
 201 #include <math.h>
 202 inline static double exp10(double x)
 203 {
 204   return pow(10.0, x);
 205 }
 206 #endif
 207
 208 #ifdef HAVE_WINDOWS_H
 209 #define NOMINMAX
 210 #endif
 211 ])
 212
 213 GR_CHECK_SHM_OPEN
 214 GR_LIBGNURADIO_CORE_EXTRA_LDFLAGS
 215 GR_CHECK_CREATEFILEMAPPING
 216
 217 dnl Check for Mingw support
 218 GR_PWIN32
 219
 220 dnl Do we have "dot", part of the graphviz package from AT&T?
 221 dnl Doxgen will use it to draw pretty diagrams ;-)
 222 AC_CHECK_PROG(HAVE_DOT, [dot],[YES],[NO])
 223
 224 PKG_CHECK_MODULES(FFTW3F, fftw3f >= 3.0)
 225 AC_SUBST(FFTW3F_LIBS)
 226
 227 dnl conditional build stuff
 228 GR_CHECK_DOXYGEN
 229 GR_SET_MD_CPU
 230
 231 dnl Define where to look for cppunit includes and libs
 232 dnl sets CPPUNIT_CFLAGS and CPPUNIT_LIBS
 233 dnl Try using pkg-config first, then fall back to cppunit-config.
 234 PKG_CHECK_EXISTS(cppunit,
 235   [PKG_CHECK_MODULES(CPPUNIT, cppunit >= 1.9.14)],
 236   [AM_PATH_CPPUNIT([1.9.14],[],
 237                 [AC_MSG_ERROR([GNU Radio requires cppunit.  Stop])])])
 238
 239 CPPUNIT_INCLUDES=$CPPUNIT_CFLAGS
 240 AC_SUBST(CPPUNIT_INCLUDES)
 241
 242 dnl see if GUILE is installed
 243 AC_PATH_PROG(GUILE,guile)
 244
 245 dnl
 246 dnl We require the boost headers, thread lib and date_time lib.
 247 dnl AX_BOOST_BASE finds the headers and the lib dir (-L<foo>)
 248 dnl
 249 dnl calls AC_SUBST(BOOST_CPPFLAGS), AC_SUBST(BOOST_LDFLAGS) and defines HAVE_BOOST
 250 AX_BOOST_BASE([1.35])
 251
 252 dnl calls AC_SUBST(BOOST_THREAD_LIB), AC_SUBST(BOOST_CXXFLAGS) and defines HAVE_BOOST_THREAD
 253 AX_BOOST_THREAD
 254 CXXFLAGS="$CXXFLAGS $BOOST_CXXFLAGS"       dnl often picks up a -pthread or something similar
 255 CFLAGS="$CFLAGS $BOOST_CXXFLAGS"           dnl often picks up a -pthread or something similar
 256
 257 dnl
 258 dnl all the rest of these call AC_SUBST(BOOST_<foo>_LIB) and define HAVE_BOOST_<foo>
 259 dnl
 260 AX_BOOST_DATE_TIME
 261 dnl AX_BOOST_FILESYSTEM
 262 dnl AX_BOOST_IOSTREAMS
 263 AX_BOOST_PROGRAM_OPTIONS
 264 dnl AX_BOOST_REGEX
 265 dnl AX_BOOST_SERIALIZATION
 266 dnl AX_BOOST_SIGNALS
 267 dnl AX_BOOST_SYSTEM
 268 dnl AX_BOOST_TEST_EXEC_MONITOR
 269 dnl AX_BOOST_UNIT_TEST_FRAMEWORK
 270 dnl AX_BOOST_WSERIALIZATION
 271
 272
 273 dnl If this is being done from a subversion tree, create variables
 274 GR_SUBVERSION
 275
 276 dnl Component specific configuration
 277 dnl The order of the GR_ macros determines the order of compilation
 278 dnl For -any- checks on $enable_all_components
 279 dnl use the following guidelines:
 280 dnl   yes : --enable-all-components was specified, so error out if any
 281 dnl         components do not pass configuration checks.
 282 dnl   no  : --disable-all-components was specified, so try to build the
 283 dnl         --enable'd components, and error out if any do not pass
 284 dnl         configuration checks.
 285 dnl   ""  : this option was not specified on the command line; try to
 286 dnl         build all components that are not --with'd, but don't
 287 dnl         error out if any component does not pass configuration checks.
 288 dnl
 289 dnl For each --enable-foo component, if that flag is not specified on
 290 dnl the command line, the related variable $enable_foo will be set to
 291 dnl $enable_all_components .
 292
 293 AC_ARG_ENABLE(
 294     [all-components],
 295     [  --enable-all-components Build all configurable components (default), or stop on failed dependencies]
 296 )
 297
 298 build_dirs="config"
 299 GRC_GRUEL                       dnl must come first
 300 GRC_OMNITHREAD                  dnl must come before gnuradio-core and mblock
 301 GRC_GCELL
 302 GRC_GNURADIO_CORE
 303 GRC_PMT
 304 GRC_MBLOCK                      dnl this must come after GRC_PMT
 305 GRC_USRP
 306 GRC_USRP2
 307 GRC_GR_USRP                     dnl this must come after GRC_USRP
 308 GRC_GR_USRP2
 309 GRC_GR_GCELL                    dnl this must come after GRC_GCELL and GRC_GNURADIO_CORE
 310 GRC_GR_AUDIO_ALSA
 311 GRC_GR_AUDIO_JACK
 312 GRC_GR_AUDIO_OSS
 313 GRC_GR_AUDIO_OSX
 314 GRC_GR_AUDIO_PORTAUDIO
 315 GRC_GR_AUDIO_WINDOWS
 316 GRC_GR_CVSD_VOCODER
 317 GRC_GR_GPIO
 318 GRC_GR_GSM_FR_VOCODER
 319 GRC_GR_PAGER
 320 GRC_GR_RADAR_MONO
 321 GRC_GR_RADIO_ASTRONOMY
 322 GRC_GR_TRELLIS
 323 GRC_GR_VIDEO_SDL
 324 GRC_GR_WXGUI
 325 GRC_GR_QTGUI
 326 GRC_GR_SOUNDER                  dnl this must come after GRC_USRP
 327 GRC_GR_UTILS                    dnl this must come after GRC_GR_WXGUI
 328 GRC_GNURADIO_EXAMPLES           dnl must come after all GRC_GR_*
 329 GRC_GRC
 330 GRC_DOCS                        dnl must be last
 331
 332 # Each component is now either to be built, was skipped, will be
 333 # included from pre-installed libraries and includes, or failed
 334 # dependencies.
 335 AC_SUBST([build_dirs], [$build_dirs])
 336 AC_SUBST([skipped_dirs], [$skipped_dirs])
 337 AC_SUBST([with_dirs], [$with_dirs])
 338
 339 # fix for older autotools that don't define these by default
 340 AC_SUBST(abs_top_srcdir)
 341 AC_SUBST(abs_top_builddir)
 342 AC_SUBST(MKDIR_P)
 343
 344 # 'with' variables - the pre-installed libraries, includes, and paths
 345 # - must always come last in the lists, so they require special
 346 # treatment.
 347 AC_SUBST(with_INCLUDES)
 348 AC_SUBST(with_SWIG_INCLUDES)
 349 AC_SUBST(with_PYDIRPATH)
 350 AC_SUBST(with_SWIGDIRPATH)
 351 AC_SUBST(with_LIBDIRPATH)
 352
 353 # Local files tweaked by AC
 354 AC_CONFIG_FILES([\
 355     Makefile \
 356     run_tests.sh \
 357     config/Makefile \
 358 ])
 359
 360 dnl run_tests.sh is created from run_tests.sh.in .  Make it executable.
 361 AC_CONFIG_COMMANDS([run_tests_build], [chmod +x run_tests.sh])
 362
 363 AC_OUTPUT
 364
 365 echo
 366 echo "*********************************************************************"
 367 echo The following GNU Radio components have been successfully configured:
 368 echo
 369 for dir in $build_dirs
 370 do
 371     echo $dir
 372 done
 373 echo
 374 echo You my now run the 'make' command to build these components.
 375 echo
 376 if test "$skipped_dirs" != ""; then
 377     echo "*********************************************************************"
 378     echo The following components were skipped either because you asked not
 379     echo to build them or they didn\'t pass configuration checks:
 380     echo
 381     for dir in $skipped_dirs
 382     do
 383         echo $dir
 384     done
 385     echo
 386     echo These components will not be built.
 387     echo
 388 fi
 389 if test "$with_dirs" != ""; then
 390     echo "*********************************************************************"
 391     echo The following components will be included from pre-installed
 392     echo libraries and includes:
 393     echo
 394     for dir in $with_dirs
 395     do
 396         echo $dir
 397     done
 398     echo
 399     echo These components will not be built.
 400     echo
 401 fi