git.gag.com Git - fw/altos/blob - src/stm/altos-loader.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; either version 2 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful, but
  10  * WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License along
  15  * with this program; if not, write to the Free Software Foundation, Inc.,
  16  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17  */
  18
  19 MEMORY {
  20         rom : ORIGIN = 0x08000000, LENGTH = 4K
  21         ram : ORIGIN = 0x20000000, LENGTH = 16K
  22 }
  23
  24 INCLUDE registers.ld
  25
  26 EXTERN (stm_interrupt_vector)
  27
  28 SECTIONS {
  29         /*
  30          * Rom contents
  31          */
  32
  33         .text : {
  34                 __text_start__ = .;
  35                 *(.interrupt)   /* Interrupt vectors */
  36
  37                 . = ORIGIN(rom) + 0x100;
  38
  39                 ao_romconfig.o(.romconfig*)
  40                 ao_product.o(.romconfig*)
  41                 *(.text*)       /* Executable code */
  42                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  43                 *(.rodata*)     /* Constants */
  44         } > rom
  45         __text_end__ = .;
  46
  47         /* Boot data which must live at the start of ram so that
  48          * the application and bootloader share the same addresses.
  49          * This must be all uninitialized data
  50          */
  51         .boot (NOLOAD) : {
  52                 __boot_start__ = .;
  53                 *(.boot)
  54                 __boot_end__ = .;
  55         } >ram
  56
  57         /* Functions placed in RAM (required for flashing)
  58          *
  59          * Align to 8 bytes as that's what the ARM likes text
  60          * segment alignments to be, and if we don't, then
  61          * we end up with a mismatch between the location in
  62          * ROM and the desired location in RAM. I don't
  63          * entirely understand this, but at least this appears
  64          * to work...
  65          */
  66
  67         .textram BLOCK(8): {
  68                 _start__ = .;
  69                 __text_ram_start__ = .;
  70                 *(.ramtext)
  71                 __text_ram_end = .;
  72         } >ram AT>rom
  73
  74         /* Data -- relocated to RAM, but written to ROM
  75          * Also aligned to 8 bytes to agree with textram
  76          */
  77         .data BLOCK(8): {
  78                 *(.data)        /* initialized data */
  79                 _end__ = .;
  80         } >ram AT>rom
  81
  82
  83         .bss : {
  84                 __bss_start__ = .;
  85                 *(.bss)
  86                 *(COMMON)
  87                 __bss_end__ = .;
  88         } >ram
  89
  90         PROVIDE(__stack__ = ORIGIN(ram) + LENGTH(ram));
  91         PROVIDE(end = .);
  92 }
  93
  94 ENTRY(start);
  95
  96