git.gag.com Git - fw/altos/blob - configure.ac

   1 dnl
   2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
   3 dnl
   4 dnl  This program is free software; you can redistribute it and/or modify
   5 dnl  it under the terms of the GNU General Public License as published by
   6 dnl  the Free Software Foundation; either version 2 of the License, or
   7 dnl  (at your option) any later version.
   8 dnl
   9 dnl  This program is distributed in the hope that it will be useful, but
  10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 dnl  General Public License for more details.
  13 dnl
  14 dnl  You should have received a copy of the GNU General Public License along
  15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
  16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17 dnl
  18 dnl Process this file with autoconf to create configure.
  19
  20 AC_PREREQ(2.57)
  21 AC_INIT([altos], 1.9.2)
  22 ANDROID_VERSION=27
  23 AC_CONFIG_SRCDIR([src/kernel/ao.h])
  24 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  25 AM_MAINTAINER_MODE
  26
  27 RELEASE_DATE=2020-02-26
  28 AC_SUBST(RELEASE_DATE)
  29
  30 DOC_DATE=`LC_ALL=C date -d $RELEASE_DATE +'%d %b %Y'`
  31
  32 AC_SUBST(DOC_DATE)
  33
  34 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
  35 AC_SUBST(VERSION_DASH)
  36 AC_SUBST(ANDROID_VERSION)
  37
  38 dnl ==========================================================================
  39 dnl Java library versions
  40
  41 ALTOSUILIB_VERSION=14
  42 ALTOSLIB_VERSION=14
  43
  44 AC_SUBST(ALTOSLIB_VERSION)
  45 AC_DEFINE(ALTOSLIB_VERSION,$ALTOSLIB_VERSION,[Version of the AltosLib package])
  46 AC_SUBST(ALTOSUILIB_VERSION)
  47 AC_DEFINE(ALTOSUILIB_VERSION,$ALTOSUILIB_VERSION,[Version of the AltosUILib package])
  48
  49 dnl ==========================================================================
  50
  51 AM_CONFIG_HEADER(config.h)
  52
  53 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
  54         [Set freetts class path (default /usr/share/java)]),
  55         [FREETTS=$withval], [FREETTS=/usr/share/java])
  56
  57 AC_SUBST(FREETTS)
  58
  59 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
  60         [Set jfreechart class path (default /usr/share/java)]),
  61         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
  62
  63 AC_SUBST(JFREECHART)
  64
  65 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
  66         [Set jcommon class path (default /usr/share/java)]),
  67         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
  68
  69 AC_SUBST(JCOMMON)
  70
  71 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm=PATH],
  72         [Set jvm path for java builds (default searches in /usr/lib/jvm)]),
  73         [JVM=$withval], [JVM=auto])
  74
  75 if test "x$JVM" = "xauto"; then
  76         AC_MSG_CHECKING([JVM])
  77         for jvm in default-java java-6-openjdk java-7-openjdk java-8-openjdk java-9-openjdk java-10-openjdk java-11-openjdk java-12-openjdk java-13-openjdk java-6-sun java-8-openjdk-amd64; do
  78                 if test "x$JVM" = "xauto"; then
  79                         INCLUDE="/usr/lib/jvm/$jvm/include"
  80                         if test -f "$INCLUDE"/jni.h; then
  81                                 JVM=/usr/lib/jvm/"$jvm"
  82                         fi
  83                 fi
  84         done
  85         if test "x$JVM" = "xauto"; then
  86                 AC_MSG_ERROR([no JVM files found])
  87         fi
  88         AC_MSG_RESULT([$JVM])
  89 fi
  90
  91 AC_ARG_WITH(java-version, AS_HELP_STRING([--with-java-version=7],
  92                                          [Set java language compatibility version (default is 7)]),
  93            [JAVA_VERSION=$withval], [JAVA_VERSION=7])
  94
  95 JAVAC="$JVM"/bin/javac
  96 JAVA="$JVM"/bin/java
  97 JVM_INCLUDE="$JVM"/include
  98 JAVAC_VERSION_FLAGS="-target 1.$JAVA_VERSION -source 1.$JAVA_VERSION"
  99
 100 AC_SUBST(JAVAC)
 101 AC_SUBST(JAVA)
 102 AC_SUBST(JVM)
 103 AC_SUBST(JVM_INCLUDE)
 104 AC_SUBST(JAVAC_VERSION_FLAGS)
 105
 106
 107 AC_ARG_WITH(android, AS_HELP_STRING([--with-android=PATH],
 108         [Set android SDK path (default searches in a variety of places)]),
 109         [ANDROID_SDK=$withval], [ANDROID_SDK=${ANDROID_SDK:-auto}])
 110
 111 if test "x$ANDROID_SDK" = "xauto"; then
 112         AC_MSG_CHECKING([Android SDK])
 113         for sdk in ../android/android-sdk-linux ../android/android-sdk ../android-sdk ../android-sdk-linux $HOME/android; do
 114                 if test "x$ANDROID_SDK" = "xauto"; then
 115                         SDK="$sdk"
 116                         if test -f "$SDK/SDK Readme.txt"; then
 117                                 ANDROID_SDK=`readlink -m "$SDK"`
 118                         fi
 119                 fi
 120         done
 121         if test "x$ANDROID_SDK" = "xauto"; then
 122                 AC_MSG_NOTICE([no Android SDK found])
 123                 ANDROID_SDK=no
 124         fi
 125         AC_MSG_RESULT([$ANDROID_SDK])
 126 fi
 127 if test "x$ANDROID_SDK" != "xno"; then
 128         AC_MSG_CHECKING([Android SDK version])
 129         SDK_VERSION=`grep -i '^Pkg.Revision=' $ANDROID_SDK/tools/source.properties | cut -f2- -d= | sed s/^r//`
 130         SDK_MAJOR_VERSION="`echo $SDK_VERSION | sed 's/[[^0-9]].*//'`"
 131         if test "$SDK_MAJOR_VERSION" -lt 17 ; then
 132                 AC_MSG_NOTICE([SDK version $SDK_VERSION is too old. Need >= r17])
 133                 ANDROID_SDK=no
 134         else
 135                 AC_MSG_RESULT([$SDK_VERSION])
 136         fi
 137 fi
 138 if test "x$ANDROID_SDK" != "xno"; then
 139         AC_MSG_CHECKING([Android SDK API Level])
 140         if test -f "$ANDROID_SDK/platforms/android-10/source.properties"; then
 141                 API_LEVEL=`sed -ne 's/^AndroidVersion.ApiLevel=//p' $ANDROID_SDK/platforms/android-10/source.properties`
 142                 if test "$API_LEVEL" = "10"; then
 143                         AC_MSG_RESULT([$API_LEVEL])
 144                 else
 145                         AC_MSG_NOTICE([API Level 10 not installed correctly.])
 146                         ANDROID_SDK=no
 147                 fi
 148         else
 149                 AC_MSG_NOTICE([API Level 10 not installed, but is required.])
 150                 ANDROID_SDK=no
 151         fi
 152 fi
 153 if test "x$ANDROID_SDK" != "xno"; then
 154         AC_MSG_CHECKING([Android SDK required extras])
 155         if test -f "$ANDROID_SDK/extras/android/support/source.properties"; then
 156                 ANDROID_SUPPORT_LIB_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/android/support/source.properties`
 157                 if test -f "$ANDROID_SDK/extras/google/google_play_services/source.properties"; then
 158                         GOOGLE_PLAY_SERVICES_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/google/google_play_services/source.properties`
 159                         AC_MSG_RESULT([$ANDROID_SUPPORT_LIB_NAME, $GOOGLE_PLAY_SERVICES_NAME])
 160                 else
 161                         AC_MSG_NOTICE([Google Play Services library not installed.])
 162                         ANDROID_SDK=no
 163                 fi
 164         else
 165                 AC_MSG_NOTICE([Android Support Library not installed.])
 166                 ANDROID_SDK=no
 167         fi
 168 fi
 169
 170 ANDROID_RELEASE=no
 171 if test "x$ANDROID_SDK" != "xno"; then
 172         HAVE_ANDROID_SDK="yes"
 173         ANDROID_RELEASE=yes
 174 else
 175         HAVE_ANDROID_SDK="no"
 176 fi
 177
 178 AM_CONDITIONAL([ANDROID], [test x$ANDROID_SDK != xno])
 179 AM_CONDITIONAL([ANDROID_RELEASE], [test x$ANDROID_RELEASE = xyes])
 180
 181 AC_SUBST(ANDROID_SDK)
 182
 183 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
 184             [Set the directory to install the 'fat-install' distribution files to (defaults to no such target)]),
 185             [FATDIR=$withval], [FATDIR=none])
 186
 187 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
 188
 189 AC_SUBST(FATDIR)
 190
 191 AC_ARG_WITH(google-key, AS_HELP_STRING([--with-google-key=PATH],
 192             [Set the file to read the AltosDroid maps API key from (defaults to ~/altusmetrumllc/google-altosdroid-maps-api-key)]),
 193             [GOOGLEKEYFILE=$withval], [GOOGLEKEYFILE=$HOME/altusmetrumllc/google-altosdroid-maps-api-key])
 194
 195 if test -r "$GOOGLEKEYFILE" -a -s "$GOOGLEKEYFILE"; then
 196         GOOGLEKEY=`cat "$GOOGLEKEYFILE"`
 197         HAVE_GOOGLE_KEY="yes"
 198 else
 199         GOOGLEKEY='null'
 200         HAVE_GOOGLE_KEY="no"
 201 fi
 202
 203 WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs"
 204 AC_SUBST(WARN_CFLAGS)
 205
 206 AC_ARG_ENABLE(faketime, AS_HELP_STRING([--enable-faketime],
 207               [Use faketime program to ensure pdf files are reproducible (default=no)]),
 208               [FAKETIME=$enableval], [FAKETIME=no])
 209
 210 AM_CONDITIONAL(FAKETIME, [test x$FAKETIME = xyes])
 211
 212 AC_SUBST(GOOGLEKEY)
 213
 214 AC_PROG_CC
 215 AC_PROG_INSTALL
 216 AC_PROG_LN_S
 217 AC_PROG_LIBTOOL
 218 PKG_PROG_PKG_CONFIG
 219
 220 WARN_CFLAGS=""
 221 if test "x$GCC" = "xyes"; then
 222         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
 223         -Wmissing-prototypes -Wmissing-declarations \
 224         -Wnested-externs -fno-strict-aliasing"
 225         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
 226         [Can use #warning in C files])
 227 fi
 228 AC_SUBST(WARN_CFLAGS)
 229
 230 #
 231 # Configure ARM compiler for STM32L and LPC11U14
 232 #
 233
 234 AC_ARG_WITH([arm-cc],
 235             [AS_HELP_STRING([--with-arm-cc],
 236                             [Name of ARM C compiler])],
 237             [],
 238             [with_arm_cc=auto])
 239
 240 if test "x$with_arm_cc" != "xno"; then
 241         if test "x$with_arm_cc" = "xauto"; then
 242                 with_arm_cc="arm-none-eabi-gcc"
 243                 AC_CHECK_PROG([HAVE_ARM_CC],[$with_arm_cc], yes, no)
 244         else
 245                 HAVE_ARM_CC=yes
 246         fi
 247 else
 248         HAVE_ARM_CC=no
 249 fi
 250
 251 if test "x$HAVE_ARM_CC" = "xno"; then
 252         AC_MSG_WARN([Arm compiler not found, ARM binaries will not be built])
 253 else
 254         ARM_CC=$with_arm_cc
 255 fi
 256 AC_SUBST(HAVE_ARM_CC)
 257 AC_SUBST(ARM_CC)
 258
 259 if test "x$HAVE_ARM_CC" = "xyes"; then
 260         save_CC="$CC"
 261         save_CFLAGS="$CFLAGS"
 262         save_LIBS="$LIBS"
 263         CC="$ARM_CC"
 264         CFLAGS="-mthumb -mcpu=cortex-m0"
 265         LIBS="-ffreestanding -nostdlib"
 266         AC_LANG_PUSH([C])
 267
 268         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m0])
 269         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 270                           [HAVE_ARM_M0_CC=yes],
 271                           [HAVE_ARM_M0_CC=no])
 272         AC_MSG_RESULT([$HAVE_ARM_M0_CC])
 273
 274         CFLAGS="-mthumb -mcpu=cortex-m3"
 275         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m3])
 276         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 277                           [HAVE_ARM_M3_CC=yes],
 278                           [HAVE_ARM_M3_CC=no])
 279         AC_MSG_RESULT([$HAVE_ARM_M3_CC])
 280
 281         AC_LANG_POP([C])
 282         LIBS="$save_LIBS"
 283         CFLAGS="$save_CFLAGS"
 284         CC="$save_CC"
 285 else
 286         HAVE_ARM_M3_CC=no
 287         HAVE_ARM_M0_CC=no
 288 fi
 289 AC_SUBST(HAVE_ARM_M3_CC)
 290 AC_SUBST(HAVE_ARM_M0_CC)
 291
 292 if test "x$HAVE_ARM_M3_CC" = "xno"; then
 293         AC_MSG_WARN([No cortex-m3 arm compiler found, STM32L binaries will not be built])
 294 fi
 295
 296 if test "x$HAVE_ARM_M0_CC" = "xno"; then
 297         AC_MSG_WARN([No cortex-m0 arm compiler found, LPC11U14 binaries will not be built])
 298 fi
 299
 300 AC_ARG_WITH([newlib-nano],
 301             [AS_HELP_STRING([--with-newlib-nano],
 302                             [Root of newlib nano install])],
 303             [],
 304             [with_newlib_nano=auto])
 305
 306 HAVE_NEWLIB_NANO=no
 307 if test "x$with_newlib_nano" != "xno"; then
 308         if test "x$with_newlib_nano" = "xauto"; then
 309                 for d in /usr/local/lib/newlib-nano /usr/lib/newlib-nano; do
 310                         if test "x$with_newlib_nano" = "xauto" -a -d "$d"; then
 311                                 with_newlib_nano="$d"
 312                                 HAVE_NEWLIB_NANO=yes
 313                         fi
 314                 done
 315         else
 316                 HAVE_NEWLIB_NANO=yes
 317         fi
 318 fi
 319
 320 if test "x$HAVE_NEWLIB_NANO" = "xno"; then
 321         AC_MSG_WARN([No newlib-nano library found, ARM binaries will not be built])
 322         HAVE_ARM_M3_CC=no
 323         HAVE_ARM_M0_CC=no
 324 else
 325         NEWLIB_NANO="$with_newlib_nano"
 326 fi
 327
 328 AC_SUBST(HAVE_NEWLIB_NANO)
 329 AC_SUBST(NEWLIB_NANO)
 330
 331 #
 332 # Configure AVR compiler
 333 #
 334
 335 AC_ARG_WITH([avr-cc],
 336             [AS_HELP_STRING([--with-avr-cc],
 337                             [Name of AVR C compiler])],
 338             [],
 339             [with_avr_cc=auto])
 340
 341 if test "x$with_avr_cc" != "xno"; then
 342         if test "x$with_avr_cc" = "xauto"; then
 343                 with_avr_cc="avr-gcc"
 344                 AC_CHECK_PROG([HAVE_AVR_CC],[$with_avr_cc], yes, no)
 345         else
 346                 HAVE_AVR_CC=yes
 347         fi
 348 else
 349         HAVE_AVR_CC=no
 350 fi
 351
 352 AC_ARG_WITH([avr-objcopy],
 353             [AS_HELP_STRING([--with-avr-objcopy],
 354                             [Name of AVR objcopy])],
 355             [],
 356             [with_avr_objcopy=auto])
 357
 358 if test "x$with_avr_objcopy" != "xno"; then
 359         if test "x$with_avr_objcopy" = "xauto"; then
 360                 with_avr_objcopy="avr-objcopy"
 361                 AC_CHECK_PROG([HAVE_AVR_OBJCOPY],[$with_avr_objcopy], yes, no)
 362         else
 363                 HAVE_AVR_OBJCOPY=yes
 364         fi
 365 else
 366         HAVE_AVR_OBJCOPY=no
 367 fi
 368
 369 if test "x$HAVE_AVR_CC" = "xno" -o "x$HAVE_AVR_OBJCOPY" = "xno"; then
 370         AC_MSG_WARN([AVR compiler and objcopy not found, atmel binaries will not be built])
 371         HAVE_AVR_CC=no
 372 else
 373         save_CC="$CC"
 374         save_CFLAGS="$CFLAGS"
 375         save_LIBS="$LIBS"
 376
 377         CC="$with_avr_cc"
 378         CFLAGS="-mmcu=attiny85"
 379         AC_LANG_PUSH([C])
 380         AC_MSG_CHECKING([if ]$with_avr_cc[ can link programs])
 381         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 382                           [AVR_LINK=yes],
 383                           [AVR_LINK=no])
 384         AC_MSG_RESULT([$AVR_LINK])
 385         AC_LANG_POP([C])
 386
 387         LIBS="$save_LIBS"
 388         CFLAGS="$save_CFLAGS"
 389         CC="$save_CC"
 390
 391         if test "x$AVR_LINK" = xyes; then
 392                 AVR_CC=$with_avr_cc
 393                 AVR_OBJCOPY=$with_avr_objcopy
 394         else
 395                 HAVE_AVR_CC=no;
 396         fi
 397 fi
 398
 399 AC_SUBST(AVR_CC)
 400 AC_SUBST(AVR_OBJCOPY)
 401 AC_SUBST(HAVE_AVR_CC)
 402
 403 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
 404 if test "x$HAVE_NICKLE" = "xno"; then
 405         AC_MSG_ERROR([Please install nickle to build AltOs])
 406 fi
 407
 408 AC_CHECK_PROG([HAVE_ASCIIDOCTOR_PDF], [asciidoctor-pdf], yes, no)
 409 if test "x$HAVE_ASCIIDOCTOR_PDF" = "xno"; then
 410         AC_MSG_WARN([asciidoctor-pdf not found, PDF docs will not be built])
 411 fi
 412 AM_CONDITIONAL([ASCIIDOCTOR_PDF], [test x$HAVE_ASCIIDOCTOR_PDF != xno])
 413
 414 AC_ARG_WITH([strip-nondeterminism],
 415             [AS_HELP_STRING([--with-strip-nondeterminism],
 416                             [Name of non-deterministic build data stripping tool])],
 417             [],
 418             [with_strip_nondeterminism=auto])
 419
 420 if test "x$with_strip_nondeterminism" != "xno"; then
 421         if test "x$with_strip_nondeterminism" = "xauto"; then
 422                 with_strip_nondeterminism="strip-nondeterminism"
 423                 AC_CHECK_PROG([HAVE_STRIP_NONDETERMINISM],[$with_strip_nondeterminism], yes, no)
 424         else
 425                 HAVE_STRIP_NONDETERMINISM=yes
 426         fi
 427 else
 428         HAVE_STRIP_NONDETERMINISM=no
 429 fi
 430 AM_CONDITIONAL([STRIP_NONDETERMINISM], [test x$HAVE_STRIP_NONDETERMINISM != xno])
 431 AC_SUBST(STRIP_NONDETERMINISM, "$with_strip_nondeterminism")
 432
 433 PKG_CHECK_MODULES([JANSSON], [jansson])
 434
 435 AC_ARG_WITH([readline],
 436             [AS_HELP_STRING([--with-readline],
 437                               [enable readline functionality in ao-dbg @<:@default=auto@:>@])],
 438               [],
 439               [with_readline=auto])
 440
 441 LIBREADLINE_LIBS=
 442
 443 if test x"$with_readline" != "xno"; then
 444         AC_CHECK_LIB([readline], [main],
 445                       [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 446                        AC_DEFINE([HAVE_LIBREADLINE], [1],
 447                          [Define if you have libreadline])],
 448                       [if test "x$with_readline" != xauto; then
 449                          AC_MSG_ERROR([--with-readline was given, but test for readline failed])
 450                        fi],
 451                        -lncurses)
 452 fi
 453
 454 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
 455
 456 AC_CHECK_HEADERS(libelf.h libelf/libelf.h, [break])
 457 AC_CHECK_HEADERS(gelf.h libelf/gelf.h, [break])
 458
 459 AC_ARG_WITH([stlink],
 460             [AS_HELP_STRING([--with-stlink],
 461                             [Build tools that use the stlink library (default: auto)])],
 462             [],
 463             [with_stlink=auto])
 464
 465 if test x"$with_stlink" != "xno"; then
 466         PKG_CHECK_MODULES([STLINK], [stlink], [HAVE_STLINK=yes], [HAVE_STLINK=no])
 467         if test x"$HAVE_STLINK" = "xno" -a x"$with_stlink" != "xauto"; then
 468                 AC_MSG_ERROR([--with-stlink was given, but stlink was not found])
 469         fi
 470 else
 471         HAVE_STLINK=no
 472 fi
 473
 474 if test x"$HAVE_STLINK" = "xyes"; then
 475         AC_DEFINE(HAVE_STLINK,1,[Using STlink library])
 476 fi
 477
 478 AM_CONDITIONAL([LIBSTLINK], [test x$HAVE_STLINK = xyes])
 479
 480 AC_ARG_ENABLE([multi-arch],
 481               [AS_HELP_STRING([--enable-multi-arch],
 482                               [enable building both i386 and amd64 libraries (default=auto)])],
 483               [MULTI_ARCH=$enableval],
 484               [MULTI_ARCH=auto])
 485
 486 case x"$MULTI_ARCH" in
 487 xauto)
 488         arch=`uname -m`
 489         case x"$arch" in
 490         xx86_64|xi*86)
 491                 save_CFLAGS="$CFLAGS"
 492                 save_LIBS="$LIBS"
 493                 LIBS="-ldl"
 494                 CFLAGS="-m64"
 495                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 496                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 497                                 [M64_LINK=yes],
 498                                 [M64_LINK=no])
 499                 AC_MSG_RESULT([$M64_LINK])
 500                 CFLAGS="-m32"
 501                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 502                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 503                                 [M32_LINK=yes],
 504                                 [M32_LINK=no])
 505                 AC_MSG_RESULT([$M32_LINK])
 506                 CFLAGS="$save_CFLAGS"
 507                 LIBS="$save_LIBS"
 508                 case x"$M64_LINK"x"$M32_LINK" in
 509                 xyesxyes)
 510                         MULTI_ARCH=yes
 511                         ;;
 512                 *)
 513                         MULTI_ARCH=no
 514                         ;;
 515                 esac
 516                 ;;
 517         *)
 518                 MULTI_ARCH=no
 519                 ;;
 520         esac
 521         ;;
 522 xyes|xno)
 523         ;;
 524 *)
 525         MULTI_ARCH="no"
 526         ;;
 527 esac
 528
 529 AM_CONDITIONAL([MULTI_ARCH], [test x$MULTI_ARCH = xyes])
 530
 531 AC_ARG_ENABLE([install-shared-mime-info],
 532               [AS_HELP_STRING([--disable-install-shared-mime-info],
 533                               [disable installing shared mime info files (default=yes)])],
 534               [INSTALL_SHARED_MIME_INFO=$enableval],
 535               [INSTALL_SHARED_MIME_INFO=yes])
 536
 537 AM_CONDITIONAL([INSTALL_SHARED_MIME_INFO], [test x$INSTALL_SHARED_MIME_INFO = xyes])
 538
 539 AC_OUTPUT([
 540 Makefile
 541 src/Makedefs
 542 src/chaoskey-v1.0/org.altusmetrum.ChaosKey.metainfo.xml
 543 doc/Makefile
 544 altoslib/Makefile
 545 altoslib/AltosVersion.java
 546 icon/Makefile
 547 altosuilib/Makefile
 548 altosui/Makefile
 549 altosui/Info.plist
 550 altosui/altos-windows.nsi
 551 libaltos/Makefile
 552 micropeak/Makefile
 553 micropeak/Info.plist
 554 micropeak/micropeak-windows.nsi
 555 telegps/Makefile
 556 telegps/Info.plist
 557 telegps/telegps-windows.nsi
 558 altosdroid/Makefile
 559 altosdroid/local.properties
 560 altosdroid/app/src/main/AndroidManifest.xml
 561 altosdroid/app/build.gradle
 562 ao-tools/Makefile
 563 ao-tools/lib/Makefile
 564 ao-tools/ao-rawload/Makefile
 565 ao-tools/ao-dbg/Makefile
 566 ao-tools/ao-bitbang/Makefile
 567 ao-tools/ao-eeprom/Makefile
 568 ao-tools/ao-list/Makefile
 569 ao-tools/ao-load/Makefile
 570 ao-tools/ao-telem/Makefile
 571 ao-tools/ao-stmload/Makefile
 572 ao-tools/ao-send-telem/Makefile
 573 ao-tools/ao-sky-flash/Makefile
 574 ao-tools/ao-dumpflash/Makefile
 575 ao-tools/ao-edit-telem/Makefile
 576 ao-tools/ao-dump-up/Makefile
 577 ao-tools/ao-elftohex/Makefile
 578 ao-tools/ao-usbload/Makefile
 579 ao-tools/ao-flash/Makefile
 580 ao-tools/ao-test-igniter/Makefile
 581 ao-tools/ao-test-baro/Makefile
 582 ao-tools/ao-test-flash/Makefile
 583 ao-tools/ao-cal-accel/Makefile
 584 ao-tools/ao-cal-freq/Makefile
 585 ao-tools/ao-test-gps/Makefile
 586 ao-tools/ao-usbtrng/Makefile
 587 ao-tools/ao-makebin/Makefile
 588 ao-utils/Makefile
 589 map-server/Makefile
 590 map-server/altos-mapd/Makefile
 591 map-server/altos-map/Makefile
 592 map-server/altos-mapj/Makefile
 593 ])
 594
 595 echo ""
 596 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 597 echo ""
 598 echo "  Configuration"
 599 echo "    Arm compiler................: ${ARM_CC}"
 600 echo "    STM32L support..............: ${HAVE_ARM_M3_CC}"
 601 echo "    LPC11U14 support............: ${HAVE_ARM_M0_CC}"
 602 echo "    AVR compiler................: ${AVR_CC} ${AVR_OBJCOPY}"
 603 echo "    AVR support.................: ${HAVE_AVR_CC}"
 604 echo "    Android support.............: ${HAVE_ANDROID_SDK}"
 605 echo "    Android release support.....: ${ANDROID_RELEASE}"
 606 echo "    STlink support..............: ${HAVE_STLINK}"
 607 echo "    Newlib-nano support.........: ${NEWLIB_NANO}"
 608 echo "    i386 and amd64 libaltos.....: ${MULTI_ARCH}"
 609 echo "    install shared mime info....: ${INSTALL_SHARED_MIME_INFO}"
 610 echo "    Strip jar timestamps........: ${STRIP_NONDETERMINISM}"
 611 echo ""
 612 echo "  Java"
 613 echo "    freetts.....................: ${FREETTS}"
 614 echo "    jfreechart..................: ${JFREECHART}"
 615 echo "    jcommon.....................: ${JCOMMON}"
 616 echo "    JVM include.................: ${JVM_INCLUDE}"
 617 echo "    AltosDroid maps API key.....: ${HAVE_GOOGLE_KEY}"
 618 if test x${ANDROID_SDK} != "xno"; then
 619 echo ""
 620 echo "  Android path"
 621 echo "    Android SDK.................: ${ANDROID_SDK}"
 622 fi
 623 echo ""