git.gag.com Git - fw/altos/blob - src/pnpservo-v1/lambda.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; either version 2 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful, but
  10  * WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License along
  15  * with this program; if not, write to the Free Software Foundation, Inc.,
  16  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17  */
  18
  19 MEMORY {
  20         rom (rx) :   ORIGIN = 0x08001000, LENGTH = 25K
  21         flash (r):   ORIGIN = 0x08007400, LENGTH = 3k
  22         ram (!w) :   ORIGIN = 0x20000000, LENGTH = 6k - 128
  23         stack (!w) : ORIGIN = 0x20000000 + 6k - 128, LENGTH = 128
  24 }
  25
  26 INCLUDE registers.ld
  27
  28 EXTERN (stm_interrupt_vector)
  29
  30 SECTIONS {
  31         /*
  32          * Rom contents
  33          */
  34
  35         .interrupt ORIGIN(ram) : AT (ORIGIN(rom)) {
  36                 __interrupt_start__ = .;
  37                 __interrupt_rom__ = ORIGIN(rom);
  38                 *(.interrupt)   /* Interrupt vectors */
  39                 __interrupt_end__ = .;
  40         } > ram
  41
  42         .text ORIGIN(rom) + 0x100 : {
  43                 __text_start__ = .;
  44
  45                 /* Ick. What I want is to specify the
  46                  * addresses of some global constants so
  47                  * that I can find them across versions
  48                  * of the application. I can't figure out
  49                  * how to make gnu ld do that, so instead
  50                  * we just load the two files that include
  51                  * these defines in the right order here and
  52                  * expect things to 'just work'. Don't change
  53                  * the contents of those files, ok?
  54                  */
  55                 ao_romconfig.o(.romconfig*)
  56                 ao_product.o(.romconfig*)
  57
  58                 *(.text*)       /* Executable code */
  59                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  60                 *(.rodata*)     /* Constants */
  61
  62         } > rom
  63         __text_end__ = .;
  64
  65
  66         /* Boot data which must live at the start of ram so that
  67          * the application and bootloader share the same addresses.
  68          * This must be all uninitialized data
  69          */
  70         .boot (NOLOAD) : {
  71                 __boot_start__ = .;
  72                 *(.boot)
  73                 . = ALIGN(4);
  74                 __boot_end__ = .;
  75         } >ram
  76
  77         /* Functions placed in RAM (required for flashing)
  78          *
  79          * Align to 8 bytes as that's what the ARM likes text
  80          * segment alignments to be, and if we don't, then
  81          * we end up with a mismatch between the location in
  82          * ROM and the desired location in RAM. I don't
  83          * entirely understand this, but at least this appears
  84          * to work...
  85          */
  86
  87         .textram BLOCK(8): {
  88                 _start__ = .;
  89                 __text_ram_start__ = .;
  90                 *(.ramtext)
  91                 __text_ram_end = .;
  92         } >ram AT>rom
  93
  94         /* Data -- relocated to RAM, but written to ROM
  95          */
  96         .data : {
  97                 *(.data)        /* initialized data */
  98                 . = ALIGN(4);
  99                 _end__ = .;
 100         } >ram AT>rom
 101
 102         .bss : {
 103                 __bss_start__ = .;
 104                 *(.bss)
 105                 *(COMMON)
 106                 . = ALIGN(4);
 107                 __bss_end__ = .;
 108         } >ram
 109
 110         PROVIDE(end = .);
 111
 112         PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
 113
 114         __flash__ = ORIGIN(flash);
 115 }
 116
 117 ENTRY(start);