git.gag.com Git - debian/gnuradio/blob - config/acx_pthread.m4

   1 # ===========================================================================
   2 #              http://autoconf-archive.cryp.to/acx_pthread.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   ACX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   This macro figures out how to build C programs using POSIX threads. It
  12 #   sets the PTHREAD_LIBS output variable to the threads library and linker
  13 #   flags, and the PTHREAD_CFLAGS output variable to any special C compiler
  14 #   flags that are needed. (The user can also force certain compiler
  15 #   flags/libs to be tested by setting these environment variables.)
  16 #
  17 #   Also sets PTHREAD_CC to any special C compiler that is needed for
  18 #   multi-threaded programs (defaults to the value of CC otherwise). (This
  19 #   is necessary on AIX to use the special cc_r compiler alias.)
  20 #
  21 #   NOTE: You are assumed to not only compile your program with these flags,
  22 #   but also link it with them as well. e.g. you should link with
  23 #   $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS
  24 #
  25 #   If you are only building threads programs, you may wish to use these
  26 #   variables in your default LIBS, CFLAGS, and CC:
  27 #
  28 #          LIBS="$PTHREAD_LIBS $LIBS"
  29 #          CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  30 #          CC="$PTHREAD_CC"
  31 #
  32 #   In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute constant
  33 #   has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to that name
  34 #   (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
  35 #
  36 #   ACTION-IF-FOUND is a list of shell commands to run if a threads library
  37 #   is found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it
  38 #   is not found. If ACTION-IF-FOUND is not specified, the default action
  39 #   will define HAVE_PTHREAD.
  40 #
  41 #   Please let the authors know if this macro fails on any platform, or if
  42 #   you have any other suggestions or comments. This macro was based on work
  43 #   by SGJ on autoconf scripts for FFTW (http://www.fftw.org/) (with help
  44 #   from M. Frigo), as well as ac_pthread and hb_pthread macros posted by
  45 #   Alejandro Forero Cuervo to the autoconf macro repository. We are also
  46 #   grateful for the helpful feedback of numerous users.
  47 #
  48 # LAST MODIFICATION
  49 #
  50 #   2008-04-12
  51 #
  52 # COPYLEFT
  53 #
  54 #   Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
  55 #
  56 #   This program is free software: you can redistribute it and/or modify it
  57 #   under the terms of the GNU General Public License as published by the
  58 #   Free Software Foundation, either version 3 of the License, or (at your
  59 #   option) any later version.
  60 #
  61 #   This program is distributed in the hope that it will be useful, but
  62 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  63 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  64 #   Public License for more details.
  65 #
  66 #   You should have received a copy of the GNU General Public License along
  67 #   with this program. If not, see <http://www.gnu.org/licenses/>.
  68 #
  69 #   As a special exception, the respective Autoconf Macro's copyright owner
  70 #   gives unlimited permission to copy, distribute and modify the configure
  71 #   scripts that are the output of Autoconf when processing the Macro. You
  72 #   need not follow the terms of the GNU General Public License when using
  73 #   or distributing such scripts, even though portions of the text of the
  74 #   Macro appear in them. The GNU General Public License (GPL) does govern
  75 #   all other use of the material that constitutes the Autoconf Macro.
  76 #
  77 #   This special exception to the GPL applies to versions of the Autoconf
  78 #   Macro released by the Autoconf Macro Archive. When you make and
  79 #   distribute a modified version of the Autoconf Macro, you may extend this
  80 #   special exception to the GPL to apply to your modified version as well.
  81
  82 AC_DEFUN([ACX_PTHREAD], [
  83 AC_REQUIRE([AC_CANONICAL_HOST])
  84 AC_LANG_SAVE
  85 AC_LANG_C
  86 acx_pthread_ok=no
  87
  88 # We used to check for pthread.h first, but this fails if pthread.h
  89 # requires special compiler flags (e.g. on True64 or Sequent).
  90 # It gets checked for in the link test anyway.
  91
  92 # First of all, check if the user has set any of the PTHREAD_LIBS,
  93 # etcetera environment variables, and if threads linking works using
  94 # them:
  95 if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
  96         save_CFLAGS="$CFLAGS"
  97         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  98         save_LIBS="$LIBS"
  99         LIBS="$PTHREAD_LIBS $LIBS"
 100         AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
 101         AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
 102         AC_MSG_RESULT($acx_pthread_ok)
 103         if test x"$acx_pthread_ok" = xno; then
 104                 PTHREAD_LIBS=""
 105                 PTHREAD_CFLAGS=""
 106         fi
 107         LIBS="$save_LIBS"
 108         CFLAGS="$save_CFLAGS"
 109 fi
 110
 111 # We must check for the threads library under a number of different
 112 # names; the ordering is very important because some systems
 113 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
 114 # libraries is broken (non-POSIX).
 115
 116 # Create a list of thread flags to try.  Items starting with a "-" are
 117 # C compiler flags, and other items are library names, except for "none"
 118 # which indicates that we try without any flags at all, and "pthread-config"
 119 # which is a program returning the flags for the Pth emulation library.
 120
 121 acx_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
 122
 123 # The ordering *is* (sometimes) important.  Some notes on the
 124 # individual items follow:
 125
 126 # pthreads: AIX (must check this before -lpthread)
 127 # none: in case threads are in libc; should be tried before -Kthread and
 128 #       other compiler flags to prevent continual compiler warnings
 129 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
 130 # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
 131 # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
 132 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
 133 # -pthreads: Solaris/gcc
 134 # -mthreads: Mingw32/gcc, Lynx/gcc
 135 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
 136 #      doesn't hurt to check since this sometimes defines pthreads too;
 137 #      also defines -D_REENTRANT)
 138 #      ... -mt is also the pthreads flag for HP/aCC
 139 # pthread: Linux, etcetera
 140 # --thread-safe: KAI C++
 141 # pthread-config: use pthread-config program (for GNU Pth library)
 142
 143 case "${host_cpu}-${host_os}" in
 144         *solaris*)
 145
 146         # On Solaris (at least, for some versions), libc contains stubbed
 147         # (non-functional) versions of the pthreads routines, so link-based
 148         # tests will erroneously succeed.  (We need to link with -pthreads/-mt/
 149         # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
 150         # a function called by this macro, so we could check for that, but
 151         # who knows whether they'll stub that too in a future libc.)  So,
 152         # we'll just look for -pthreads and -lpthread first:
 153
 154         acx_pthread_flags="-pthreads pthread -mt -pthread $acx_pthread_flags"
 155         ;;
 156 esac
 157
 158 if test x"$acx_pthread_ok" = xno; then
 159 for flag in $acx_pthread_flags; do
 160
 161         case $flag in
 162                 none)
 163                 AC_MSG_CHECKING([whether pthreads work without any flags])
 164                 ;;
 165
 166                 -*)
 167                 AC_MSG_CHECKING([whether pthreads work with $flag])
 168                 PTHREAD_CFLAGS="$flag"
 169                 ;;
 170
 171                 pthread-config)
 172                 AC_CHECK_PROG(acx_pthread_config, pthread-config, yes, no)
 173                 if test x"$acx_pthread_config" = xno; then continue; fi
 174                 PTHREAD_CFLAGS="`pthread-config --cflags`"
 175                 PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
 176                 ;;
 177
 178                 *)
 179                 AC_MSG_CHECKING([for the pthreads library -l$flag])
 180                 PTHREAD_LIBS="-l$flag"
 181                 ;;
 182         esac
 183
 184         save_LIBS="$LIBS"
 185         save_CFLAGS="$CFLAGS"
 186         LIBS="$PTHREAD_LIBS $LIBS"
 187         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 188
 189         # Check for various functions.  We must include pthread.h,
 190         # since some functions may be macros.  (On the Sequent, we
 191         # need a special flag -Kthread to make this header compile.)
 192         # We check for pthread_join because it is in -lpthread on IRIX
 193         # while pthread_create is in libc.  We check for pthread_attr_init
 194         # due to DEC craziness with -lpthreads.  We check for
 195         # pthread_cleanup_push because it is one of the few pthread
 196         # functions on Solaris that doesn't have a non-functional libc stub.
 197         # We try pthread_create on general principles.
 198         AC_TRY_LINK([#include <pthread.h>],
 199                     [pthread_t th; pthread_join(th, 0);
 200                      pthread_attr_init(0); pthread_cleanup_push(0, 0);
 201                      pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],
 202                     [acx_pthread_ok=yes])
 203
 204         LIBS="$save_LIBS"
 205         CFLAGS="$save_CFLAGS"
 206
 207         AC_MSG_RESULT($acx_pthread_ok)
 208         if test "x$acx_pthread_ok" = xyes; then
 209                 break;
 210         fi
 211
 212         PTHREAD_LIBS=""
 213         PTHREAD_CFLAGS=""
 214 done
 215 fi
 216
 217 # Various other checks:
 218 if test "x$acx_pthread_ok" = xyes; then
 219         save_LIBS="$LIBS"
 220         LIBS="$PTHREAD_LIBS $LIBS"
 221         save_CFLAGS="$CFLAGS"
 222         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 223
 224         # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
 225         AC_MSG_CHECKING([for joinable pthread attribute])
 226         attr_name=unknown
 227         for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
 228             AC_TRY_LINK([#include <pthread.h>], [int attr=$attr; return attr;],
 229                         [attr_name=$attr; break])
 230         done
 231         AC_MSG_RESULT($attr_name)
 232         if test "$attr_name" != PTHREAD_CREATE_JOINABLE; then
 233             AC_DEFINE_UNQUOTED(PTHREAD_CREATE_JOINABLE, $attr_name,
 234                                [Define to necessary symbol if this constant
 235                                 uses a non-standard name on your system.])
 236         fi
 237
 238         AC_MSG_CHECKING([if more special flags are required for pthreads])
 239         flag=no
 240         case "${host_cpu}-${host_os}" in
 241             *-aix* | *-freebsd* | *-darwin*) flag="-D_THREAD_SAFE";;
 242             *solaris* | *-osf* | *-hpux*) flag="-D_REENTRANT";;
 243         esac
 244         AC_MSG_RESULT(${flag})
 245         if test "x$flag" != xno; then
 246             PTHREAD_CFLAGS="$flag $PTHREAD_CFLAGS"
 247         fi
 248
 249         LIBS="$save_LIBS"
 250         CFLAGS="$save_CFLAGS"
 251
 252         # More AIX lossage: must compile with xlc_r or cc_r
 253         if test x"$GCC" != xyes; then
 254           AC_CHECK_PROGS(PTHREAD_CC, xlc_r cc_r, ${CC})
 255         else
 256           PTHREAD_CC=$CC
 257         fi
 258 else
 259         PTHREAD_CC="$CC"
 260 fi
 261
 262 AC_SUBST(PTHREAD_LIBS)
 263 AC_SUBST(PTHREAD_CFLAGS)
 264 AC_SUBST(PTHREAD_CC)
 265
 266 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
 267 if test x"$acx_pthread_ok" = xyes; then
 268         ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
 269         :
 270 else
 271         acx_pthread_ok=no
 272         $2
 273 fi
 274 AC_LANG_RESTORE
 275 ])dnl ACX_PTHREAD