git.gag.com Git - debian/gnuradio/blob - config/gr_set_md_cpu.m4

   1 dnl
   2 dnl Copyright 2003,2008 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GNU Radio
   5 dnl
   6 dnl GNU Radio is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3, or (at your option)
   9 dnl any later version.
  10 dnl
  11 dnl GNU Radio is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with GNU Radio; see the file COPYING.  If not, write to
  18 dnl the Free Software Foundation, Inc., 51 Franklin Street,
  19 dnl Boston, MA 02110-1301, USA.
  20 dnl
  21
  22 AC_DEFUN([_TRY_ADD_ALTIVEC],
  23 [
  24   LF_CHECK_CC_FLAG([-mabi=altivec -maltivec])
  25   LF_CHECK_CXX_FLAG([-mabi=altivec -maltivec])
  26 ])
  27
  28 AC_DEFUN([GR_SET_MD_CPU],[
  29   AC_REQUIRE([AC_CANONICAL_HOST])
  30   AC_ARG_WITH(md-cpu,
  31         AC_HELP_STRING([--with-md-cpu=ARCH],[set machine dependent speedups (auto)]),
  32                 [cf_with_md_cpu="$withval"],
  33                 [cf_with_md_cpu="$host_cpu"])
  34
  35   case "$cf_with_md_cpu" in
  36    x86 | i[[3-7]]86)    MD_CPU=x86      MD_SUBCPU=x86 ;;
  37    x86_64)              MD_CPU=x86      MD_SUBCPU=x86_64 ;;
  38    powerpc*)            MD_CPU=powerpc ;;
  39    *)                   MD_CPU=generic ;;
  40   esac
  41
  42   AC_ARG_ENABLE(altivec,
  43     AC_HELP_STRING([--enable-altivec],[enable altivec on PowerPC (yes)]),
  44     [ if test $MD_CPU = powerpc; then
  45         case "$enableval" in
  46           (no)  MD_CPU=generic ;;
  47           (yes) _TRY_ADD_ALTIVEC ;;
  48           (*) AC_MSG_ERROR([Invalid argument ($enableval) to --enable-altivec]) ;;
  49         esac
  50       fi],
  51     [ if test $MD_CPU = powerpc; then _TRY_ADD_ALTIVEC fi])
  52
  53
  54   AC_MSG_CHECKING([for machine dependent speedups])
  55   AC_MSG_RESULT($MD_CPU)
  56   AC_SUBST(MD_CPU)
  57   AC_SUBST(MD_SUBCPU)
  58
  59   AM_CONDITIONAL(MD_CPU_x86,     test "$MD_CPU" = "x86")
  60   AM_CONDITIONAL(MD_SUBCPU_x86_64,  test "$MD_SUBCPU" = "x86_64")
  61   AM_CONDITIONAL(MD_CPU_powerpc, test "$MD_CPU" = "powerpc")
  62   AM_CONDITIONAL(MD_CPU_generic, test "$MD_CPU" = "generic")
  63 ])