git.gag.com Git - fw/altos/blob - src/stm/altos-loader.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom : ORIGIN = 0x08000000, LENGTH = 8K
  20         ram : ORIGIN = 0x20000000, LENGTH = 16K
  21 }
  22
  23 INCLUDE registers.ld
  24
  25 EXTERN (stm_interrupt_vector)
  26
  27 SECTIONS {
  28         /*
  29          * Rom contents
  30          */
  31
  32         .text : {
  33                 __text_start__ = .;
  34                 *(.interrupt)   /* Interrupt vectors */
  35
  36                 . = ORIGIN(rom) + 0x100;
  37
  38                 ao_romconfig.o(.romconfig*)
  39                 ao_product.o(.romconfig*)
  40
  41                 *(.text)        /* Executable code */
  42                 *(.rodata)      /* Constants */
  43
  44         } > rom
  45
  46         .ARM.exidx : {
  47                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  48         } > rom
  49         __text_end__ = .;
  50
  51         /* Functions placed in RAM (required for flashing) */
  52         .textram : {
  53                 __text_ram_start = .;
  54                 __data_start__ = .;
  55                 *(.text.ram)
  56                 . = ALIGN(4);
  57         } >ram AT>rom
  58         __text_ram_end = .;
  59
  60         /* Data -- relocated to RAM, but written to ROM
  61          */
  62         .data : {
  63                 *(.data)        /* initialized data */
  64                 . = ALIGN (4);
  65         } >ram AT>rom
  66         __data_end__ = .;
  67
  68         .bss : {
  69                 __bss_start__ = .;
  70                 *(.bss)
  71                 *(COMMON)
  72                 __bss_end__ = .;
  73         } >ram
  74
  75         PROVIDE(__stack__ = ORIGIN(ram) + LENGTH(ram));
  76         PROVIDE(end = .);
  77 }
  78
  79 ENTRY(start);
  80
  81