git.gag.com Git - debian/gnuradio/blob - config/grc_usrp2.m4

   1 dnl Copyright 2008 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_DEFUN([GRC_USRP2],[
  21     GRC_ENABLE(usrp2)
  22
  23     dnl firmware uses a subsidiary configure.ac
  24     AC_CONFIG_SUBDIRS([usrp2/firmware])
  25
  26     dnl Don't do usrp if omnithread or gruel is skipped
  27     GRC_CHECK_DEPENDENCY(usrp2, gruel)
  28     GRC_CHECK_DEPENDENCY(usrp2, omnithread)
  29
  30     dnl USRP2 host code only works on Linux at the moment
  31     AC_MSG_CHECKING([whether host_os is linux*])
  32     case "$host_os" in
  33       linux*)
  34         AC_MSG_RESULT([yes])
  35         ;;
  36       *)
  37         AC_MSG_RESULT([no])
  38         AC_MSG_NOTICE([USRP2 currently requires Linux host OS, not found])
  39         passed="no"
  40         ;;
  41     esac
  42
  43     dnl If execution gets to here, $passed will be:
  44     dnl   with : if the --with code didn't error out
  45     dnl   yes  : if the --enable code passed muster and all dependencies are met
  46     dnl   no   : otherwise
  47     if test $passed = yes; then
  48         dnl Needed for usrp2_socket_opener
  49         AC_CHECK_HEADERS(arpa/inet.h byteswap.h linux/if_packet.h sys/socket.h sys/un.h)
  50         AC_CHECK_MEMBERS([struct msghdr.msg_control,
  51                           struct msghdr.msg_accrights,
  52                           struct cmsgcred.cmcred_uid,
  53                           struct ucred.uid],
  54                          [],[],
  55                          [#define __USE_GNU 1
  56                           #include <sys/types.h>
  57                           #include <sys/socket.h>
  58                           #include <sys/un.h>])
  59     fi
  60     if test $passed != with; then
  61         dnl how and where to find INCLUDES and LA
  62         USRP2_INCLUDES="-I\${abs_top_srcdir}/usrp2/host/include \
  63                 -I\${abs_top_srcdir}/usrp2/firmware/include"
  64         USRP2_LA="\${abs_top_builddir}/usrp2/host/lib/libusrp2.la"
  65     fi
  66
  67     dnl Include the usrp2 INCLUDES and LA
  68     AC_SUBST(USRP2_INCLUDES)
  69     AC_SUBST(USRP2_LA)
  70
  71     AC_CONFIG_FILES([ \
  72         usrp2/Makefile
  73         usrp2/host/Makefile \
  74         usrp2/host/usrp2.pc \
  75         usrp2/host/include/Makefile
  76         usrp2/host/include/usrp2/Makefile
  77         usrp2/host/lib/Makefile
  78         usrp2/host/apps/Makefile
  79     ])
  80
  81     GRC_BUILD_CONDITIONAL(usrp2)
  82 ])