git.gag.com Git - debian/gnuradio/blob - config/usrp_fusb_tech.m4

   1 dnl
   2 dnl Copyright 2003,2008 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GNU Radio
   5 dnl
   6 dnl GNU Radio is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3, or (at your option)
   9 dnl any later version.
  10 dnl
  11 dnl GNU Radio is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with GNU Radio; see the file COPYING.  If not, write to
  18 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  19 dnl Boston, MA 02110-1301, USA.
  20 dnl
  21
  22 # $1 is $enable_usrp:
  23 #   yes : do these tests
  24 #   no  : do not do these tests
  25 #   ""  : do these tests
  26
  27 AC_DEFUN([USRP_SET_FUSB_TECHNIQUE],[
  28   AC_ARG_WITH([fusb-tech],
  29               AC_HELP_STRING([--with-fusb-tech=OS],
  30                              [Set fast USB technique (default=auto)]),
  31               [cf_with_fusb_tech="$withval"],
  32               [cf_with_fusb_tech="$host_os"])
  33   if test [x]$1 != xno; then
  34       case "$cf_with_fusb_tech" in
  35         linux*)
  36           AC_CHECK_HEADER([linux/usbdevice_fs.h],
  37                           [x_have_usbdevice_fs_h=yes],
  38                           [x_have_usbdevice_fs_h=no])
  39           if test x${x_have_usbdevice_fs_h} = xyes; then
  40               FUSB_TECH=linux
  41           else
  42               FUSB_TECH=generic
  43           fi
  44           ;;
  45         darwin*)
  46           FUSB_TECH=darwin
  47           ;;
  48         cygwin*|win*|mingw*)
  49           FUSB_TECH=win32
  50           ;;
  51         *bsd*)
  52           AC_MSG_CHECKING([for RA/WB])
  53           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <dev/usb/usb.h>]],
  54                                              [[struct usb_bulk_ra_wb_opt o;
  55                                                ioctl(0, USB_SET_BULK_RA, &o);]])],
  56                             [FUSB_TECH=ra_wb],
  57                             [FUSB_TECH=generic])
  58           ;;
  59         *)
  60           FUSB_TECH=generic
  61           ;;
  62       esac
  63
  64       AC_MSG_CHECKING([for fast usb technique to use])
  65       AC_MSG_RESULT($FUSB_TECH)
  66       AC_SUBST(FUSB_TECH)
  67   fi
  68
  69   AM_CONDITIONAL(FUSB_TECH_darwin,   test x$FUSB_TECH = xdarwin)
  70   AM_CONDITIONAL(FUSB_TECH_win32,    test x$FUSB_TECH = xwin32)
  71   AM_CONDITIONAL(FUSB_TECH_generic,  test x$FUSB_TECH = xgeneric)
  72   AM_CONDITIONAL(FUSB_TECH_linux,    test x$FUSB_TECH = xlinux)
  73   AM_CONDITIONAL(FUSB_TECH_ra_wb,    test x$FUSB_TECH = xra_wb)
  74 ])