git.gag.com Git - fw/altos/blob - telegps/telegps-windows.nsi.in

   1 !addplugindir ../altosui/Instdrv/NSIS/Plugins
   2 !addincludedir ../altosui/Instdrv/NSIS/Includes
   3 !include x64.nsh
   4 !include java.nsh
   5 !include refresh-sh.nsh
   6
   7 !define REG_NAME        "TeleGPS"
   8 !define PROG_ID_TELEM   "altusmetrum.telegps.telem.1"
   9 !define PROG_ID_EEPROM  "altusmetrum.telegps.eeprom.1"
  10 !define FAT_NAME        "telegps-fat.jar"
  11 !define WIN_APP_ICON    "altusmetrum-telegps.ico"
  12 !define WIN_APP_EXE     "altusmetrum-telegps.exe"
  13 !define WIN_TELEM_EXE   "application-vnd.altusmetrum.telemetry.exe"
  14 !define WIN_EEPROM_EXE  "application-vnd.altusmetrum.eeprom.exe"
  15
  16 Name "${REG_NAME} Installer"
  17
  18 ; Default install directory
  19 InstallDir "$PROGRAMFILES\AltusMetrum"
  20
  21 ; Tell the installer where to re-install a new version
  22 InstallDirRegKey HKLM "Software\${REG_NAME}" "Install_Dir"
  23
  24 LicenseText "GNU General Public License Version 2"
  25 LicenseData "../COPYING"
  26
  27 ; Need admin privs for Vista or Win7
  28 RequestExecutionLevel admin
  29
  30 ShowInstDetails Show
  31
  32 ComponentText "${REG_NAME} Software and Driver Installer"
  33
  34 Function .onInit
  35         DetailPrint "Checking host operating system"
  36         ${If} ${RunningX64}
  37                 DetailPrint "Installer running on 64-bit host"
  38                 SetRegView 64
  39                 StrCpy $INSTDIR "$PROGRAMFILES64\AltusMetrum"
  40                 ${DisableX64FSRedirection}
  41         ${EndIf}
  42 FunctionEnd
  43
  44 Function un.onInit
  45         DetailPrint "Checking host operating system"
  46         ${If} ${RunningX64}
  47                 DetailPrint "Installer running on 64-bit host"
  48                 SetRegView 64
  49                 StrCpy $INSTDIR "$PROGRAMFILES64\AltusMetrum"
  50                 ${DisableX64FSRedirection}
  51         ${EndIf}
  52 FunctionEnd
  53
  54 ; Pages to present
  55
  56 Page license
  57 Page components
  58 Page directory
  59 Page instfiles
  60
  61 UninstPage uninstConfirm
  62 UninstPage instfiles
  63
  64 ; And the stuff to install
  65
  66 Section "Install Driver" InstDriver
  67
  68         InstDrv::InitDriverSetup /NOUNLOAD {4D36E96D-E325-11CE-BFC1-08002BE10318} AltusMetrumSerial
  69         Pop $0
  70         DetailPrint "InitDriverSetup: $0"
  71         InstDrv::DeleteOemInfFiles /NOUNLOAD
  72         InstDrv::CreateDevice /NOUNLOAD
  73
  74         SetOutPath $INSTDIR
  75         File "../altusmetrum.inf"
  76         File "../altusmetrum.cat"
  77
  78         ${DisableX64FSRedirection}
  79         IfFileExists $WINDIR\System32\PnPutil.exe 0 nopnp
  80                 ${DisableX64FSRedirection}
  81                 nsExec::ExecToLog '"$WINDIR\System32\PnPutil.exe" -i -a "$INSTDIR\altusmetrum.inf"'
  82                 Goto done
  83 nopnp:
  84                 InstDrv::InstallDriver /NOUNLOAD "$INSTDIR\altusmetrum.inf"
  85 done:
  86
  87 SectionEnd
  88
  89 Section "${REG_NAME} Application"
  90         Call DetectJRE
  91
  92         SetOutPath $INSTDIR
  93
  94         File "${FAT_NAME}"
  95         File "altoslib_@ALTOSLIB_VERSION@.jar"
  96         File "altosuilib_@ALTOSUILIB_VERSION@.jar"
  97         File "cmudict04.jar"
  98         File "cmulex.jar"
  99         File "cmu_time_awb.jar"
 100         File "cmutimelex.jar"
 101         File "cmu_us_kal.jar"
 102         File "en_us.jar"
 103         File "freetts.jar"
 104         File "jfreechart.jar"
 105         File "jcommon.jar"
 106         File "../icon/${WIN_APP_EXE}"
 107
 108         File "*.dll"
 109
 110         File "../icon/${WIN_APP_ICON}"
 111
 112         CreateShortCut "$SMPROGRAMS\${REG_NAME}.lnk" "$INSTDIR\${WIN_APP_EXE}" "" "$INSTDIR\${WIN_APP_ICON}"
 113 SectionEnd
 114
 115 Section "${REG_NAME} Desktop Shortcut"
 116         CreateShortCut "$DESKTOP\${REG_NAME}.lnk" "$INSTDIR\${WIN_APP_EXE}"  "" "$INSTDIR\${WIN_APP_ICON}"
 117 SectionEnd
 118
 119 Section "TeleGPS, TeleDongle and TeleBT Firmware"
 120
 121         SetOutPath $INSTDIR
 122
 123         File "../src/telegps-v1.0/telegps-v1.0-${VERSION}.ihx"
 124         File "../src/teledongle-v0.2/teledongle-v0.2-${VERSION}.ihx"
 125         File "../src/teledongle-v3.0/teledongle-v3.0-${VERSION}.ihx"
 126         File "../src/telebt-v1.0/telebt-v1.0-${VERSION}.ihx"
 127
 128 SectionEnd
 129
 130 Section "Documentation"
 131
 132         SetOutPath $INSTDIR
 133
 134         File "../doc/telegps.pdf"
 135         File "../doc/altos.pdf"
 136         File "../doc/telemetry.pdf"
 137 SectionEnd
 138
 139 Section "File Associations"
 140
 141         ${DisableX64FSRedirection}
 142
 143         SetOutPath $INSTDIR
 144
 145         File "../icon/${WIN_TELEM_EXE}"
 146         File "../icon/${WIN_EEPROM_EXE}"
 147
 148         DeleteRegKey HKCR "${PROG_ID_TELEM}"
 149         DeleteRegKey HKCR "${PROG_ID_EEPROM}"
 150
 151         DeleteRegKey   HKCR ".eeprom\${PROG_ID_EEPROM}"
 152         DeleteRegValue HKCR ".eeprom\OpenWithProgids" "${PROG_ID_EEPROM}"
 153         DeleteRegKey   HKCR ".telem\${PROG_ID_EEPROM}"
 154         DeleteRegValue HKCR ".telem\OpenWithProgids" "${PROG_ID_EEPROM}"
 155
 156         ; .eeprom elements
 157
 158         WriteRegStr HKCR "${PROG_ID_EEPROM}"            ""                              "Altus Metrum Log File"
 159         WriteRegStr HKCR "${PROG_ID_EEPROM}"            "FriendlyTypeName"              "Altus Metrum Log File"
 160         WriteRegStr HKCR "${PROG_ID_EEPROM}\CurVer"     ""                              "${PROG_ID_EEPROM}"
 161         WriteRegStr HKCR "${PROG_ID_EEPROM}\DefaultIcon" ""                             '"$INSTDIR\${WIN_EEPROM_EXE}",-101'
 162   WriteRegExpandStr HKCR "${PROG_ID_EEPROM}\shell\open\command" ""                      '"$INSTDIR\${WIN_APP_EXE}" "%1"'
 163
 164         WriteRegStr HKCR ".eeprom"                      ""                              "${PROG_ID_EEPROM}"
 165         WriteRegStr HKCR ".eeprom"                      "PerceivedType"                 "Altus Metrum Log File"
 166         WriteRegStr HKCR ".eeprom"                      "Content Type"                  "application/vnd.altusmetrum.eeprom"
 167
 168         WriteRegStr HKCR ".eeprom\OpenWithProgids"      "${PROG_ID_EEPROM}"             ""
 169         WriteRegStr HKCR ".eeprom\${PROG_ID_EEPROM}"    ""                              "${REG_NAME}"
 170
 171         ; .telem elements
 172
 173         WriteRegStr HKCR "${PROG_ID_TELEM}"             ""                              "Altus Metrum Telemetry File"
 174         WriteRegStr HKCR "${PROG_ID_TELEM}"             "FriendlyTypeName"              "Altus Metrum Telemetry File"
 175         WriteRegStr HKCR "${PROG_ID_TELEM}\CurVer"      ""                              "${PROG_ID_TELEM}"
 176         WriteRegStr HKCR "${PROG_ID_TELEM}\DefaultIcon" ""                              '"$INSTDIR\${WIN_TELEM_EXE}",-101'
 177   WriteRegExpandStr HKCR "${PROG_ID_TELEM}\shell\open\command" ""                       '"$INSTDIR\${WIN_APP_EXE}" "%1"'
 178
 179         WriteRegStr HKCR ".telem"                       ""                              "${PROG_ID_TELEM}"
 180         WriteRegStr HKCR ".telem"                       "PerceivedType"                 "Altus Metrum Telemetry File"
 181         WriteRegStr HKCR ".telem"                       "Content Type"                  "application/vnd.altusmetrum.telemetry"
 182
 183         WriteRegStr HKCR ".telem\OpenWithProgids"       "${PROG_ID_TELEM}"              ""
 184         WriteRegStr HKCR ".telem\${PROG_ID_TELEM}"      ""                              "${REG_NAME}"
 185
 186         Call RefreshShellIcons
 187 SectionEnd
 188
 189 Section "Uninstaller"
 190
 191         ; Deal with the uninstaller
 192
 193         ${DisableX64FSRedirection}
 194         SetOutPath $INSTDIR
 195
 196         ; Write the install path to the registry
 197         WriteRegStr HKLM "SOFTWARE\${REG_NAME}" "Install_Dir" "$INSTDIR"
 198
 199         ; Write the uninstall keys for windows
 200         WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\${REG_NAME}" "DisplayName" "${REG_NAME}"
 201         WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\${REG_NAME}" "UninstallString" '"$INSTDIR\uninstall-${REG_NAME}.exe"'
 202         WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\${REG_NAME}" "NoModify" "1"
 203         WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\${REG_NAME}" "NoRepair" "1"
 204
 205         WriteUninstaller "uninstall-${REG_NAME}.exe"
 206 SectionEnd
 207
 208 Section "Uninstall"
 209
 210         ${DisableX64FSRedirection}
 211
 212         DeleteRegKey   HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\${REG_NAME}"
 213         DeleteRegKey   HKLM "SOFTWARE\${REG_NAME}"
 214
 215         DetailPrint "Delete uninstall reg entries"
 216
 217         DeleteRegKey   HKCR "${PROG_ID_EEPROM}"
 218         DeleteRegKey   HKCR "${PROG_ID_TELEM}"
 219
 220         DeleteRegKey   HKCR ".eeprom\${PROG_ID_EEPROM}"
 221         DeleteRegValue HKCR ".eeprom\OpenWithProgids" "${PROG_ID_EEPROM}"
 222
 223         DeleteRegKey   HKCR ".telem\${PROG_ID_TELEM}"
 224         DeleteRegValue HKCR ".telem\OpenWithProgids" "${PROG_ID_TELEM}"
 225
 226         DetailPrint "Delete file association reg entries"
 227
 228         Delete "$INSTDIR\${FAT_NAME}"
 229         Delete "$INSTDIR\uninstall-${REG_NAME}.exe"
 230
 231         Delete "$INSTDIR\${WIN_APP_ICON}"
 232         Delete "$INSTDIR\${WIN_APP_EXE}"
 233
 234         ; Remove shortcuts, if any
 235         Delete "$SMPROGRAMS\${REG_NAME}.lnk"
 236         Delete "$DESKTOP\${REG_NAME}.lnk"
 237
 238         Call un.RefreshShellIcons
 239 SectionEnd