git.gag.com Git - fw/altos/blob - configure.ac

   1 dnl
   2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
   3 dnl
   4 dnl  This program is free software; you can redistribute it and/or modify
   5 dnl  it under the terms of the GNU General Public License as published by
   6 dnl  the Free Software Foundation; either version 2 of the License, or
   7 dnl  (at your option) any later version.
   8 dnl
   9 dnl  This program is distributed in the hope that it will be useful, but
  10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 dnl  General Public License for more details.
  13 dnl
  14 dnl  You should have received a copy of the GNU General Public License along
  15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
  16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17 dnl
  18 dnl Process this file with autoconf to create configure.
  19
  20 AC_PREREQ(2.57)
  21 AC_INIT([altos], 1.8.7.1)
  22 ANDROID_VERSION=18
  23 AC_CONFIG_SRCDIR([src/kernel/ao.h])
  24 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  25 AM_MAINTAINER_MODE
  26
  27 RELEASE_DATE=2018-10-08
  28 AC_SUBST(RELEASE_DATE)
  29
  30 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
  31 AC_SUBST(VERSION_DASH)
  32 AC_SUBST(ANDROID_VERSION)
  33
  34 dnl ==========================================================================
  35 dnl Java library versions
  36
  37 ALTOSUILIB_VERSION=13
  38 ALTOSLIB_VERSION=13
  39
  40 AC_SUBST(ALTOSLIB_VERSION)
  41 AC_DEFINE(ALTOSLIB_VERSION,$ALTOSLIB_VERSION,[Version of the AltosLib package])
  42 AC_SUBST(ALTOSUILIB_VERSION)
  43 AC_DEFINE(ALTOSUILIB_VERSION,$ALTOSUILIB_VERSION,[Version of the AltosUILib package])
  44
  45 dnl ==========================================================================
  46
  47 AM_CONFIG_HEADER(config.h)
  48
  49 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
  50         [Set freetts class path (default /usr/share/java)]),
  51         [FREETTS=$withval], [FREETTS=/usr/share/java])
  52
  53 AC_SUBST(FREETTS)
  54
  55 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
  56         [Set jfreechart class path (default /usr/share/java)]),
  57         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
  58
  59 AC_SUBST(JFREECHART)
  60
  61 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
  62         [Set jcommon class path (default /usr/share/java)]),
  63         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
  64
  65 AC_SUBST(JCOMMON)
  66
  67 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm-include=PATH],
  68         [Set jvm include path for jni builds (default searches in /usr/lib/jvm)]),
  69         [JVM_INCLUDE=$withval], [JVM_INCLUDE=auto])
  70
  71 if test "x$JVM_INCLUDE" = "xauto"; then
  72         AC_MSG_CHECKING([JVM include files])
  73         for jvm in default-java java-6-openjdk java-6-sun; do
  74                 if test "x$JVM_INCLUDE" = "xauto"; then
  75                         INCLUDE="/usr/lib/jvm/$jvm/include"
  76                         if test -f "$INCLUDE"/jni.h; then
  77                                 JVM_INCLUDE="$INCLUDE"
  78                         fi
  79                 fi
  80         done
  81         if test "x$JVM_INCLUDE" = "xauto"; then
  82                 AC_MSG_ERROR([no JVM include files found])
  83         fi
  84         AC_MSG_RESULT([$JVM_INCLUDE])
  85 fi
  86
  87 AC_SUBST(JVM_INCLUDE)
  88
  89 AC_ARG_WITH(android, AS_HELP_STRING([--with-android=PATH],
  90         [Set android SDK path (default searches in a variety of places)]),
  91         [ANDROID_SDK=$withval], [ANDROID_SDK=${ANDROID_SDK:-auto}])
  92
  93 if test "x$ANDROID_SDK" = "xauto"; then
  94         AC_MSG_CHECKING([Android SDK])
  95         for sdk in ../android/android-sdk-linux ../android/android-sdk ../android-sdk ../android-sdk-linux $HOME/android; do
  96                 if test "x$ANDROID_SDK" = "xauto"; then
  97                         SDK="$sdk"
  98                         if test -f "$SDK/SDK Readme.txt"; then
  99                                 ANDROID_SDK=`readlink -m "$SDK"`
 100                         fi
 101                 fi
 102         done
 103         if test "x$ANDROID_SDK" = "xauto"; then
 104                 AC_MSG_NOTICE([no Android SDK found])
 105                 ANDROID_SDK=no
 106         fi
 107         AC_MSG_RESULT([$ANDROID_SDK])
 108 fi
 109 if test "x$ANDROID_SDK" != "xno"; then
 110         AC_MSG_CHECKING([Android SDK version])
 111         SDK_VERSION=`grep -i '^Pkg.Revision=' $ANDROID_SDK/tools/source.properties | cut -f2- -d= | sed s/^r//`
 112         SDK_MAJOR_VERSION="`echo $SDK_VERSION | sed 's/[[^0-9]].*//'`"
 113         if test "$SDK_MAJOR_VERSION" -lt 17 ; then
 114                 AC_MSG_NOTICE([SDK version $SDK_VERSION is too old. Need >= r17])
 115                 ANDROID_SDK=no
 116         else
 117                 AC_MSG_RESULT([$SDK_VERSION])
 118         fi
 119 fi
 120 if test "x$ANDROID_SDK" != "xno"; then
 121         AC_MSG_CHECKING([Android SDK API Level])
 122         if test -f "$ANDROID_SDK/platforms/android-10/source.properties"; then
 123                 API_LEVEL=`sed -ne 's/^AndroidVersion.ApiLevel=//p' $ANDROID_SDK/platforms/android-10/source.properties`
 124                 if test "$API_LEVEL" = "10"; then
 125                         AC_MSG_RESULT([$API_LEVEL])
 126                 else
 127                         AC_MSG_NOTICE([API Level 10 not installed correctly.])
 128                         ANDROID_SDK=no
 129                 fi
 130         else
 131                 AC_MSG_NOTICE([API Level 10 not installed, but is required.])
 132                 ANDROID_SDK=no
 133         fi
 134 fi
 135 if test "x$ANDROID_SDK" != "xno"; then
 136         AC_MSG_CHECKING([Android SDK required extras])
 137         if test -f "$ANDROID_SDK/extras/android/support/source.properties"; then
 138                 ANDROID_SUPPORT_LIB_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/android/support/source.properties`
 139                 if test -f "$ANDROID_SDK/extras/google/google_play_services/source.properties"; then
 140                         GOOGLE_PLAY_SERVICES_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/google/google_play_services/source.properties`
 141                         AC_MSG_RESULT([$ANDROID_SUPPORT_LIB_NAME, $GOOGLE_PLAY_SERVICES_NAME])
 142                 else
 143                         AC_MSG_NOTICE([Google Play Services library not installed.])
 144                         ANDROID_SDK=no
 145                 fi
 146         else
 147                 AC_MSG_NOTICE([Android Support Library not installed.])
 148                 ANDROID_SDK=no
 149         fi
 150 fi
 151
 152 ANDROID_RELEASE=no
 153 if test "x$ANDROID_SDK" != "xno"; then
 154         HAVE_ANDROID_SDK="yes"
 155         if test -f "$HOME/altusmetrumllc/google-play-release.keystore" -a -f "$HOME/altusmetrumllc/google-play-passphrase"; then
 156                 ANDROID_RELEASE=yes
 157         fi
 158 else
 159         HAVE_ANDROID_SDK="no"
 160 fi
 161
 162 AM_CONDITIONAL([ANDROID], [test x$ANDROID_SDK != xno])
 163 AM_CONDITIONAL([ANDROID_RELEASE], [test x$ANDROID_RELEASE = xyes])
 164
 165 AC_SUBST(ANDROID_SDK)
 166
 167 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
 168             [Set the directory to install the 'fat-install' distribution files to (defaults to no such target)]),
 169             [FATDIR=$withval], [FATDIR=none])
 170
 171 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
 172
 173 AC_SUBST(FATDIR)
 174
 175 AC_ARG_WITH(google-key, AS_HELP_STRING([--with-google-key=PATH],
 176             [Set the file to read the AltosDroid maps API key from (defaults to ~/altusmetrumllc/google-altosdroid-maps-api-key)]),
 177             [GOOGLEKEYFILE=$withval], [GOOGLEKEYFILE=$HOME/altusmetrumllc/google-altosdroid-maps-api-key])
 178
 179 if test -r "$GOOGLEKEYFILE" -a -s "$GOOGLEKEYFILE"; then
 180         GOOGLEKEY=`cat "$GOOGLEKEYFILE"`
 181         HAVE_GOOGLE_KEY="yes"
 182 else
 183         GOOGLEKEY='null'
 184         HAVE_GOOGLE_KEY="no"
 185 fi
 186
 187 AC_ARG_ENABLE(faketime, AS_HELP_STRING([--enable-faketime],
 188               [Use faketime program to ensure pdf files are reproducible (default=no)]),
 189               [FAKETIME=$enableval], [FAKETIME=no])
 190
 191 AM_CONDITIONAL(FAKETIME, [test x$FAKETIME = xyes])
 192
 193 AC_SUBST(GOOGLEKEY)
 194
 195 AC_PROG_CC
 196 AC_PROG_INSTALL
 197 AC_PROG_LN_S
 198 AC_PROG_LIBTOOL
 199 PKG_PROG_PKG_CONFIG
 200
 201 CFLAGS="-g"
 202 WARN_CFLAGS=""
 203 if test "x$GCC" = "xyes"; then
 204         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
 205         -Wmissing-prototypes -Wmissing-declarations \
 206         -Wnested-externs -fno-strict-aliasing"
 207         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
 208         [Can use #warning in C files])
 209 fi
 210 AC_SUBST(WARN_CFLAGS)
 211
 212 #
 213 # Configure ARM compiler for STM32L and LPC11U14
 214 #
 215
 216 AC_ARG_WITH([arm-cc],
 217             [AS_HELP_STRING([--with-arm-cc],
 218                             [Name of ARM C compiler])],
 219             [],
 220             [with_arm_cc=auto])
 221
 222 if test "x$with_arm_cc" != "xno"; then
 223         if test "x$with_arm_cc" = "xauto"; then
 224                 with_arm_cc="arm-none-eabi-gcc"
 225                 AC_CHECK_PROG([HAVE_ARM_CC],[$with_arm_cc], yes, no)
 226         else
 227                 HAVE_ARM_CC=yes
 228         fi
 229 else
 230         HAVE_ARM_CC=no
 231 fi
 232
 233 if test "x$HAVE_ARM_CC" = "xno"; then
 234         AC_MSG_WARN([Arm compiler not found, ARM binaries will not be built])
 235 else
 236         ARM_CC=$with_arm_cc
 237 fi
 238 AC_SUBST(HAVE_ARM_CC)
 239 AC_SUBST(ARM_CC)
 240
 241 if test "x$HAVE_ARM_CC" = "xyes"; then
 242         save_CC="$CC"
 243         save_CFLAGS="$CFLAGS"
 244         save_LIBS="$LIBS"
 245         CC="$ARM_CC"
 246         CFLAGS="-mthumb -mcpu=cortex-m0"
 247         LIBS="-ffreestanding -nostdlib"
 248         AC_LANG_PUSH([C])
 249
 250         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m0])
 251         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 252                           [HAVE_ARM_M0_CC=yes],
 253                           [HAVE_ARM_M0_CC=no])
 254         AC_MSG_RESULT([$HAVE_ARM_M0_CC])
 255
 256         CFLAGS="-mthumb -mcpu=cortex-m3"
 257         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m3])
 258         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 259                           [HAVE_ARM_M3_CC=yes],
 260                           [HAVE_ARM_M3_CC=no])
 261         AC_MSG_RESULT([$HAVE_ARM_M3_CC])
 262
 263         AC_LANG_POP([C])
 264         LIBS="$save_LIBS"
 265         CFLAGS="$save_CFLAGS"
 266         CC="$save_CC"
 267 else
 268         HAVE_ARM_M3_CC=no
 269         HAVE_ARM_M0_CC=no
 270 fi
 271 AC_SUBST(HAVE_ARM_M3_CC)
 272 AC_SUBST(HAVE_ARM_M0_CC)
 273
 274 if test "x$HAVE_ARM_M3_CC" = "xno"; then
 275         AC_MSG_WARN([No cortex-m3 arm compiler found, STM32L binaries will not be built])
 276 fi
 277
 278 if test "x$HAVE_ARM_M0_CC" = "xno"; then
 279         AC_MSG_WARN([No cortex-m0 arm compiler found, LPC11U14 binaries will not be built])
 280 fi
 281
 282 AC_ARG_WITH([newlib-nano],
 283             [AS_HELP_STRING([--with-newlib-nano],
 284                             [Root of newlib nano install])],
 285             [],
 286             [with_newlib_nano=auto])
 287
 288 HAVE_NEWLIB_NANO=no
 289 if test "x$with_newlib_nano" != "xno"; then
 290         if test "x$with_newlib_nano" = "xauto"; then
 291                 for d in /usr/local/lib/newlib-nano /usr/lib/newlib-nano; do
 292                         if test "x$with_newlib_nano" = "xauto" -a -d "$d"; then
 293                                 with_newlib_nano="$d"
 294                                 HAVE_NEWLIB_NANO=yes
 295                         fi
 296                 done
 297         else
 298                 HAVE_NEWLIB_NANO=yes
 299         fi
 300 fi
 301
 302 if test "x$HAVE_NEWLIB_NANO" = "xno"; then
 303         AC_MSG_WARN([No newlib-nano library found, ARM binaries will not be built])
 304         HAVE_ARM_M3_CC=no
 305         HAVE_ARM_M0_CC=no
 306 else
 307         NEWLIB_NANO="$with_newlib_nano"
 308 fi
 309
 310 AC_SUBST(HAVE_NEWLIB_NANO)
 311 AC_SUBST(NEWLIB_NANO)
 312
 313 #
 314 # Configure AVR compiler
 315 #
 316
 317 AC_ARG_WITH([avr-cc],
 318             [AS_HELP_STRING([--with-avr-cc],
 319                             [Name of AVR C compiler])],
 320             [],
 321             [with_avr_cc=auto])
 322
 323 if test "x$with_avr_cc" != "xno"; then
 324         if test "x$with_avr_cc" = "xauto"; then
 325                 with_avr_cc="avr-gcc"
 326                 AC_CHECK_PROG([HAVE_AVR_CC],[$with_avr_cc], yes, no)
 327         else
 328                 HAVE_AVR_CC=yes
 329         fi
 330 else
 331         HAVE_AVR_CC=no
 332 fi
 333
 334 AC_ARG_WITH([avr-objcopy],
 335             [AS_HELP_STRING([--with-avr-objcopy],
 336                             [Name of AVR objcopy])],
 337             [],
 338             [with_avr_objcopy=auto])
 339
 340 if test "x$with_avr_objcopy" != "xno"; then
 341         if test "x$with_avr_objcopy" = "xauto"; then
 342                 with_avr_objcopy="avr-objcopy"
 343                 AC_CHECK_PROG([HAVE_AVR_OBJCOPY],[$with_avr_objcopy], yes, no)
 344         else
 345                 HAVE_AVR_OBJCOPY=yes
 346         fi
 347 else
 348         HAVE_AVR_OBJCOPY=no
 349 fi
 350
 351 if test "x$HAVE_AVR_CC" = "xno" -o "x$HAVE_AVR_OBJCOPY" = "xno"; then
 352         AC_MSG_WARN([AVR compiler and objcopy not found, atmel binaries will not be built])
 353         HAVE_AVR_CC=no
 354 else
 355         save_CC="$CC"
 356         save_CFLAGS="$CFLAGS"
 357         save_LIBS="$LIBS"
 358
 359         CC="$with_avr_cc"
 360         CFLAGS="-mmcu=attiny85"
 361         AC_LANG_PUSH([C])
 362         AC_MSG_CHECKING([if ]$with_avr_cc[ can link programs])
 363         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 364                           [AVR_LINK=yes],
 365                           [AVR_LINK=no])
 366         AC_MSG_RESULT([$AVR_LINK])
 367         AC_LANG_POP([C])
 368
 369         LIBS="$save_LIBS"
 370         CFLAGS="$save_CFLAGS"
 371         CC="$save_CC"
 372
 373         if test "x$AVR_LINK" = xyes; then
 374                 AVR_CC=$with_avr_cc
 375                 AVR_OBJCOPY=$with_avr_objcopy
 376         else
 377                 HAVE_AVR_CC=no;
 378         fi
 379 fi
 380
 381 AC_SUBST(AVR_CC)
 382 AC_SUBST(AVR_OBJCOPY)
 383 AC_SUBST(HAVE_AVR_CC)
 384
 385 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
 386 if test "x$HAVE_NICKLE" = "xno"; then
 387         AC_MSG_ERROR([Please install nickle to build AltOs])
 388 fi
 389
 390 PKG_CHECK_MODULES([JANSSON], [jansson])
 391
 392 AC_ARG_WITH([readline],
 393             [AS_HELP_STRING([--with-readline],
 394                               [enable readline functionality in ao-dbg @<:@default=auto@:>@])],
 395               [],
 396               [with_readline=auto])
 397
 398 LIBREADLINE_LIBS=
 399
 400 if test x"$with_readline" != "xno"; then
 401         AC_CHECK_LIB([readline], [main],
 402                       [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 403                        AC_DEFINE([HAVE_LIBREADLINE], [1],
 404                          [Define if you have libreadline])],
 405                       [if test "x$with_readline" != xauto; then
 406                          AC_MSG_ERROR([--with-readline was given, but test for readline failed])
 407                        fi],
 408                        -lncurses)
 409 fi
 410
 411 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
 412
 413 AC_CHECK_HEADERS(libelf.h libelf/libelf.h, [break])
 414 AC_CHECK_HEADERS(gelf.h libelf/gelf.h, [break])
 415
 416 AC_ARG_WITH([stlink],
 417             [AS_HELP_STRING([--with-stlink],
 418                             [Build tools that use the stlink library (default: auto)])],
 419             [],
 420             [with_stlink=auto])
 421
 422 if test x"$with_stlink" != "xno"; then
 423         PKG_CHECK_MODULES([STLINK], [stlink], [HAVE_STLINK=yes], [HAVE_STLINK=no])
 424         if test x"$HAVE_STLINK" = "xno" -a x"$with_stlink" != "xauto"; then
 425                 AC_MSG_ERROR([--with-stlink was given, but stlink was not found])
 426         fi
 427 else
 428         HAVE_STLINK=no
 429 fi
 430
 431 if test x"$HAVE_STLINK" = "xyes"; then
 432         AC_DEFINE(HAVE_STLINK,1,[Using STlink library])
 433 fi
 434
 435 AM_CONDITIONAL([LIBSTLINK], [test x$HAVE_STLINK = xyes])
 436
 437 AC_ARG_ENABLE([multi-arch],
 438               [AS_HELP_STRING([--enable-multi-arch],
 439                               [enable building both i386 and amd64 libraries (default=auto)])],
 440               [MULTI_ARCH=$enableval],
 441               [MULTI_ARCH=auto])
 442
 443 case x"$MULTI_ARCH" in
 444 xauto)
 445         arch=`uname -m`
 446         case x"$arch" in
 447         xx86_64|xi*86)
 448                 save_CFLAGS="$CFLAGS"
 449                 save_LIBS="$LIBS"
 450                 LIBS="-ldl"
 451                 CFLAGS="-m64"
 452                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 453                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 454                                 [M64_LINK=yes],
 455                                 [M64_LINK=no])
 456                 AC_MSG_RESULT([$M64_LINK])
 457                 CFLAGS="-m32"
 458                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 459                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 460                                 [M32_LINK=yes],
 461                                 [M32_LINK=no])
 462                 AC_MSG_RESULT([$M32_LINK])
 463                 CFLAGS="$save_CFLAGS"
 464                 LIBS="$save_LIBS"
 465                 case x"$M64_LINK"x"$M32_LINK" in
 466                 xyesxyes)
 467                         MULTI_ARCH=yes
 468                         ;;
 469                 *)
 470                         MULTI_ARCH=no
 471                         ;;
 472                 esac
 473                 ;;
 474         *)
 475                 MULTI_ARCH=no
 476                 ;;
 477         esac
 478         ;;
 479 xyes|xno)
 480         ;;
 481 *)
 482         MULTI_ARCH="no"
 483         ;;
 484 esac
 485
 486 AM_CONDITIONAL([MULTI_ARCH], [test x$MULTI_ARCH = xyes])
 487
 488 AC_ARG_ENABLE([install-shared-mime-info],
 489               [AS_HELP_STRING([--disable-install-shared-mime-info],
 490                               [disable installing shared mime info files (default=yes)])],
 491               [INSTALL_SHARED_MIME_INFO=$enableval],
 492               [INSTALL_SHARED_MIME_INFO=yes])
 493
 494 AM_CONDITIONAL([INSTALL_SHARED_MIME_INFO], [test x$INSTALL_SHARED_MIME_INFO = xyes])
 495
 496 AC_OUTPUT([
 497 Makefile
 498 src/Makedefs
 499 src/chaoskey-v1.0/org.altusmetrum.ChaosKey.metainfo.xml
 500 doc/Makefile
 501 altoslib/Makefile
 502 altoslib/AltosVersion.java
 503 icon/Makefile
 504 altosuilib/Makefile
 505 altosui/Makefile
 506 altosui/Info.plist
 507 altosui/altos-windows.nsi
 508 libaltos/Makefile
 509 micropeak/Makefile
 510 micropeak/Info.plist
 511 micropeak/micropeak-windows.nsi
 512 telegps/Makefile
 513 telegps/Info.plist
 514 telegps/telegps-windows.nsi
 515 altosdroid/Makefile
 516 altosdroid/local.properties
 517 altosdroid/AndroidManifest.xml
 518 ao-tools/Makefile
 519 ao-tools/lib/Makefile
 520 ao-tools/ao-rawload/Makefile
 521 ao-tools/ao-dbg/Makefile
 522 ao-tools/ao-bitbang/Makefile
 523 ao-tools/ao-eeprom/Makefile
 524 ao-tools/ao-list/Makefile
 525 ao-tools/ao-load/Makefile
 526 ao-tools/ao-telem/Makefile
 527 ao-tools/ao-stmload/Makefile
 528 ao-tools/ao-send-telem/Makefile
 529 ao-tools/ao-sky-flash/Makefile
 530 ao-tools/ao-dumpflash/Makefile
 531 ao-tools/ao-edit-telem/Makefile
 532 ao-tools/ao-dump-up/Makefile
 533 ao-tools/ao-elftohex/Makefile
 534 ao-tools/ao-usbload/Makefile
 535 ao-tools/ao-flash/Makefile
 536 ao-tools/ao-test-igniter/Makefile
 537 ao-tools/ao-test-baro/Makefile
 538 ao-tools/ao-test-flash/Makefile
 539 ao-tools/ao-cal-accel/Makefile
 540 ao-tools/ao-cal-freq/Makefile
 541 ao-tools/ao-test-gps/Makefile
 542 ao-tools/ao-usbtrng/Makefile
 543 ao-tools/ao-chaosread/Makefile
 544 ao-tools/ao-makebin/Makefile
 545 ao-utils/Makefile
 546 map-server/Makefile
 547 map-server/altos-mapd/Makefile
 548 map-server/altos-map/Makefile
 549 map-server/altos-mapj/Makefile
 550 src/Version
 551 ])
 552
 553 echo ""
 554 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 555 echo ""
 556 echo "  Configuration"
 557 echo "    Arm compiler................: ${ARM_CC}"
 558 echo "    STM32L support..............: ${HAVE_ARM_M3_CC}"
 559 echo "    LPC11U14 support............: ${HAVE_ARM_M0_CC}"
 560 echo "    AVR compiler................: ${AVR_CC} ${AVR_OBJCOPY}"
 561 echo "    AVR support.................: ${HAVE_AVR_CC}"
 562 echo "    Android support.............: ${HAVE_ANDROID_SDK}"
 563 echo "    Android release support.....: ${ANDROID_RELEASE}"
 564 echo "    STlink support..............: ${HAVE_STLINK}"
 565 echo "    Newlib-nano support.........: ${NEWLIB_NANO}"
 566 echo "    i386 and amd64 libaltos.....: ${MULTI_ARCH}"
 567 echo "    install shared mime info....: ${INSTALL_SHARED_MIME_INFO}"
 568 echo ""
 569 echo "  Java"
 570 echo "    freetts.....................: ${FREETTS}"
 571 echo "    jfreechart..................: ${JFREECHART}"
 572 echo "    jcommon.....................: ${JCOMMON}"
 573 echo "    JVM include.................: ${JVM_INCLUDE}"
 574 echo "    AltosDroid maps API key.....: ${HAVE_GOOGLE_KEY}"
 575 if test x${ANDROID_SDK} != "xno"; then
 576 echo ""
 577 echo "  Android path"
 578 echo "    Android SDK.................: ${ANDROID_SDK}"
 579 fi
 580 echo ""