git.gag.com Git - fw/altos/blob - src/stm/altos.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom (rx) : ORIGIN = 0x08000000, LENGTH = 128K
  20         ram (!w) : ORIGIN = 0x20000000, LENGTH = 16K
  21 }
  22
  23 INCLUDE registers.ld
  24
  25 EXTERN (stm_interrupt_vector)
  26 C_STACK_SIZE = 512;
  27
  28 SECTIONS {
  29         . = ORIGIN(rom);
  30
  31         /*
  32          * Rom contents
  33          */
  34
  35         __text_start__ = .;
  36
  37         .text : {
  38                 *(.interrupt)   /* Interrupt vectors */
  39                 *(.text)        /* Executable code */
  40                 *(.rodata)      /* Constants */
  41         } > rom
  42
  43         .ARM.exidx : {
  44                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  45                 __text_end__ = .;
  46         } > rom
  47
  48         . = ORIGIN(ram);
  49         __data_start__ = .;
  50
  51         /* Data -- relocated to RAM, but written to ROM
  52          */
  53         .data : AT (ADDR(.ARM.exidx) + SIZEOF (.ARM.exidx)) {
  54                 *(.data)        /* initialized data */
  55                 __data_end__ = .;
  56                 __bss_start__ = .;
  57         } >ram
  58
  59         .bss : {
  60                 *(.bss)
  61                 *(COMMON)
  62                 __bss_end__ = .;
  63         } >ram
  64
  65         PROVIDE(__stack__ = . + C_STACK_SIZE);
  66         PROVIDE(end = .);
  67
  68 }
  69
  70 ENTRY(start);
  71
  72