git.gag.com Git - fw/altos/blob - src/lpc/altos.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom (rx) : ORIGIN = 0x00001000, LENGTH = 28K
  20         ram (!w) : ORIGIN = 0x10000000, LENGTH = 4K - 128
  21         usb (!x) : ORIGIN = 0x20004000 + 2K - 256, LENGTH = 256
  22         stack (!w) : ORIGIN = 0x10000000 + 4K - 128, LENGTH = 128
  23 }
  24
  25 INCLUDE registers.ld
  26
  27 EXTERN (lpc_interrupt_vector)
  28
  29 SECTIONS {
  30         /*
  31          * Rom contents
  32          */
  33
  34         .interrupt ORIGIN(ram) : AT (ORIGIN(rom)) {
  35                 __interrupt_start__ = .;
  36                 __interrupt_rom__ = ORIGIN(rom);
  37                 *(.interrupt)   /* Interrupt vectors */
  38                 __interrupt_end__ = .;
  39         } > ram
  40
  41         .text ORIGIN(rom) + 0x100 : {
  42                 __text_start__ = .;
  43
  44                 ao_romconfig.o(.romconfig*)
  45                 ao_product.o(.romconfig*)
  46
  47                 *(.text*)       /* Executable code */
  48                 *(.rodata*)     /* Constants */
  49
  50         } > rom
  51
  52         .ARM.exidx : {
  53                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  54                 __text_end__ = .;
  55         } > rom
  56
  57         /* Boot data which must live at the start of ram so that
  58          * the application and bootloader share the same addresses.
  59          * This must be all uninitialized data
  60          */
  61         .boot : {
  62                 __boot_start__ = .;
  63                 *(.boot)
  64                 . = ALIGN(4);
  65                 __boot_end__ = .;
  66         } >ram
  67
  68         /* Data -- relocated to RAM, but written to ROM
  69          */
  70         .data : AT (ADDR(.ARM.exidx) + SIZEOF (.ARM.exidx)) {
  71                 __data_start__ = .;
  72                 *(.data)        /* initialized data */
  73                 __data_end__ = .;
  74                 __bss_start__ = .;
  75         } >ram
  76
  77         .bss : {
  78                 __bss_start__ = .;
  79                 *(.bss)
  80                 *(COMMON)
  81                 __bss_end__ = .;
  82         } >ram
  83         PROVIDE(end = .);
  84
  85         PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
  86 }
  87
  88 ENTRY(start);
  89
  90