git.gag.com Git - debian/gnuradio/blob - config/sdl.m4

   1 # Configure paths for SDL
   2 # Sam Lantinga 9/21/99
   3 # stolen from Manish Singh
   4 # stolen back from Frank Belew
   5 # stolen from Manish Singh
   6 # Shamelessly stolen from Owen Taylor
   7
   8 dnl AM_PATH_SDL([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
   9 dnl Test for SDL, and define SDL_CFLAGS and SDL_LIBS
  10 dnl
  11 AC_DEFUN([AM_PATH_SDL],
  12 [dnl
  13 dnl Get the cflags and libraries from the sdl-config script
  14 dnl
  15 AC_ARG_WITH(sdl-prefix,[  --with-sdl-prefix=PFX   Prefix where SDL is installed (optional)],
  16             sdl_prefix="$withval", sdl_prefix="")
  17 AC_ARG_WITH(sdl-exec-prefix,[  --with-sdl-exec-prefix=PFX Exec prefix where SDL is installed (optional)],
  18             sdl_exec_prefix="$withval", sdl_exec_prefix="")
  19 AC_ARG_ENABLE(sdltest, AC_HELP_STRING([--disable-sdltest],
  20                                       [Do not try to compile and run a test SDL program]),
  21               [], enable_sdltest=yes)
  22
  23   if test x$sdl_exec_prefix != x ; then
  24      sdl_args="$sdl_args --exec-prefix=$sdl_exec_prefix"
  25      if test x${SDL_CONFIG+set} != xset ; then
  26         SDL_CONFIG=$sdl_exec_prefix/bin/sdl-config
  27      fi
  28   fi
  29   if test x$sdl_prefix != x ; then
  30      sdl_args="$sdl_args --prefix=$sdl_prefix"
  31      if test x${SDL_CONFIG+set} != xset ; then
  32         SDL_CONFIG=$sdl_prefix/bin/sdl-config
  33      fi
  34   fi
  35
  36   AC_REQUIRE([AC_CANONICAL_TARGET])
  37   TMP_PATH="$prefix/bin:$prefix/usr/bin:$PATH"
  38   AC_PATH_PROG(SDL_CONFIG, sdl-config, no, [$TMP_PATH])
  39   min_sdl_version=ifelse([$1], ,0.11.0,$1)
  40   AC_MSG_CHECKING(for SDL - version >= $min_sdl_version)
  41   no_sdl=""
  42   if test "$SDL_CONFIG" = "no" ; then
  43     no_sdl=yes
  44   else
  45     SDL_CFLAGS=`$SDL_CONFIG $sdlconf_args --cflags`
  46     SDL_LIBS=`$SDL_CONFIG $sdlconf_args --libs`
  47
  48     sdl_major_version=`$SDL_CONFIG $sdl_args --version | \
  49            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
  50     sdl_minor_version=`$SDL_CONFIG $sdl_args --version | \
  51            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
  52     sdl_micro_version=`$SDL_CONFIG $sdl_config_args --version | \
  53            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
  54     if test "x$enable_sdltest" = "xyes" ; then
  55       ac_save_CFLAGS="$CFLAGS"
  56       ac_save_LIBS="$LIBS"
  57       CFLAGS="$CFLAGS $SDL_CFLAGS"
  58       LIBS="$LIBS $SDL_LIBS"
  59 dnl
  60 dnl Now check if the installed SDL is sufficiently new. (Also sanity
  61 dnl checks the results of sdl-config to some extent
  62 dnl
  63       rm -f conf.sdltest
  64       AC_TRY_RUN([
  65 #include <stdio.h>
  66 #include <stdlib.h>
  67 #include <string.h>
  68 #include "SDL.h"
  69
  70 char*
  71 my_strdup (char *str)
  72 {
  73   char *new_str;
  74
  75   if (str)
  76     {
  77       new_str = (char *)malloc ((strlen (str) + 1) * sizeof(char));
  78       strcpy (new_str, str);
  79     }
  80   else
  81     new_str = NULL;
  82
  83   return new_str;
  84 }
  85
  86 int main (int argc, char *argv[])
  87 {
  88   int major, minor, micro;
  89   char *tmp_version;
  90
  91   /* This hangs on some systems (?)
  92   system ("touch conf.sdltest");
  93   */
  94   { FILE *fp = fopen("conf.sdltest", "a"); if ( fp ) fclose(fp); }
  95
  96   /* HP/UX 9 (%@#!) writes to sscanf strings */
  97   tmp_version = my_strdup("$min_sdl_version");
  98   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
  99      printf("%s, bad version string\n", "$min_sdl_version");
 100      exit(1);
 101    }
 102
 103    if (($sdl_major_version > major) ||
 104       (($sdl_major_version == major) && ($sdl_minor_version > minor)) ||
 105       (($sdl_major_version == major) && ($sdl_minor_version == minor) && ($sdl_micro_version >= micro)))
 106     {
 107       return 0;
 108     }
 109   else
 110     {
 111       printf("\n*** 'sdl-config --version' returned %d.%d.%d, but the minimum version\n", $sdl_major_version, $sdl_minor_version, $sdl_micro_version);
 112       printf("*** of SDL required is %d.%d.%d. If sdl-config is correct, then it is\n", major, minor, micro);
 113       printf("*** best to upgrade to the required version.\n");
 114       printf("*** If sdl-config was wrong, set the environment variable SDL_CONFIG\n");
 115       printf("*** to point to the correct copy of sdl-config, and remove the file\n");
 116       printf("*** config.cache before re-running configure\n");
 117       return 1;
 118     }
 119 }
 120
 121 ],, no_sdl=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 122        CFLAGS="$ac_save_CFLAGS"
 123        LIBS="$ac_save_LIBS"
 124      fi
 125   fi
 126   if test "x$no_sdl" = x ; then
 127      AC_MSG_RESULT(yes)
 128      ifelse([$2], , :, [$2])
 129   else
 130      AC_MSG_RESULT(no)
 131      if test "$SDL_CONFIG" = "no" ; then
 132        echo "*** The sdl-config script installed by SDL could not be found"
 133        echo "*** If SDL was installed in PREFIX, make sure PREFIX/bin is in"
 134        echo "*** your path, or set the SDL_CONFIG environment variable to the"
 135        echo "*** full path to sdl-config."
 136      else
 137        if test -f conf.sdltest ; then
 138         :
 139        else
 140           echo "*** Could not run SDL test program, checking why..."
 141           CFLAGS="$CFLAGS $SDL_CFLAGS"
 142           LIBS="$LIBS $SDL_LIBS"
 143           AC_TRY_LINK([
 144 #include <stdio.h>
 145 #include "SDL.h"
 146
 147 int main(int argc, char *argv[])
 148 { return 0; }
 149 #undef  main
 150 #define main K_and_R_C_main
 151 ],      [ return 0; ],
 152         [ echo "*** The test program compiled, but did not run. This usually means"
 153           echo "*** that the run-time linker is not finding SDL or finding the wrong"
 154           echo "*** version of SDL. If it is not finding SDL, you'll need to set your"
 155           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 156           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 157           echo "*** is required on your system"
 158           echo "***"
 159           echo "*** If you have an old version installed, it is best to remove it, although"
 160           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"],
 161         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 162           echo "*** exact error that occured. This usually means SDL was incorrectly installed"
 163           echo "*** or that you have moved SDL since it was installed. In the latter case, you"
 164           echo "*** may want to edit the sdl-config script: $SDL_CONFIG" ])
 165           CFLAGS="$ac_save_CFLAGS"
 166           LIBS="$ac_save_LIBS"
 167        fi
 168      fi
 169      SDL_CFLAGS=""
 170      SDL_LIBS=""
 171      ifelse([$3], , :, [$3])
 172   fi
 173   AC_SUBST(SDL_CFLAGS)
 174   AC_SUBST(SDL_LIBS)
 175   rm -f conf.sdltest
 176 ])