git.gag.com Git - fw/altos/blob - src/stm/altos-application.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom (rx) : ORIGIN = 0x08002000, LENGTH = 120K
  20         ram (!w) : ORIGIN = 0x20000000, LENGTH = 16K
  21 }
  22
  23 INCLUDE registers.ld
  24
  25 EXTERN (stm_interrupt_vector)
  26
  27 SECTIONS {
  28         /*
  29          * Rom contents
  30          */
  31
  32         .text ORIGIN(rom) : {
  33                 __text_start__ = .;
  34                 *(.interrupt)   /* Interrupt vectors */
  35
  36                 . = ORIGIN(rom) + 0x100;
  37
  38
  39                 /* Ick. What I want is to specify the
  40                  * addresses of some global constants so
  41                  * that I can find them across versions
  42                  * of the application. I can't figure out
  43                  * how to make gnu ld do that, so instead
  44                  * we just load the two files that include
  45                  * these defines in the right order here and
  46                  * expect things to 'just work'. Don't change
  47                  * the contents of those files, ok?
  48                  */
  49                 ao_romconfig.o(.romconfig*)
  50                 ao_product.o(.romconfig*)
  51                 *(.text*)       /* Executable code */
  52                 *(.rodata*)     /* Constants */
  53
  54         } > rom
  55
  56         .ARM.exidx : {
  57                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  58         } > rom
  59         __text_end__ = .;
  60
  61         /* Boot data which must live at the start of ram so that
  62          * the application and bootloader share the same addresses.
  63          * This must be all uninitialized data
  64          */
  65         .boot (NOLOAD) : {
  66                 __boot_start__ = .;
  67                 *(.boot)
  68                 . = ALIGN(4);
  69                 __boot_end__ = .;
  70         } >ram
  71
  72         /* Data -- relocated to RAM, but written to ROM
  73          */
  74         .data : {
  75                 __data_start__ = .;
  76                 *(.data)        /* initialized data */
  77                 . = ALIGN(4);
  78                 __data_end__ = .;
  79         } >ram AT>rom
  80
  81         .bss : {
  82                 __bss_start__ = .;
  83                 *(.bss)
  84                 *(COMMON)
  85                 . = ALIGN(4);
  86                 __bss_end__ = .;
  87         } >ram
  88
  89         PROVIDE(__stack__ = ORIGIN(ram) + LENGTH(ram));
  90         PROVIDE(end = .);
  91 }
  92
  93 ENTRY(start);
  94
  95