git.gag.com Git - fw/altos/blob - configure.ac

   1 dnl
   2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
   3 dnl
   4 dnl  This program is free software; you can redistribute it and/or modify
   5 dnl  it under the terms of the GNU General Public License as published by
   6 dnl  the Free Software Foundation; either version 2 of the License, or
   7 dnl  (at your option) any later version.
   8 dnl
   9 dnl  This program is distributed in the hope that it will be useful, but
  10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 dnl  General Public License for more details.
  13 dnl
  14 dnl  You should have received a copy of the GNU General Public License along
  15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
  16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17 dnl
  18 dnl Process this file with autoconf to create configure.
  19
  20 AC_PREREQ(2.57)
  21 AC_INIT([altos], 1.2.9.4)
  22 AC_CONFIG_SRCDIR([src/core/ao.h])
  23 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  24 AM_MAINTAINER_MODE
  25
  26 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
  27 AC_SUBST(VERSION_DASH)
  28
  29 dnl ==========================================================================
  30 dnl Java library versions
  31
  32 ALTOSUILIB_VERSION=1
  33 ALTOSLIB_VERSION=2
  34
  35 AC_SUBST(ALTOSLIB_VERSION)
  36 AC_DEFINE(ALTOSLIB_VERSION,$ALTOSLIB_VERSION,[Version of the AltosLib package])
  37 AC_SUBST(ALTOSUILIB_VERSION)
  38 AC_DEFINE(ALTOSUILIB_VERSION,$ALTOSUILIB_VERSION,[Version of the AltosUILib package])
  39
  40 dnl ==========================================================================
  41
  42 AM_CONFIG_HEADER(config.h)
  43
  44 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
  45         [Set freetts class path (default /usr/share/java)]),
  46         [FREETTS=$withval], [FREETTS=/usr/share/java])
  47
  48 AC_SUBST(FREETTS)
  49
  50 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
  51         [Set jfreechart class path (default /usr/share/java)]),
  52         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
  53
  54 AC_SUBST(JFREECHART)
  55
  56 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
  57         [Set jcommon class path (default /usr/share/java)]),
  58         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
  59
  60 AC_SUBST(JCOMMON)
  61
  62 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm-include=PATH],
  63         [Set jvm include path for jni builds (default searches in /usr/lib/jvm)]),
  64         [JVM_INCLUDE=$withval], [JVM_INCLUDE=auto])
  65
  66 if test "x$JVM_INCLUDE" = "xauto"; then
  67         AC_MSG_CHECKING([JVM include files])
  68         for jvm in default-java java-6-openjdk java-6-sun; do
  69                 if test "x$JVM_INCLUDE" = "xauto"; then
  70                         INCLUDE="/usr/lib/jvm/$jvm/include"
  71                         if test -f "$INCLUDE"/jni.h; then
  72                                 JVM_INCLUDE="$INCLUDE"
  73                         fi
  74                 fi
  75         done
  76         if test "x$JVM_INCLUDE" = "xauto"; then
  77                 AC_MSG_ERROR([no JVM include files found])
  78         fi
  79         AC_MSG_RESULT([$JVM_INCLUDE])
  80 fi
  81
  82 AC_SUBST(JVM_INCLUDE)
  83
  84 AC_ARG_WITH(android, AS_HELP_STRING([--with-android=PATH],
  85         [Set android SDK path (default searches in a variety of places)]),
  86         [ANDROID_SDK=$withval], [ANDROID_SDK=${ANDROID_SDK:-auto}])
  87
  88 if test "x$ANDROID_SDK" = "xauto"; then
  89         AC_MSG_CHECKING([Android SDK])
  90         for sdk in ../android/android-sdk-linux ../android/android-sdk ../android-sdk ../android-sdk-linux $HOME/android; do
  91                 if test "x$ANDROID_SDK" = "xauto"; then
  92                         SDK="$sdk"
  93                         if test -f "$SDK/SDK Readme.txt"; then
  94                                 ANDROID_SDK=`readlink -m "$SDK"`
  95                         fi
  96                 fi
  97         done
  98         if test "x$ANDROID_SDK" = "xauto"; then
  99                 AC_MSG_NOTICE([no Android SDK found])
 100                 ANDROID_SDK=no
 101         fi
 102         AC_MSG_RESULT([$ANDROID_SDK])
 103 fi
 104 if test "x$ANDROID_SDK" != "xno"; then
 105         AC_MSG_CHECKING([Android SDK version])
 106         SDK_VERSION=`grep -i '^Pkg.Revision=' $ANDROID_SDK/tools/source.properties | cut -f2- -d= | sed s/^r//`
 107         SDK_MAJOR_VERSION="`echo $SDK_VERSION | sed 's/[[^0-9]].*//'`"
 108         if test "$SDK_MAJOR_VERSION" -lt 17 ; then
 109                 AC_MSG_NOTICE([SDK version $SDK_VERSION is too old. Need >= r17])
 110                 ANDROID_SDK=no
 111         else
 112                 AC_MSG_RESULT([$SDK_VERSION])
 113         fi
 114 fi
 115 if test "x$ANDROID_SDK" != "xno"; then
 116         AC_MSG_CHECKING([Android SDK API Level])
 117         if test -f "$ANDROID_SDK/platforms/android-10/source.properties"; then
 118                 API_LEVEL=`sed -ne 's/^AndroidVersion.ApiLevel=//p' $ANDROID_SDK/platforms/android-10/source.properties`
 119                 if test "$API_LEVEL" = "10"; then
 120                         AC_MSG_RESULT([$API_LEVEL])
 121                 else
 122                         AC_MSG_NOTICE([API Level 10 not installed correctly.])
 123                         ANDROID_SDK=no
 124                 fi
 125         else
 126                 AC_MSG_NOTICE([API Level 10 not installed, but is required.])
 127                 ANDROID_SDK=no
 128         fi
 129 fi
 130 if test "x$ANDROID_SDK" != "xno"; then
 131         AC_MSG_CHECKING([Android SDK required extras])
 132         if test -f "$ANDROID_SDK/extras/android/support/source.properties"; then
 133                 ANDROID_SUPPORT_LIB_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/android/support/source.properties`
 134                 if test -f "$ANDROID_SDK/extras/google/google_play_services/source.properties"; then
 135                         GOOGLE_PLAY_SERVICES_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/google/google_play_services/source.properties`
 136                         AC_MSG_RESULT([$ANDROID_SUPPORT_LIB_NAME, $GOOGLE_PLAY_SERVICES_NAME])
 137                 else
 138                         AC_MSG_NOTICE([Google Play Services library not installed.])
 139                         ANDROID_SDK=no
 140                 fi
 141         else
 142                 AC_MSG_NOTICE([Android Support Library not installed.])
 143                 ANDROID_SDK=no
 144         fi
 145 fi
 146
 147 if test "x$ANDROID_SDK" != "xno"; then
 148         HAVE_ANDROID_SDK="yes"
 149 else
 150         HAVE_ANDROID_SDK="no"
 151 fi
 152
 153 AM_CONDITIONAL([ANDROID], [test x$ANDROID_SDK != xno])
 154
 155 AC_SUBST(ANDROID_SDK)
 156
 157 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
 158             [Set the directory to install the 'fat' distribution files to (defaults to not installing)]),
 159             [FATDIR=$withval], [FATDIR=none])
 160
 161 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
 162
 163 AC_SUBST(FATDIR)
 164
 165 AC_PROG_CC
 166 AC_PROG_INSTALL
 167 AC_PROG_LN_S
 168 AC_PROG_LIBTOOL
 169 PKG_PROG_PKG_CONFIG
 170
 171 CFLAGS="-g"
 172 WARN_CFLAGS=""
 173 if test "x$GCC" = "xyes"; then
 174         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
 175         -Wmissing-prototypes -Wmissing-declarations \
 176         -Wnested-externs -fno-strict-aliasing"
 177         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
 178         [Can use #warning in C files])
 179 fi
 180 AC_SUBST(WARN_CFLAGS)
 181
 182 #
 183 # Configure SDCC
 184 #
 185
 186 AC_ARG_WITH([sdcc],
 187             [AS_HELP_STRING([--with-sdcc],
 188                             [Name of SDCC])],
 189             [],
 190             [with_sdcc=auto])
 191
 192 if test "x$with_sdcc" != "xno"; then
 193         if test "x$with_sdcc" = "xauto"; then
 194                 with_sdcc="sdcc"
 195                 AC_CHECK_PROG([HAVE_SDCC],[$with_sdcc], yes, no)
 196         else
 197                 HAVE_SDCC=yes
 198         fi
 199 else
 200         HAVE_SDCC=no
 201 fi
 202
 203 if test "x$HAVE_SDCC" = "xno"; then
 204         AC_MSG_WARN([SDCC not found, cc1111 binaries will not be built])
 205 else
 206         SDCC=$with_sdcc
 207 fi
 208
 209 AC_SUBST(SDCC)
 210 AC_SUBST(HAVE_SDCC)
 211
 212 #
 213 # Configure ARM compiler for STM32L and LPC11U14
 214 #
 215
 216 AC_ARG_WITH([arm-cc],
 217             [AS_HELP_STRING([--with-arm-cc],
 218                             [Name of ARM C compiler])],
 219             [],
 220             [with_arm_cc=auto])
 221
 222 if test "x$with_arm_cc" != "xno"; then
 223         if test "x$with_arm_cc" = "xauto"; then
 224                 with_arm_cc="arm-none-eabi-gcc"
 225                 AC_CHECK_PROG([HAVE_ARM_CC],[$with_arm_cc], yes, no)
 226         else
 227                 HAVE_ARM_CC=yes
 228         fi
 229 else
 230         HAVE_ARM_CC=no
 231 fi
 232
 233 if test "x$HAVE_ARM_CC" = "xno"; then
 234         AC_MSG_WARN([Arm compiler not found, ARM binaries will not be built])
 235 else
 236         ARM_CC=$with_arm_cc
 237 fi
 238 AC_SUBST(HAVE_ARM_CC)
 239 AC_SUBST(ARM_CC)
 240
 241 if test "x$HAVE_ARM_CC" = "xyes"; then
 242         save_CC="$CC"
 243         save_CFLAGS="$CFLAGS"
 244         save_LIBS="$LIBS"
 245         CC="$ARM_CC"
 246         CFLAGS="-mthumb -mcpu=cortex-m0"
 247         LIBS="-ffreestanding -nostdlib"
 248         AC_LANG_PUSH([C])
 249
 250         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m0])
 251         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 252                           [HAVE_ARM_M0_CC=yes],
 253                           [HAVE_ARM_M0_CC=no])
 254         AC_MSG_RESULT([$HAVE_ARM_M0_CC])
 255
 256         AC_CHECK_LIB(pdclib-cortex-m0,memcpy,
 257                      [],
 258                      [HAVE_ARM_M0_CC=no])
 259
 260         CFLAGS="-mthumb -mcpu=cortex-m3"
 261         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m3])
 262         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 263                           [HAVE_ARM_M3_CC=yes],
 264                           [HAVE_ARM_M3_CC=no])
 265         AC_MSG_RESULT([$HAVE_ARM_M3_CC])
 266
 267         AC_CHECK_LIB(pdclib-cortex-m3,memcpy,
 268                      [],
 269                      [HAVE_ARM_M3_CC=no])
 270
 271         AC_LANG_POP([C])
 272         LIBS="$save_LIBS"
 273         CFLAGS="$save_CFLAGS"
 274         CC="$save_CC"
 275 else
 276         HAVE_ARM_M3_CC=no
 277         HAVE_ARM_M0_CC=no
 278 fi
 279 AC_SUBST(HAVE_ARM_M3_CC)
 280 AC_SUBST(HAVE_ARM_M0_CC)
 281
 282 if test "x$HAVE_ARM_M3_CC" = "xno"; then
 283         AC_MSG_WARN([No cortex-m3 arm compiler found, STM32L binaries will not be built])
 284 fi
 285
 286 if test "x$HAVE_ARM_M0_CC" = "xno"; then
 287         AC_MSG_WARN([No cortex-m0 arm compiler found, LPC11U14 binaries will not be built])
 288 fi
 289
 290 #
 291 # Configure AVR compiler
 292 #
 293
 294 AC_ARG_WITH([avr-cc],
 295             [AS_HELP_STRING([--with-avr-cc],
 296                             [Name of AVR C compiler])],
 297             [],
 298             [with_avr_cc=auto])
 299
 300 if test "x$with_avr_cc" != "xno"; then
 301         if test "x$with_avr_cc" = "xauto"; then
 302                 with_avr_cc="avr-gcc"
 303                 AC_CHECK_PROG([HAVE_AVR_CC],[$with_avr_cc], yes, no)
 304         else
 305                 HAVE_AVR_CC=yes
 306         fi
 307 else
 308         HAVE_AVR_CC=no
 309 fi
 310
 311 AC_ARG_WITH([avr-objcopy],
 312             [AS_HELP_STRING([--with-avr-objcopy],
 313                             [Name of AVR objcopy])],
 314             [],
 315             [with_avr_objcopy=auto])
 316
 317 if test "x$with_avr_objcopy" != "xno"; then
 318         if test "x$with_avr_objcopy" = "xauto"; then
 319                 with_avr_objcopy="avr-objcopy"
 320                 AC_CHECK_PROG([HAVE_AVR_OBJCOPY],[$with_avr_objcopy], yes, no)
 321         else
 322                 HAVE_AVR_OBJCOPY=yes
 323         fi
 324 else
 325         HAVE_AVR_OBJCOPY=no
 326 fi
 327
 328 if test "x$HAVE_AVR_CC" = "xno" -o "x$HAVE_AVR_OBJCOPY" = "xno"; then
 329         AC_MSG_WARN([AVR compiler and objcopy not found, atmel binaries will not be built])
 330         HAVE_AVR_CC=no
 331 else
 332         save_CC="$CC"
 333         save_CFLAGS="$CFLAGS"
 334         save_LIBS="$LIBS"
 335
 336         CC="$with_avr_cc"
 337         CFLAGS="-mmcu=attiny85"
 338         AC_LANG_PUSH([C])
 339         AC_MSG_CHECKING([if ]$with_avr_cc[ can link programs])
 340         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 341                           [AVR_LINK=yes],
 342                           [AVR_LINK=no])
 343         AC_MSG_RESULT([$AVR_LINK])
 344         AC_LANG_POP([C])
 345
 346         LIBS="$save_LIBS"
 347         CFLAGS="$save_CFLAGS"
 348         CC="$save_CC"
 349
 350         if test "x$AVR_LINK" = xyes; then
 351                 AVR_CC=$with_avr_cc
 352                 AVR_OBJCOPY=$with_avr_objcopy
 353         else
 354                 HAVE_AVR_CC=no;
 355         fi
 356 fi
 357
 358 AC_SUBST(AVR_CC)
 359 AC_SUBST(AVR_OBJCOPY)
 360 AC_SUBST(HAVE_AVR_CC)
 361
 362 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
 363 if test "x$HAVE_NICKLE" = "xno"; then
 364         AC_MSG_ERROR([Please install nickle to build AltOs])
 365 fi
 366
 367 AC_ARG_WITH([readline],
 368             [AS_HELP_STRING([--with-readline],
 369                               [enable readline functionality in ao-dbg @<:@default=auto@:>@])],
 370               [],
 371               [with_readline=auto])
 372
 373 LIBREADLINE_LIBS=
 374
 375 if test x"$with_readline" != "xno"; then
 376         AC_CHECK_LIB([readline], [main],
 377                       [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 378                        AC_DEFINE([HAVE_LIBREADLINE], [1],
 379                          [Define if you have libreadline])],
 380                       [if test "x$with_readline" != xauto; then
 381                          AC_MSG_ERROR([--with-readline was given, but test for readline failed])
 382                        fi],
 383                        -lncurses)
 384 fi
 385
 386 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
 387
 388 AC_CHECK_HEADERS(libelf.h libelf/libelf.h, [break])
 389 AC_CHECK_HEADERS(gelf.h libelf/gelf.h, [break])
 390
 391 AC_ARG_WITH([stlink],
 392             [AS_HELP_STRING([--with-stlink],
 393                             [Build tools that use the stlink library (default: auto)])],
 394             [],
 395             [with_stlink=auto])
 396
 397 if test x"$with_stlink" != "xno"; then
 398         PKG_CHECK_MODULES([STLINK], [stlink], [HAVE_STLINK=yes], [HAVE_STLINK=no])
 399         if test x"$HAVE_STLINK" = "xno" -a x"$with_stlink" != "xauto"; then
 400                 AC_MSG_ERROR([--with-stlink was given, but stlink was not found])
 401         fi
 402 else
 403         HAVE_STLINK=no
 404 fi
 405
 406 if test x"$HAVE_STLINK" = "xyes"; then
 407         AC_DEFINE(HAVE_STLINK,1,[Using STlink library])
 408 fi
 409
 410 AM_CONDITIONAL([LIBSTLINK], [test x$HAVE_STLINK == xyes])
 411
 412 AC_OUTPUT([
 413 Makefile
 414 src/Makedefs
 415 altoslib/Makefile
 416 altosuilib/Makefile
 417 altosuilib/AltosUIVersion.java
 418 altosui/Makefile
 419 altosui/Info.plist
 420 altosui/altos-windows.nsi
 421 libaltos/Makefile
 422 micropeak/Makefile
 423 micropeak/Info.plist
 424 micropeak/micropeak-windows.nsi
 425 altosdroid/Makefile
 426 altosdroid/local.properties
 427 ao-tools/Makefile
 428 ao-tools/lib/Makefile
 429 ao-tools/ao-rawload/Makefile
 430 ao-tools/ao-dbg/Makefile
 431 ao-tools/ao-bitbang/Makefile
 432 ao-tools/ao-eeprom/Makefile
 433 ao-tools/ao-list/Makefile
 434 ao-tools/ao-load/Makefile
 435 ao-tools/ao-telem/Makefile
 436 ao-tools/ao-stmload/Makefile
 437 ao-tools/ao-send-telem/Makefile
 438 ao-tools/ao-sky-flash/Makefile
 439 ao-tools/ao-dumpflash/Makefile
 440 ao-tools/ao-edit-telem/Makefile
 441 ao-tools/ao-dump-up/Makefile
 442 ao-tools/ao-elftohex/Makefile
 443 ao-tools/ao-usbload/Makefile
 444 ao-tools/ao-flash/Makefile
 445 ao-utils/Makefile
 446 src/Version
 447 ])
 448
 449 echo ""
 450 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 451 echo ""
 452 echo "  Configuration"
 453 echo "    Arm compiler................: ${ARM_CC}"
 454 echo "    STM32L support..............: ${HAVE_ARM_M3_CC}"
 455 echo "    LPC11U14 support............: ${HAVE_ARM_M0_CC}"
 456 echo "    SDCC........................: ${SDCC}"
 457 echo "    CC1111 support..............: ${HAVE_SDCC}"
 458 echo "    AVR compiler................: ${AVR_CC} ${AVR_OBJCOPY}"
 459 echo "    AVR support.................: ${HAVE_AVR_CC}"
 460 echo "    Android support.............: ${HAVE_ANDROID_SDK}"
 461 echo "    STlink support..............: ${HAVE_STLINK}"
 462 echo ""
 463 echo "  Java paths"
 464 echo "    freetts.....................: ${FREETTS}"
 465 echo "    jfreechart..................: ${JFREECHART}"
 466 echo "    jcommon.....................: ${JCOMMON}"
 467 echo "    JVM include.................: ${JVM_INCLUDE}"
 468 if test x${ANDROID_SDK} != "xno"; then
 469 echo ""
 470 echo "  Android path"
 471 echo "    Android SDK.................: ${ANDROID_SDK}"
 472 fi
 473 echo ""