X-Git-Url: https://git.gag.com/?p=fw%2Faltos;a=blobdiff_plain;f=src%2Fstm%2Faltos-loader.ld;fp=src%2Fstm%2Faltos-loader.ld;h=2d71b4eeeb070511e5a47a01b226f2ed2552687f;hp=0000000000000000000000000000000000000000;hb=c9c35b100c3fcae661501d2bf89eedc7fceb2e1c;hpb=a6887032b4d217bca5236ea15389218f10d69545

diff --git a/src/stm/altos-loader.ld b/src/stm/altos-loader.ld
new file mode 100644
index 00000000..2d71b4ee
--- /dev/null
+++ b/src/stm/altos-loader.ld
@@ -0,0 +1,72 @@
+/*
+ * Copyright © 2012 Keith Packard <keithp@keithp.com>
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; version 2 of the License.
+ *
+ * This program is distributed in the hope that it will be useful, but
+ * WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+ * General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License along
+ * with this program; if not, write to the Free Software Foundation, Inc.,
+ * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
+ */
+
+MEMORY {
+	rom (rx) : ORIGIN = 0x08000000, LENGTH = 8K
+	ram (!w) : ORIGIN = 0x20000000, LENGTH = 16K
+}
+
+INCLUDE registers.ld
+
+EXTERN (stm_interrupt_vector)
+
+SECTIONS {
+	/*
+	 * Rom contents
+	 */
+
+	.text ORIGIN(rom) : {
+		__text_start__ = .;
+		*(.interrupt)	/* Interrupt vectors */
+
+		. = ORIGIN(rom) + 0x100;
+
+		ao_romconfig.o(.romconfig*)
+		ao_product.o(.romconfig*)
+
+		*(.text*)	/* Executable code */
+		*(.rodata*)	/* Constants */
+
+	} > rom
+
+	.ARM.exidx : {
+		*(.ARM.exidx* .gnu.linkonce.armexidx.*)
+		__text_end__ = .;
+	} > rom
+
+	/* Data -- relocated to RAM, but written to ROM
+	 */
+	.data ORIGIN(ram) : AT (ADDR(.ARM.exidx) + SIZEOF (.ARM.exidx)) {
+		__data_start__ = .;
+		*(.data)	/* initialized data */
+		__data_end__ = .;
+		__bss_start__ = .;
+	} >ram
+
+	.bss : {
+		*(.bss)
+		*(COMMON)
+		__bss_end__ = .;
+	} >ram
+
+	PROVIDE(__stack__ = ORIGIN(ram) + LENGTH(ram));
+	PROVIDE(end = .);
+}
+
+ENTRY(start);
+
+