git.gag.com Git - fw/altos/blob - src/micropeak-v2.0/micropeak.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; either version 2 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful, but
  10  * WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License along
  15  * with this program; if not, write to the Free Software Foundation, Inc.,
  16  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17  */
  18
  19 MEMORY {
  20         rom (rx) :   ORIGIN = 0x08001000, LENGTH = 20K
  21         flash(rx) :  ORIGIN = 0x08006000, LENGTH = 8K
  22         ram (!w) :   ORIGIN = 0x20000000, LENGTH = 6k - 512
  23         stack (!w) : ORIGIN = 0x20000000 + 6k - 512, LENGTH = 512
  24 }
  25
  26 INCLUDE registers.ld
  27
  28 EXTERN (stm_interrupt_vector)
  29
  30 SECTIONS {
  31         /*
  32          * Rom contents
  33          */
  34
  35         .interrupt ORIGIN(ram) : AT (ORIGIN(rom)) {
  36                 __interrupt_start__ = .;
  37                 __interrupt_rom__ = ORIGIN(rom);
  38                 *(.interrupt)   /* Interrupt vectors */
  39                 __interrupt_end__ = .;
  40         } > ram
  41
  42         .text ORIGIN(rom) + 0x100 : {
  43                 __text_start__ = .;
  44
  45                 /* Ick. What I want is to specify the
  46                  * addresses of some global constants so
  47                  * that I can find them across versions
  48                  * of the application. I can't figure out
  49                  * how to make gnu ld do that, so instead
  50                  * we just load the two files that include
  51                  * these defines in the right order here and
  52                  * expect things to 'just work'. Don't change
  53                  * the contents of those files, ok?
  54                  */
  55                 ao_romconfig.o(.romconfig*)
  56                 ao_product.o(.romconfig*)
  57
  58                 *(.text*)       /* Executable code */
  59         } > rom
  60
  61         .ARM.exidx : {
  62                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  63         } > rom
  64
  65         .rodata : {
  66                 *(.rodata*)     /* Constants */
  67         } > rom
  68
  69         __text_end__ = .;
  70
  71         /* Boot data which must live at the start of ram so that
  72          * the application and bootloader share the same addresses.
  73          * This must be all uninitialized data
  74          */
  75         .boot (NOLOAD) : {
  76                 __boot_start__ = .;
  77                 *(.boot)
  78                 . = ALIGN(4);
  79                 __boot_end__ = .;
  80         } >ram
  81
  82         /* Functions placed in RAM (required for flashing)
  83          *
  84          * Align to 8 bytes as that's what the ARM likes text
  85          * segment alignments to be, and if we don't, then
  86          * we end up with a mismatch between the location in
  87          * ROM and the desired location in RAM. I don't
  88          * entirely understand this, but at least this appears
  89          * to work...
  90          */
  91
  92         .textram BLOCK(8): {
  93                 _start__ = .;
  94                 *(.ramtext)
  95         } >ram AT>rom
  96
  97         /* Data -- relocated to RAM, but written to ROM,
  98          * also aligned to 8 bytes to agree with textram
  99          */
 100         .data BLOCK(8): {
 101                 *(.data)        /* initialized data */
 102                 _end__ = .;
 103         } >ram AT>rom
 104
 105         .bss : {
 106                 __bss_start__ = .;
 107                 *(.bss)
 108                 *(COMMON)
 109                 . = ALIGN(4);
 110                 __bss_end__ = .;
 111         } >ram
 112
 113         PROVIDE(end = .);
 114
 115         PROVIDE(__flash__ = ORIGIN(flash));
 116         PROVIDE(__flash_end__ = ORIGIN(flash) + LENGTH(flash));
 117
 118         PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
 119 }
 120
 121 ENTRY(start);
 122
 123