git.gag.com Git - debian/gnuradio/blob - config/grc_usrp.m4

   1 dnl Copyright 2001,2002,2003,2004,2005,2006,2007,2008,2009 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GNU Radio
   4 dnl
   5 dnl GNU Radio is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3, or (at your option)
   8 dnl any later version.
   9 dnl
  10 dnl GNU Radio is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GNU Radio; see the file COPYING.  If not, write to
  17 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  18 dnl Boston, MA 02110-1301, USA.
  19
  20 AC_DEFUN([GRC_USRP],[
  21     GRC_ENABLE(usrp)
  22
  23     GRC_WITH(usrp)
  24
  25     dnl Don't do usrp if omnithread skipped
  26     GRC_CHECK_DEPENDENCY(usrp, omnithread)
  27
  28     dnl Make sure the fast usb technique is set, OS dependent.
  29     dnl This is always performed, since it puts out CLI flags.
  30     USRP_SET_FUSB_TECHNIQUE(${enable_usrp})
  31
  32     dnl If execution gets to here, $passed will be:
  33     dnl   with : if the --with code didn't error out
  34     dnl   yes  : if the --enable code passed muster and all dependencies are met
  35     dnl   no   : otherwise
  36     if test $passed = yes; then
  37         dnl gnulib.
  38         dnl FIXME: this needs to fail gracefully and continue, not implemented yet
  39         UTILS_FUNC_MKSTEMP
  40
  41         dnl These checks don't fail
  42         AC_C_BIGENDIAN
  43         AC_CHECK_HEADERS([byteswap.h linux/compiler.h])
  44         AC_CHECK_FUNCS([getrusage sched_setscheduler pthread_setschedparam])
  45         AC_CHECK_FUNCS([sigaction snprintf])
  46
  47         dnl Make sure libusb is installed; required for legacy USB
  48         USRP_LIBUSB([],[passed=no;AC_MSG_RESULT([Unable to find dependency libusb.])])
  49
  50         dnl Make sure SDCC >= 2.4.0 is available.
  51         USRP_SDCC([2.4.0],[],[passed=no;AC_MSG_RESULT([Unable to find firmware compiler SDCC.])])
  52     fi
  53     if test $passed != with; then
  54         dnl how and where to find INCLUDES and LA
  55         usrp_INCLUDES="-I\${abs_top_srcdir}/usrp/host/lib/legacy \
  56                 -I\${abs_top_srcdir}/usrp/firmware/include \
  57                 -I\${abs_top_builddir}/usrp/host/lib/legacy"
  58         usrp_LA="\${abs_top_builddir}/usrp/host/lib/legacy/libusrp.la"
  59     fi
  60
  61     dnl There are 2 pkg-config files (usrp, and usrp-inband); the one
  62     dnl for usrp requires omnithread for Darwin only.  Create a variable
  63     dnl for just the usrp.pc.in case.
  64     case "$host_os" in
  65       darwin*)
  66         usrp_darwin_omnithread_pc_requires="gnuradio-omnithread"
  67         ;;
  68       *) dnl (blanks)
  69         usrp_darwin_omnithread_pc_requires=""
  70         ;;
  71     esac
  72     AC_SUBST(usrp_darwin_omnithread_pc_requires)
  73
  74     AC_CONFIG_FILES([ \
  75         usrp/Makefile \
  76         usrp/usrp.pc \
  77         usrp/usrp.iss \
  78         usrp/doc/Doxyfile \
  79         usrp/doc/Makefile \
  80         usrp/doc/other/Makefile \
  81         usrp/host/Makefile \
  82         usrp/host/misc/Makefile \
  83         usrp/host/lib/Makefile \
  84         usrp/host/lib/legacy/Makefile \
  85         usrp/host/lib/legacy/std_paths.h \
  86         usrp/host/swig/Makefile \
  87         usrp/host/apps/Makefile \
  88         usrp/firmware/Makefile \
  89         usrp/firmware/include/Makefile \
  90         usrp/firmware/lib/Makefile \
  91         usrp/firmware/src/Makefile \
  92         usrp/firmware/src/common/Makefile \
  93         usrp/firmware/src/usrp2/Makefile \
  94         usrp/fpga/Makefile \
  95         usrp/fpga/rbf/Makefile \
  96         usrp/fpga/rbf/rev2/Makefile \
  97         usrp/fpga/rbf/rev4/Makefile \
  98     ])
  99
 100     GRC_BUILD_CONDITIONAL(usrp)
 101 ])