git.gag.com Git - fw/altos/blob - src/stmf0/altos-loader.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; either version 2 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful, but
  10  * WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License along
  15  * with this program; if not, write to the Free Software Foundation, Inc.,
  16  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17  */
  18
  19 MEMORY {
  20         rom : ORIGIN = 0x08000000, LENGTH = 4K
  21         ram : ORIGIN = 0x20000000, LENGTH = 6K
  22 }
  23
  24 INCLUDE registers.ld
  25
  26 EXTERN (stm_interrupt_vector)
  27
  28 SECTIONS {
  29         /*
  30          * Rom contents
  31          */
  32
  33         .interrupt : {
  34                 __text_start__ = .;
  35                 *(.interrupt)   /* Interrupt vectors */
  36         } > rom
  37
  38         .text ORIGIN(rom) + 0x100 : {
  39                 ao_romconfig.o(.romconfig*)
  40                 ao_product.o(.romconfig*)
  41
  42                 *(.text*)       /* Executable code */
  43                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  44                 *(.rodata*)     /* Constants */
  45         } > rom
  46         __text_end__ = .;
  47
  48         /* Boot data which must live at the start of ram so that
  49          * the application and bootloader share the same addresses.
  50          * This must be all uninitialized data
  51          */
  52         .boot ORIGIN(ram) + SIZEOF(.interrupt) (NOLOAD) : {
  53                 __boot_start__ = .;
  54                 *(.boot)
  55                 __boot_end__ = .;
  56         } >ram
  57
  58         /* Functions placed in RAM (required for flashing)
  59          *
  60          * Align to 8 bytes as that's what the ARM likes text
  61          * segment alignments to be, and if we don't, then
  62          * we end up with a mismatch between the location in
  63          * ROM and the desired location in RAM. I don't
  64          * entirely understand this, but at least this appears
  65          * to work...
  66          */
  67
  68         .textram BLOCK(8): {
  69                 _start__ = .;
  70                 __text_ram_start__ = .;
  71                 *(.ramtext)
  72                 __text_ram_end = .;
  73         } >ram AT>rom
  74
  75         /* Data -- relocated to RAM, but written to ROM.
  76          * also aligned to 8 bytes in case textram is empty
  77          */
  78         .data BLOCK(8): {
  79                 *(.data)        /* initialized data */
  80                 _end__ = .;
  81         } >ram AT>rom
  82
  83
  84         .bss : {
  85                 __bss_start__ = .;
  86                 *(.bss)
  87                 *(COMMON)
  88                 __bss_end__ = .;
  89         } >ram
  90
  91         PROVIDE(__stack__ = ORIGIN(ram) + LENGTH(ram));
  92         PROVIDE(end = .);
  93 }
  94
  95 ENTRY(start);
  96
  97