git.gag.com Git - fw/altos/blob - src/lpc/altos-loader.ld

   1 /*
   2  * Copyright © 2012 Keith Packard <keithp@keithp.com>
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation; version 2 of the License.
   7  *
   8  * This program is distributed in the hope that it will be useful, but
   9  * WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11  * General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License along
  14  * with this program; if not, write to the Free Software Foundation, Inc.,
  15  * 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  16  */
  17
  18 MEMORY {
  19         rom : ORIGIN = 0x00000000, LENGTH = 4K
  20         ram : ORIGIN = 0x10000000, LENGTH = 4k - 128 - 32
  21         usb (!x) : ORIGIN = 0x20004000 + 2K - 256, LENGTH = 256
  22         stack (!w) : ORIGIN = 0x10000000 + 4K - 128 - 32, LENGTH = 128
  23 }
  24
  25 INCLUDE registers.ld
  26
  27 EXTERN (lpc_interrupt_vector)
  28
  29 SECTIONS {
  30         /*
  31          * Rom contents
  32          */
  33
  34         .interrupt : {
  35                 __text_start__ = .;
  36                 *(.interrupt)   /* Interrupt vectors */
  37
  38         } > rom
  39
  40         .text ORIGIN(rom) + 0x100 : {
  41                 ao_romconfig.o(.romconfig*)
  42                 ao_product.o(.romconfig*)
  43
  44                 *(.text*)       /* Executable code */
  45                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  46                 *(.rodata*)     /* Constants */
  47                 __text_end__ = .;
  48         } > rom
  49
  50         /* Boot data which must live at the start of ram so that
  51          * the application and bootloader share the same addresses.
  52          * This must be all uninitialized data
  53          */
  54         .boot ORIGIN(ram) + SIZEOF(.interrupt) (NOLOAD) : {
  55                 __boot_start__ = .;
  56                 *(.boot*)
  57                 __boot_end__ = .;
  58         } >ram
  59
  60         /* Data -- relocated to RAM, but written to ROM
  61          */
  62         .data : {
  63                 __data_start__ = .;
  64                 *(.data*)       /* initialized data */
  65                 __data_end__ = .;
  66         } >ram AT>rom
  67
  68
  69         .bss : {
  70                 __bss_start__ = .;
  71                 *(.bss*)
  72                 *(COMMON*)
  73                 __bss_end__ = .;
  74         } >ram
  75
  76         PROVIDE(__stack__ = ORIGIN(ram) + LENGTH(ram));
  77         PROVIDE(end = .);
  78 }
  79
  80 ENTRY(start);