git.gag.com Git - debian/cc1111/blob - support/cpp/configure.in

   1 # configure.in for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   5
   6 #This file is part of GCC.
   7
   8 #GCC is free software; you can redistribute it and/or modify it under
   9 #the terms of the GNU General Public License as published by the Free
  10 #Software Foundation; either version 2, or (at your option) any later
  11 #version.
  12
  13 #GCC is distributed in the hope that it will be useful, but WITHOUT
  14 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  15 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  16 #for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING.  If not, write to the Free
  20 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 #02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.60)
  25 AC_INIT(sdcpp.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for additional parameters
  34
  35 # With GNU ld
  36 AC_ARG_WITH(gnu-ld,
  37 [  --with-gnu-ld           arrange to work with GNU ld.],
  38 gnu_ld_flag="$with_gnu_ld",
  39 gnu_ld_flag=no)
  40
  41 # With pre-defined ld
  42 AC_ARG_WITH(ld,
  43 [  --with-ld               arrange to use the specified ld (full pathname)],
  44 DEFAULT_LINKER="$with_ld")
  45 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  46   if test ! -x "$DEFAULT_LINKER"; then
  47     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
  48   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
  49     gnu_ld_flag=yes
  50   fi
  51   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
  52         [Define to enable the use of a default linker.])
  53 fi
  54
  55 # With GNU as
  56 AC_ARG_WITH(gnu-as,
  57 [  --with-gnu-as           arrange to work with GNU as],
  58 gas_flag="$with_gnu_as",
  59 gas_flag=no)
  60
  61 AC_ARG_WITH(as,
  62 [  --with-as               arrange to use the specified as (full pathname)],
  63 DEFAULT_ASSEMBLER="$with_as")
  64 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
  65   if test ! -x "$DEFAULT_ASSEMBLER"; then
  66     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
  67   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
  68     gas_flag=yes
  69   fi
  70   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
  71         [Define to enable the use of a default assembler.])
  72 fi
  73
  74 # With stabs
  75 AC_ARG_WITH(stabs,
  76 [  --with-stabs            arrange to use stabs instead of host debug format],
  77 stabs="$with_stabs",
  78 stabs=no)
  79
  80 # With ELF
  81 AC_ARG_WITH(elf,
  82 [  --with-elf              arrange to use ELF instead of host debug format],
  83 elf="$with_elf",
  84 elf=no)
  85
  86 # Specify the local prefix
  87 local_prefix=
  88 AC_ARG_WITH(local-prefix,
  89 [  --with-local-prefix=DIR specifies directory to put local include],
  90 [case "${withval}" in
  91 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
  92 no)     ;;
  93 *)      local_prefix=$with_local_prefix ;;
  94 esac])
  95
  96 # Default local prefix if it is empty
  97 if test x$local_prefix = x; then
  98         local_prefix=/usr/local
  99 fi
 100
 101 AC_ARG_PROGRAM
 102
 103 # Enable Multibyte Characters for C/C++
 104 AC_ARG_ENABLE(c-mbchar,
 105 [  --enable-c-mbchar       enable multibyte characters for C and C++],
 106 if test x$enable_c_mbchar != xno; then
 107   AC_DEFINE(MULTIBYTE_CHARS, 1,
 108   [Define if you want the C and C++ compilers to support multibyte
 109    character sets for source code.])
 110 fi)
 111
 112 # Find the native compiler
 113 AC_PROG_CC
 114 AC_PROG_CC_C_O
 115 # autoconf is lame and doesn't give us any substitution variable for this.
 116 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 117   NO_MINUS_C_MINUS_O=yes
 118 else
 119   OUTPUT_OPTION='-o $@'
 120 fi
 121 AC_SUBST(NO_MINUS_C_MINUS_O)
 122 AC_SUBST(OUTPUT_OPTION)
 123
 124 AC_PROG_CPP
 125 AC_C_INLINE
 126
 127 gcc_AC_C__BOOL
 128
 129 # sizeof(char) is 1 by definition.
 130 gcc_AC_COMPILE_CHECK_SIZEOF(short)
 131 gcc_AC_COMPILE_CHECK_SIZEOF(int)
 132 gcc_AC_COMPILE_CHECK_SIZEOF(long)
 133
 134 gcc_AC_C_CHARSET
 135
 136 # If the native compiler is GCC, we can enable warnings even in stage1.
 137 # That's useful for people building cross-compilers, or just running a
 138 # quick `make'.
 139 warn_cflags=
 140 if test "x$GCC" = "xyes"; then
 141   warn_cflags='$(GCC_WARN_CFLAGS)'
 142 fi
 143 AC_SUBST(warn_cflags)
 144
 145 AC_PROG_MAKE_SET
 146
 147 AC_MSG_CHECKING([whether a default assembler was specified])
 148 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 149     if test x"$gas_flag" = x"no"; then
 150         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 151     else
 152         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 153     fi
 154 else
 155     AC_MSG_RESULT(no)
 156 fi
 157
 158 AC_MSG_CHECKING([whether a default linker was specified])
 159 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 160     if test x"$gnu_ld_flag" = x"no"; then
 161         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 162     else
 163         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 164     fi
 165 else
 166     AC_MSG_RESULT(no)
 167 fi
 168
 169 # Find some useful tools
 170 AC_PROG_AWK
 171 # We need awk to run opts.sh (to create options.c and options.h).
 172 # Bail out if it's missing.
 173 case ${AWK} in
 174   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 175 esac
 176
 177 gcc_AC_PROG_LN
 178 gcc_AC_PROG_LN_S
 179 AC_PROG_RANLIB
 180 gcc_AC_PROG_INSTALL
 181
 182 AC_HEADER_STDC
 183 AC_HEADER_TIME
 184 gcc_AC_HEADER_STDBOOL
 185 gcc_AC_HEADER_STRING
 186 AC_HEADER_SYS_WAIT
 187 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 188                  fcntl.h unistd.h sys/file.h sys/time.h \
 189                  sys/param.h sys/stat.h \
 190                  direct.h malloc.h)
 191
 192 # Check for thread headers.
 193
 194 # These tests can't be done till we know if we have limits.h.
 195 gcc_AC_C_CHAR_BIT
 196 gcc_AC_C_COMPILE_ENDIAN
 197
 198 # See if we have the mktemp command.
 199 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 200
 201 AC_CHECK_PROG(STRIP, strip, strip, :)
 202
 203 # See if the stage1 system preprocessor understands the ANSI C
 204 # preprocessor stringification operator.  (Used by symcat.h.)
 205 AC_C_STRINGIZE
 206
 207 dnl Disabled until we have a complete test for buggy enum bitfields.
 208 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 209
 210 AC_CHECK_FUNCS(clock strsignal strchr strrchr lstat)
 211
 212 AC_CHECK_TYPE(ssize_t, int)
 213
 214 AC_FUNC_MMAP_ANYWHERE
 215 AC_FUNC_MMAP_FILE
 216
 217 # We will need to find libiberty.h and ansidecl.h
 218 saved_CFLAGS="$CFLAGS"
 219 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 220 gcc_AC_CHECK_DECLS(getenv abort strsignal errno \
 221         malloc realloc calloc free clock, , ,[
 222 #include "ansidecl.h"
 223 #include "system.h"])
 224
 225 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 226 CFLAGS="$saved_CFLAGS"
 227
 228 # mkdir takes a single argument on some systems.
 229 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 230
 231 # File extensions
 232 manext='.1'
 233 objext='.o'
 234 AC_SUBST(manext)
 235 AC_SUBST(objext)
 236
 237 build_xm_file=
 238 build_xm_defines=
 239 build_install_headers_dir=install-headers-tar
 240 build_exeext=
 241 host_xm_file=
 242 host_xm_defines=
 243 host_xmake_file=
 244 host_truncate_target=
 245 host_exeext=
 246
 247 # Decode the host machine, then the target machine.
 248 # For the host machine, we save the xm_file variable as host_xm_file;
 249 # then we decode the target machine and forget everything else
 250 # that came from the host machine.
 251 #for machine in $build $host $target; do
 252 #       . ${srcdir}/config.gcc
 253 #done
 254
 255 extra_objs="${host_extra_objs} ${extra_objs}"
 256
 257 # Default the target-machine variables that were not explicitly set.
 258 if test x"$tm_file" = x
 259 then tm_file=$cpu_type/$cpu_type.h; fi
 260
 261 if test x"$extra_headers" = x
 262 then extra_headers=; fi
 263
 264 if test x$md_file = x
 265 then md_file=$cpu_type/$cpu_type.md; fi
 266
 267 if test x$out_file = x
 268 then out_file=$cpu_type/$cpu_type.c; fi
 269
 270 if test x"$tmake_file" = x
 271 then tmake_file=$cpu_type/t-$cpu_type
 272 fi
 273
 274 if test x"$dwarf2" = xyes
 275 then tm_file="$tm_file tm-dwarf2.h"
 276 fi
 277
 278 # Handle cpp installation.
 279 if test x$enable_cpp != xno
 280 then
 281   tmake_file="$tmake_file t-install-cpp"
 282 fi
 283
 284 # auto-host.h is the file containing items generated by autoconf and is
 285 # the first file included by config.h.
 286 # If host=build, it is correct to have hconfig include auto-host.h
 287 # as well.  If host!=build, we are in error and need to do more
 288 # work to find out the build config parameters.
 289 if test x$host = x$build
 290 then
 291         build_auto=auto-host.h
 292 else
 293         # We create a subdir, then run autoconf in the subdir.
 294         # To prevent recursion we set host and build for the new
 295         # invocation of configure to the build for this invocation
 296         # of configure.
 297         tempdir=build.$$
 298         rm -rf $tempdir
 299         mkdir $tempdir
 300         cd $tempdir
 301         case ${srcdir} in
 302         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
 303         *) realsrcdir=../${srcdir};;
 304         esac
 305         CC=${CC_FOR_BUILD} ${realsrcdir}/configure \
 306                 --target=$target --host=$build --build=$build
 307
 308         # We just finished tests for the build machine, so rename
 309         # the file auto-build.h in the gcc directory.
 310         mv auto-host.h ../auto-build.h
 311         cd ..
 312         rm -rf $tempdir
 313         build_auto=auto-build.h
 314 fi
 315
 316 tm_file="${tm_file} defaults.h"
 317 host_xm_file="auto-host.h ansidecl.h ${host_xm_file} ${tm_file}"
 318 build_xm_file="${build_auto} ansidecl.h ${build_xm_file} ${tm_file}"
 319 xm_file="ansidecl.h ${xm_file} ${tm_file}"
 320
 321 # Truncate the target if necessary
 322 if test x$host_truncate_target != x; then
 323         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 324 fi
 325
 326 # Get the version trigger filename from the toplevel
 327 if test "${with_gcc_version_trigger+set}" = set; then
 328         gcc_version_trigger=$with_gcc_version_trigger
 329 else
 330         gcc_version_trigger=${srcdir}/version.c
 331 fi
 332 changequote(,)dnl
 333 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
 334 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 335
 336 changequote([,])dnl
 337
 338 # Internationalization
 339 PACKAGE=sdcc
 340 VERSION="$gcc_version"
 341 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
 342         [Define to the name of the distribution.])
 343 AC_DEFINE_UNQUOTED(VERSION, "$VERSION",
 344         [Define to the version of the distribution.])
 345 AC_SUBST(PACKAGE)
 346 AC_SUBST(VERSION)
 347
 348 ALL_LINGUAS="sv"
 349
 350 # Get an absolute path to the GCC top-level source directory
 351 holddir=`pwd`
 352 cd $srcdir
 353 topdir=`pwd`
 354 cd $holddir
 355
 356 out_object_file=`basename $out_file .c`.o
 357
 358 # Figure out what assembler we will be using.
 359 AC_MSG_CHECKING(what assembler to use)
 360 gcc_cv_as=
 361 gcc_cv_gas_major_version=
 362 gcc_cv_gas_minor_version=
 363 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
 364 if test -x "$DEFAULT_ASSEMBLER"; then
 365         gcc_cv_as="$DEFAULT_ASSEMBLER"
 366 elif test -x "$AS"; then
 367         gcc_cv_as="$AS"
 368 elif test -x as$host_exeext; then
 369         # Build using assembler in the current directory.
 370         gcc_cv_as=./as$host_exeext
 371 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
 372         # Single tree build which includes gas.
 373         for f in $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
 374         do
 375 changequote(,)dnl
 376                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
 377 changequote([,])dnl
 378                 if test x$gcc_cv_gas_version != x; then
 379                         break
 380                 fi
 381         done
 382 changequote(,)dnl
 383         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
 384         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
 385 changequote([,])dnl
 386 fi
 387
 388 if test "x$gcc_cv_as" = x -a x$host = x$target; then
 389         # Native build.
 390         # Search the same directories that the installed compiler will
 391         # search.  Else we may find the wrong assembler and lose.  If we
 392         # do not find a suitable assembler binary, then try the user's
 393         # path.
 394         #
 395         # Also note we have to check MD_EXEC_PREFIX before checking the
 396         # user's path.  Unfortunately, there is no good way to get at the
 397         # value of MD_EXEC_PREFIX here.  So we do a brute force search
 398         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
 399         # to be fixed as part of the make/configure rewrite too.
 400
 401         if test "x$exec_prefix" = xNONE; then
 402                 if test "x$prefix" = xNONE; then
 403                         test_prefix=/usr/local
 404                 else
 405                         test_prefix=$prefix
 406                 fi
 407         else
 408                 test_prefix=$exec_prefix
 409         fi
 410
 411         # If the loop below does not find an assembler, then use whatever
 412         # one we can find in the users's path.
 413         # user's path.
 414         gcc_cv_as=as$host_exeext
 415
 416         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
 417                    $test_prefix/lib/gcc-lib/$target \
 418                    /usr/lib/gcc/$target/$gcc_version \
 419                    /usr/lib/gcc/$target \
 420                    $test_prefix/$target/bin/$target/$gcc_version \
 421                    $test_prefix/$target/bin \
 422                    /usr/libexec \
 423                    /usr/ccs/gcc \
 424                    /usr/ccs/bin \
 425                    /udk/usr/ccs/bin \
 426                    /bsd43/usr/lib/cmplrs/cc \
 427                    /usr/cross64/usr/bin \
 428                    /usr/lib/cmplrs/cc \
 429                    /sysv/usr/lib/cmplrs/cc \
 430                    /svr4/usr/lib/cmplrs/cc \
 431                    /usr/bin"
 432
 433         for dir in $test_dirs; do
 434                 if test -f $dir/as$host_exeext; then
 435                         gcc_cv_as=$dir/as$host_exeext
 436                         break;
 437                 fi
 438         done
 439 fi
 440 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
 441   AC_MSG_RESULT("newly built gas")
 442 else
 443   AC_MSG_RESULT($gcc_cv_as)
 444 fi
 445
 446 # Figure out what nm we will be using.
 447 AC_MSG_CHECKING(what nm to use)
 448 if test -x nm$host_exeext; then
 449         gcc_cv_nm=./nm$host_exeext
 450 elif test x$host = x$target; then
 451         # Native build.
 452         gcc_cv_nm=nm$host_exeext
 453 fi
 454 AC_MSG_RESULT($gcc_cv_nm)
 455
 456 dnl Very limited version of automake's enable-maintainer-mode
 457
 458 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
 459   dnl maintainer-mode is disabled by default
 460   AC_ARG_ENABLE(maintainer-mode,
 461 [  --enable-maintainer-mode
 462                           enable make rules and dependencies not useful
 463                           (and sometimes confusing) to the casual installer],
 464       maintainer_mode=$enableval,
 465       maintainer_mode=no)
 466
 467 AC_MSG_RESULT($maintainer_mode)
 468
 469 if test "$maintainer_mode" = "yes"; then
 470   MAINT=''
 471 else
 472   MAINT='#'
 473 fi
 474 AC_SUBST(MAINT)dnl
 475
 476 # These (without "all_") are set in each config-lang.in.
 477 # `language' must be a single word so is spelled singularly.
 478 all_stagestuff=
 479 all_outputs='Makefile'
 480 # List of language makefile fragments.
 481
 482 # Add the language fragments.
 483 # Languages are added via two mechanisms.  Some information must be
 484 # recorded in makefile variables, these are defined in config-lang.in.
 485 # We accumulate them and plug them into the main Makefile.
 486 # The other mechanism is a set of hooks for each of the main targets
 487 # like `clean', `install', etc.
 488
 489 language_fragments="Make-lang"
 490
 491 # Define variables host_canonical and build_canonical
 492 # because some Cygnus local changes in the Makefile depend on them.
 493 build_canonical=${build}
 494 host_canonical=${host}
 495 target_subdir=
 496 if test "${host}" != "${target}" ; then
 497     target_subdir=${target_alias}/
 498 fi
 499 AC_SUBST(build_canonical)
 500 AC_SUBST(host_canonical)
 501 AC_SUBST(target_subdir)
 502
 503 # Nothing to do for FLOAT_H, float_format already handled.
 504 objdir=`pwd`
 505 AC_SUBST(objdir)
 506
 507 # Substitute configuration variables
 508 AC_SUBST(all_stagestuff)
 509 AC_SUBST(build_exeext)
 510 AC_SUBST(build_install_headers_dir)
 511 AC_SUBST(build_xm_file_list)
 512 AC_SUBST(build_xm_file)
 513 AC_SUBST(build_xm_defines)
 514 AC_SUBST(check_languages)
 515 AC_SUBST(dep_host_xmake_file)
 516 AC_SUBST(dep_tmake_file)
 517 AC_SUBST(extra_c_flags)
 518 AC_SUBST(extra_headers_list)
 519 AC_SUBST(extra_objs)
 520 AC_SUBST(extra_parts)
 521 AC_SUBST(extra_passes)
 522 AC_SUBST(extra_programs)
 523 AC_SUBST(gcc_config_arguments)
 524 AC_SUBST(gcc_version)
 525 AC_SUBST(gcc_version_full)
 526 AC_SUBST(gcc_version_trigger)
 527 AC_SUBST(host_exeext)
 528 AC_SUBST(host_extra_gcc_objs)
 529 AC_SUBST(install)
 530 AC_SUBST(lang_tree_files)
 531 AC_SUBST(local_prefix)
 532 AC_SUBST(md_file)
 533 AC_SUBST(out_file)
 534 AC_SUBST(out_object_file)
 535 AC_SUBST(symbolic_link)
 536 AC_SUBST(thread_file)
 537 AC_SUBST(c_target_objs)
 538
 539 #AC_SUBST_FILE(target_overrides)
 540 #AC_SUBST_FILE(host_overrides)
 541 #AC_SUBST(cross_defines)
 542 #AC_SUBST_FILE(cross_overrides)
 543 #AC_SUBST_FILE(build_overrides)
 544
 545 # Create the Makefile
 546 # and configure language subdirectories
 547 AC_OUTPUT($all_outputs,
 548 [
 549 case x$CONFIG_HEADERS in
 550 xauto-host.h:config.in)
 551 echo > cstamp-h ;;
 552 esac
 553
 554 # Avoid having to add intl to our include paths.
 555 if test -f intl/libintl.h; then
 556   echo creating libintl.h
 557   echo '#include "intl/libintl.h"' >libintl.h
 558 fi
 559 ],
 560 [
 561 host='${host}'
 562 build='${build}'
 563 target='${target}'
 564 target_alias='${target_alias}'
 565 srcdir='${srcdir}'
 566 symbolic_link='${symbolic_link}'
 567 program_transform_set='${program_transform_set}'
 568 program_transform_name='${program_transform_name}'
 569 dep_host_xmake_file='${dep_host_xmake_file}'
 570 host_xmake_file='${host_xmake_file}'
 571 dep_tmake_file='${dep_tmake_file}'
 572 tmake_file='${tmake_file}'
 573 thread_file='${thread_file}'
 574 gcc_config_arguments='${gcc_config_arguments}'
 575 gcc_version='${gcc_version}'
 576 gcc_version_full='${gcc_version_full}'
 577 gcc_version_trigger='${gcc_version_trigger}'
 578 local_prefix='${local_prefix}'
 579 build_install_headers_dir='${build_install_headers_dir}'
 580 build_exeext='${build_exeext}'
 581 host_exeext='${host_exeext}'
 582 out_file='${out_file}'
 583 gdb_needs_out_file_path='${gdb_needs_out_file_path}'
 584 SET_MAKE='${SET_MAKE}'
 585 target_list='${target_list}'
 586 target_overrides='${target_overrides}'
 587 host_overrides='${host_overrides}'
 588 cross_defines='${cross_defines}'
 589 cross_overrides='${cross_overrides}'
 590 build_overrides='${build_overrides}'
 591 cpp_install_dir='${cpp_install_dir}'
 592 ])