git.gag.com Git - fw/altos/blob - src/lpc/altos-standalone.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; either version 2 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful, but
  10  * WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License along
  15  * with this program; if not, write to the Free Software Foundation, Inc.,
  16  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17  */
  18
  19 MEMORY {
  20         rom (rx) : ORIGIN = 0x00000000, LENGTH = 32K
  21         ram (!w) : ORIGIN = 0x10000000, LENGTH = 4K - 128 - 32
  22         usb (!x) : ORIGIN = 0x20004000 + 2K - 256, LENGTH = 256
  23         stack (!w) : ORIGIN = 0x10000000 + 4K - 128 - 32, LENGTH = 128
  24 }
  25
  26 INCLUDE registers.ld
  27
  28 EXTERN (lpc_interrupt_vector)
  29
  30 SECTIONS {
  31         /*
  32          * Rom contents
  33          */
  34
  35         .text ORIGIN(rom) : {
  36                 __text_start__ = .;
  37                 *(.interrupt)   /* Interrupt vectors */
  38
  39                 . = ORIGIN(rom) + 0x100;
  40
  41                 ao_romconfig.o(.romconfig*)
  42                 ao_product.o(.romconfig*)
  43
  44                 *(.text*)       /* Executable code */
  45                 *(.rodata*)     /* Constants */
  46
  47         } > rom
  48
  49         .ARM.exidx : {
  50                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  51                 __text_end__ = .;
  52         } > rom
  53
  54         /* Boot data which must live at the start of ram so that
  55          * the application and bootloader share the same addresses.
  56          * This must be all uninitialized data
  57          */
  58         .boot (NOLOAD) : {
  59                 __boot_start__ = .;
  60                 *(.boot)
  61                 . = ALIGN(4);
  62                 __boot_end__ = .;
  63         } >ram
  64
  65         /* Data -- relocated to RAM, but written to ROM
  66          */
  67         .data ORIGIN(ram) : AT (ADDR(.ARM.exidx) + SIZEOF (.ARM.exidx)) {
  68                 _start__ = .;
  69                 *(.data)        /* initialized data */
  70                 _end__ = .;
  71                 __bss_start__ = .;
  72         } >ram
  73
  74         .bss : {
  75                 *(.bss)
  76                 *(COMMON)
  77                 __bss_end__ = .;
  78         } >ram
  79         PROVIDE(end = .);
  80
  81         PROVIDE(__stack__ = ORIGIN(stack) + LENGTH(stack));
  82 }
  83
  84 ENTRY(start);
  85
  86