git.gag.com Git - fw/altos/blob - configure.ac

   1 dnl
   2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
   3 dnl
   4 dnl  This program is free software; you can redistribute it and/or modify
   5 dnl  it under the terms of the GNU General Public License as published by
   6 dnl  the Free Software Foundation; either version 2 of the License, or
   7 dnl  (at your option) any later version.
   8 dnl
   9 dnl  This program is distributed in the hope that it will be useful, but
  10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 dnl  General Public License for more details.
  13 dnl
  14 dnl  You should have received a copy of the GNU General Public License along
  15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
  16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17 dnl
  18 dnl Process this file with autoconf to create configure.
  19
  20 AC_PREREQ(2.57)
  21 AC_INIT([altos], 1.8.6.1)
  22 ANDROID_VERSION=17
  23 AC_CONFIG_SRCDIR([src/kernel/ao.h])
  24 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  25 AM_MAINTAINER_MODE
  26
  27 RELEASE_DATE=2018-06-17
  28 AC_SUBST(RELEASE_DATE)
  29
  30 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
  31 AC_SUBST(VERSION_DASH)
  32 AC_SUBST(ANDROID_VERSION)
  33
  34 dnl ==========================================================================
  35 dnl Java library versions
  36
  37 ALTOSUILIB_VERSION=13
  38 ALTOSLIB_VERSION=13
  39
  40 AC_SUBST(ALTOSLIB_VERSION)
  41 AC_DEFINE(ALTOSLIB_VERSION,$ALTOSLIB_VERSION,[Version of the AltosLib package])
  42 AC_SUBST(ALTOSUILIB_VERSION)
  43 AC_DEFINE(ALTOSUILIB_VERSION,$ALTOSUILIB_VERSION,[Version of the AltosUILib package])
  44
  45 dnl ==========================================================================
  46
  47 AM_CONFIG_HEADER(config.h)
  48
  49 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
  50         [Set freetts class path (default /usr/share/java)]),
  51         [FREETTS=$withval], [FREETTS=/usr/share/java])
  52
  53 AC_SUBST(FREETTS)
  54
  55 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
  56         [Set jfreechart class path (default /usr/share/java)]),
  57         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
  58
  59 AC_SUBST(JFREECHART)
  60
  61 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
  62         [Set jcommon class path (default /usr/share/java)]),
  63         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
  64
  65 AC_SUBST(JCOMMON)
  66
  67 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm-include=PATH],
  68         [Set jvm include path for jni builds (default searches in /usr/lib/jvm)]),
  69         [JVM_INCLUDE=$withval], [JVM_INCLUDE=auto])
  70
  71 if test "x$JVM_INCLUDE" = "xauto"; then
  72         AC_MSG_CHECKING([JVM include files])
  73         for jvm in default-java java-6-openjdk java-6-sun; do
  74                 if test "x$JVM_INCLUDE" = "xauto"; then
  75                         INCLUDE="/usr/lib/jvm/$jvm/include"
  76                         if test -f "$INCLUDE"/jni.h; then
  77                                 JVM_INCLUDE="$INCLUDE"
  78                         fi
  79                 fi
  80         done
  81         if test "x$JVM_INCLUDE" = "xauto"; then
  82                 AC_MSG_ERROR([no JVM include files found])
  83         fi
  84         AC_MSG_RESULT([$JVM_INCLUDE])
  85 fi
  86
  87 AC_SUBST(JVM_INCLUDE)
  88
  89 AC_ARG_WITH(android, AS_HELP_STRING([--with-android=PATH],
  90         [Set android SDK path (default searches in a variety of places)]),
  91         [ANDROID_SDK=$withval], [ANDROID_SDK=${ANDROID_SDK:-auto}])
  92
  93 if test "x$ANDROID_SDK" = "xauto"; then
  94         AC_MSG_CHECKING([Android SDK])
  95         for sdk in ../android/android-sdk-linux ../android/android-sdk ../android-sdk ../android-sdk-linux $HOME/android; do
  96                 if test "x$ANDROID_SDK" = "xauto"; then
  97                         SDK="$sdk"
  98                         if test -f "$SDK/SDK Readme.txt"; then
  99                                 ANDROID_SDK=`readlink -m "$SDK"`
 100                         fi
 101                 fi
 102         done
 103         if test "x$ANDROID_SDK" = "xauto"; then
 104                 AC_MSG_NOTICE([no Android SDK found])
 105                 ANDROID_SDK=no
 106         fi
 107         AC_MSG_RESULT([$ANDROID_SDK])
 108 fi
 109 if test "x$ANDROID_SDK" != "xno"; then
 110         AC_MSG_CHECKING([Android SDK version])
 111         SDK_VERSION=`grep -i '^Pkg.Revision=' $ANDROID_SDK/tools/source.properties | cut -f2- -d= | sed s/^r//`
 112         SDK_MAJOR_VERSION="`echo $SDK_VERSION | sed 's/[[^0-9]].*//'`"
 113         if test "$SDK_MAJOR_VERSION" -lt 17 ; then
 114                 AC_MSG_NOTICE([SDK version $SDK_VERSION is too old. Need >= r17])
 115                 ANDROID_SDK=no
 116         else
 117                 AC_MSG_RESULT([$SDK_VERSION])
 118         fi
 119 fi
 120 if test "x$ANDROID_SDK" != "xno"; then
 121         AC_MSG_CHECKING([Android SDK API Level])
 122         if test -f "$ANDROID_SDK/platforms/android-10/source.properties"; then
 123                 API_LEVEL=`sed -ne 's/^AndroidVersion.ApiLevel=//p' $ANDROID_SDK/platforms/android-10/source.properties`
 124                 if test "$API_LEVEL" = "10"; then
 125                         AC_MSG_RESULT([$API_LEVEL])
 126                 else
 127                         AC_MSG_NOTICE([API Level 10 not installed correctly.])
 128                         ANDROID_SDK=no
 129                 fi
 130         else
 131                 AC_MSG_NOTICE([API Level 10 not installed, but is required.])
 132                 ANDROID_SDK=no
 133         fi
 134 fi
 135 if test "x$ANDROID_SDK" != "xno"; then
 136         AC_MSG_CHECKING([Android SDK required extras])
 137         if test -f "$ANDROID_SDK/extras/android/support/source.properties"; then
 138                 ANDROID_SUPPORT_LIB_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/android/support/source.properties`
 139                 if test -f "$ANDROID_SDK/extras/google/google_play_services/source.properties"; then
 140                         GOOGLE_PLAY_SERVICES_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/google/google_play_services/source.properties`
 141                         AC_MSG_RESULT([$ANDROID_SUPPORT_LIB_NAME, $GOOGLE_PLAY_SERVICES_NAME])
 142                 else
 143                         AC_MSG_NOTICE([Google Play Services library not installed.])
 144                         ANDROID_SDK=no
 145                 fi
 146         else
 147                 AC_MSG_NOTICE([Android Support Library not installed.])
 148                 ANDROID_SDK=no
 149         fi
 150 fi
 151
 152 ANDROID_RELEASE=no
 153 if test "x$ANDROID_SDK" != "xno"; then
 154         HAVE_ANDROID_SDK="yes"
 155         if test -f "$HOME/altusmetrumllc/google-play-release.keystore" -a -f "$HOME/altusmetrumllc/google-play-passphrase"; then
 156                 ANDROID_RELEASE=yes
 157         fi
 158 else
 159         HAVE_ANDROID_SDK="no"
 160 fi
 161
 162 AM_CONDITIONAL([ANDROID], [test x$ANDROID_SDK != xno])
 163 AM_CONDITIONAL([ANDROID_RELEASE], [test x$ANDROID_RELEASE = xyes])
 164
 165 AC_SUBST(ANDROID_SDK)
 166
 167 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
 168             [Set the directory to install the 'fat-install' distribution files to (defaults to no such target)]),
 169             [FATDIR=$withval], [FATDIR=none])
 170
 171 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
 172
 173 AC_SUBST(FATDIR)
 174
 175 AC_ARG_WITH(google-key, AS_HELP_STRING([--with-google-key=PATH],
 176             [Set the file to read the google maps API key from (defaults to ~/altusmetrumllc/google-maps-api-key)]),
 177             [GOOGLEKEYFILE=$withval], [GOOGLEKEYFILE=$HOME/altusmetrumllc/google-maps-api-key])
 178
 179 if test -r "$GOOGLEKEYFILE" -a -s "$GOOGLEKEYFILE"; then
 180         GOOGLEKEY=`cat "$GOOGLEKEYFILE"`
 181         HAVE_GOOGLE_KEY="yes"
 182 else
 183         GOOGLEKEY='null'
 184         HAVE_GOOGLE_KEY="no"
 185 fi
 186
 187 AC_SUBST(GOOGLEKEY)
 188
 189 AC_PROG_CC
 190 AC_PROG_INSTALL
 191 AC_PROG_LN_S
 192 AC_PROG_LIBTOOL
 193 PKG_PROG_PKG_CONFIG
 194
 195 CFLAGS="-g"
 196 WARN_CFLAGS=""
 197 if test "x$GCC" = "xyes"; then
 198         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
 199         -Wmissing-prototypes -Wmissing-declarations \
 200         -Wnested-externs -fno-strict-aliasing"
 201         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
 202         [Can use #warning in C files])
 203 fi
 204 AC_SUBST(WARN_CFLAGS)
 205
 206 #
 207 # Configure ARM compiler for STM32L and LPC11U14
 208 #
 209
 210 AC_ARG_WITH([arm-cc],
 211             [AS_HELP_STRING([--with-arm-cc],
 212                             [Name of ARM C compiler])],
 213             [],
 214             [with_arm_cc=auto])
 215
 216 if test "x$with_arm_cc" != "xno"; then
 217         if test "x$with_arm_cc" = "xauto"; then
 218                 with_arm_cc="arm-none-eabi-gcc"
 219                 AC_CHECK_PROG([HAVE_ARM_CC],[$with_arm_cc], yes, no)
 220         else
 221                 HAVE_ARM_CC=yes
 222         fi
 223 else
 224         HAVE_ARM_CC=no
 225 fi
 226
 227 if test "x$HAVE_ARM_CC" = "xno"; then
 228         AC_MSG_WARN([Arm compiler not found, ARM binaries will not be built])
 229 else
 230         ARM_CC=$with_arm_cc
 231 fi
 232 AC_SUBST(HAVE_ARM_CC)
 233 AC_SUBST(ARM_CC)
 234
 235 if test "x$HAVE_ARM_CC" = "xyes"; then
 236         save_CC="$CC"
 237         save_CFLAGS="$CFLAGS"
 238         save_LIBS="$LIBS"
 239         CC="$ARM_CC"
 240         CFLAGS="-mthumb -mcpu=cortex-m0"
 241         LIBS="-ffreestanding -nostdlib"
 242         AC_LANG_PUSH([C])
 243
 244         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m0])
 245         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 246                           [HAVE_ARM_M0_CC=yes],
 247                           [HAVE_ARM_M0_CC=no])
 248         AC_MSG_RESULT([$HAVE_ARM_M0_CC])
 249
 250         CFLAGS="-mthumb -mcpu=cortex-m3"
 251         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m3])
 252         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 253                           [HAVE_ARM_M3_CC=yes],
 254                           [HAVE_ARM_M3_CC=no])
 255         AC_MSG_RESULT([$HAVE_ARM_M3_CC])
 256
 257         AC_LANG_POP([C])
 258         LIBS="$save_LIBS"
 259         CFLAGS="$save_CFLAGS"
 260         CC="$save_CC"
 261 else
 262         HAVE_ARM_M3_CC=no
 263         HAVE_ARM_M0_CC=no
 264 fi
 265 AC_SUBST(HAVE_ARM_M3_CC)
 266 AC_SUBST(HAVE_ARM_M0_CC)
 267
 268 if test "x$HAVE_ARM_M3_CC" = "xno"; then
 269         AC_MSG_WARN([No cortex-m3 arm compiler found, STM32L binaries will not be built])
 270 fi
 271
 272 if test "x$HAVE_ARM_M0_CC" = "xno"; then
 273         AC_MSG_WARN([No cortex-m0 arm compiler found, LPC11U14 binaries will not be built])
 274 fi
 275
 276 AC_ARG_WITH([newlib-nano],
 277             [AS_HELP_STRING([--with-newlib-nano],
 278                             [Root of newlib nano install])],
 279             [],
 280             [with_newlib_nano=auto])
 281
 282 HAVE_NEWLIB_NANO=no
 283 if test "x$with_newlib_nano" != "xno"; then
 284         if test "x$with_newlib_nano" = "xauto"; then
 285                 for d in /usr/local/lib/newlib-nano /usr/lib/newlib-nano; do
 286                         if test "x$with_newlib_nano" = "xauto" -a -d "$d"; then
 287                                 with_newlib_nano="$d"
 288                                 HAVE_NEWLIB_NANO=yes
 289                         fi
 290                 done
 291         else
 292                 HAVE_NEWLIB_NANO=yes
 293         fi
 294 fi
 295
 296 if test "x$HAVE_NEWLIB_NANO" = "xno"; then
 297         AC_MSG_WARN([No newlib-nano library found, ARM binaries will not be built])
 298         HAVE_ARM_M3_CC=no
 299         HAVE_ARM_M0_CC=no
 300 else
 301         NEWLIB_NANO="$with_newlib_nano"
 302 fi
 303
 304 AC_SUBST(HAVE_NEWLIB_NANO)
 305 AC_SUBST(NEWLIB_NANO)
 306
 307 #
 308 # Configure AVR compiler
 309 #
 310
 311 AC_ARG_WITH([avr-cc],
 312             [AS_HELP_STRING([--with-avr-cc],
 313                             [Name of AVR C compiler])],
 314             [],
 315             [with_avr_cc=auto])
 316
 317 if test "x$with_avr_cc" != "xno"; then
 318         if test "x$with_avr_cc" = "xauto"; then
 319                 with_avr_cc="avr-gcc"
 320                 AC_CHECK_PROG([HAVE_AVR_CC],[$with_avr_cc], yes, no)
 321         else
 322                 HAVE_AVR_CC=yes
 323         fi
 324 else
 325         HAVE_AVR_CC=no
 326 fi
 327
 328 AC_ARG_WITH([avr-objcopy],
 329             [AS_HELP_STRING([--with-avr-objcopy],
 330                             [Name of AVR objcopy])],
 331             [],
 332             [with_avr_objcopy=auto])
 333
 334 if test "x$with_avr_objcopy" != "xno"; then
 335         if test "x$with_avr_objcopy" = "xauto"; then
 336                 with_avr_objcopy="avr-objcopy"
 337                 AC_CHECK_PROG([HAVE_AVR_OBJCOPY],[$with_avr_objcopy], yes, no)
 338         else
 339                 HAVE_AVR_OBJCOPY=yes
 340         fi
 341 else
 342         HAVE_AVR_OBJCOPY=no
 343 fi
 344
 345 if test "x$HAVE_AVR_CC" = "xno" -o "x$HAVE_AVR_OBJCOPY" = "xno"; then
 346         AC_MSG_WARN([AVR compiler and objcopy not found, atmel binaries will not be built])
 347         HAVE_AVR_CC=no
 348 else
 349         save_CC="$CC"
 350         save_CFLAGS="$CFLAGS"
 351         save_LIBS="$LIBS"
 352
 353         CC="$with_avr_cc"
 354         CFLAGS="-mmcu=attiny85"
 355         AC_LANG_PUSH([C])
 356         AC_MSG_CHECKING([if ]$with_avr_cc[ can link programs])
 357         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 358                           [AVR_LINK=yes],
 359                           [AVR_LINK=no])
 360         AC_MSG_RESULT([$AVR_LINK])
 361         AC_LANG_POP([C])
 362
 363         LIBS="$save_LIBS"
 364         CFLAGS="$save_CFLAGS"
 365         CC="$save_CC"
 366
 367         if test "x$AVR_LINK" = xyes; then
 368                 AVR_CC=$with_avr_cc
 369                 AVR_OBJCOPY=$with_avr_objcopy
 370         else
 371                 HAVE_AVR_CC=no;
 372         fi
 373 fi
 374
 375 AC_SUBST(AVR_CC)
 376 AC_SUBST(AVR_OBJCOPY)
 377 AC_SUBST(HAVE_AVR_CC)
 378
 379 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
 380 if test "x$HAVE_NICKLE" = "xno"; then
 381         AC_MSG_ERROR([Please install nickle to build AltOs])
 382 fi
 383
 384 AC_ARG_WITH([readline],
 385             [AS_HELP_STRING([--with-readline],
 386                               [enable readline functionality in ao-dbg @<:@default=auto@:>@])],
 387               [],
 388               [with_readline=auto])
 389
 390 LIBREADLINE_LIBS=
 391
 392 if test x"$with_readline" != "xno"; then
 393         AC_CHECK_LIB([readline], [main],
 394                       [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 395                        AC_DEFINE([HAVE_LIBREADLINE], [1],
 396                          [Define if you have libreadline])],
 397                       [if test "x$with_readline" != xauto; then
 398                          AC_MSG_ERROR([--with-readline was given, but test for readline failed])
 399                        fi],
 400                        -lncurses)
 401 fi
 402
 403 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
 404
 405 AC_CHECK_HEADERS(libelf.h libelf/libelf.h, [break])
 406 AC_CHECK_HEADERS(gelf.h libelf/gelf.h, [break])
 407
 408 AC_ARG_WITH([stlink],
 409             [AS_HELP_STRING([--with-stlink],
 410                             [Build tools that use the stlink library (default: auto)])],
 411             [],
 412             [with_stlink=auto])
 413
 414 if test x"$with_stlink" != "xno"; then
 415         PKG_CHECK_MODULES([STLINK], [stlink], [HAVE_STLINK=yes], [HAVE_STLINK=no])
 416         if test x"$HAVE_STLINK" = "xno" -a x"$with_stlink" != "xauto"; then
 417                 AC_MSG_ERROR([--with-stlink was given, but stlink was not found])
 418         fi
 419 else
 420         HAVE_STLINK=no
 421 fi
 422
 423 if test x"$HAVE_STLINK" = "xyes"; then
 424         AC_DEFINE(HAVE_STLINK,1,[Using STlink library])
 425 fi
 426
 427 AM_CONDITIONAL([LIBSTLINK], [test x$HAVE_STLINK = xyes])
 428
 429 AC_ARG_ENABLE([multi-arch],
 430               [AS_HELP_STRING([--enable-multi-arch],
 431                               [enable building both i386 and amd64 libraries (default=auto)])],
 432               [MULTI_ARCH=$enableval],
 433               [MULTI_ARCH=auto])
 434
 435 case x"$MULTI_ARCH" in
 436 xauto)
 437         arch=`uname -m`
 438         case x"$arch" in
 439         xx86_64|xi*86)
 440                 save_CFLAGS="$CFLAGS"
 441                 save_LIBS="$LIBS"
 442                 LIBS="-ldl"
 443                 CFLAGS="-m64"
 444                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 445                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 446                                 [M64_LINK=yes],
 447                                 [M64_LINK=no])
 448                 AC_MSG_RESULT([$M64_LINK])
 449                 CFLAGS="-m32"
 450                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 451                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 452                                 [M32_LINK=yes],
 453                                 [M32_LINK=no])
 454                 AC_MSG_RESULT([$M32_LINK])
 455                 CFLAGS="$save_CFLAGS"
 456                 LIBS="$save_LIBS"
 457                 case x"$M64_LINK"x"$M32_LINK" in
 458                 xyesxyes)
 459                         MULTI_ARCH=yes
 460                         ;;
 461                 *)
 462                         MULTI_ARCH=no
 463                         ;;
 464                 esac
 465                 ;;
 466         *)
 467                 MULTI_ARCH=no
 468                 ;;
 469         esac
 470         ;;
 471 xyes|xno)
 472         ;;
 473 *)
 474         MULTI_ARCH="no"
 475         ;;
 476 esac
 477
 478 AM_CONDITIONAL([MULTI_ARCH], [test x$MULTI_ARCH = xyes])
 479
 480 AC_ARG_ENABLE([install-shared-mime-info],
 481               [AS_HELP_STRING([--disable-install-shared-mime-info],
 482                               [disable installing shared mime info files (default=yes)])],
 483               [INSTALL_SHARED_MIME_INFO=$enableval],
 484               [INSTALL_SHARED_MIME_INFO=yes])
 485
 486 AM_CONDITIONAL([INSTALL_SHARED_MIME_INFO], [test x$INSTALL_SHARED_MIME_INFO = xyes])
 487
 488 AC_OUTPUT([
 489 Makefile
 490 src/Makedefs
 491 src/chaoskey-v1.0/org.altusmetrum.ChaosKey.metainfo.xml
 492 altoslib/Makefile
 493 altoslib/AltosVersion.java
 494 icon/Makefile
 495 altosuilib/Makefile
 496 altosui/Makefile
 497 altosui/Info.plist
 498 altosui/altos-windows.nsi
 499 libaltos/Makefile
 500 micropeak/Makefile
 501 micropeak/Info.plist
 502 micropeak/micropeak-windows.nsi
 503 telegps/Makefile
 504 telegps/Info.plist
 505 telegps/telegps-windows.nsi
 506 altosdroid/Makefile
 507 altosdroid/local.properties
 508 altosdroid/AndroidManifest.xml
 509 ao-tools/Makefile
 510 ao-tools/lib/Makefile
 511 ao-tools/ao-rawload/Makefile
 512 ao-tools/ao-dbg/Makefile
 513 ao-tools/ao-bitbang/Makefile
 514 ao-tools/ao-eeprom/Makefile
 515 ao-tools/ao-list/Makefile
 516 ao-tools/ao-load/Makefile
 517 ao-tools/ao-telem/Makefile
 518 ao-tools/ao-stmload/Makefile
 519 ao-tools/ao-send-telem/Makefile
 520 ao-tools/ao-sky-flash/Makefile
 521 ao-tools/ao-dumpflash/Makefile
 522 ao-tools/ao-edit-telem/Makefile
 523 ao-tools/ao-dump-up/Makefile
 524 ao-tools/ao-elftohex/Makefile
 525 ao-tools/ao-usbload/Makefile
 526 ao-tools/ao-flash/Makefile
 527 ao-tools/ao-test-igniter/Makefile
 528 ao-tools/ao-test-baro/Makefile
 529 ao-tools/ao-test-flash/Makefile
 530 ao-tools/ao-cal-accel/Makefile
 531 ao-tools/ao-cal-freq/Makefile
 532 ao-tools/ao-test-gps/Makefile
 533 ao-tools/ao-usbtrng/Makefile
 534 ao-tools/ao-chaosread/Makefile
 535 ao-tools/ao-makebin/Makefile
 536 ao-utils/Makefile
 537 src/Version
 538 ])
 539
 540 echo ""
 541 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 542 echo ""
 543 echo "  Configuration"
 544 echo "    Arm compiler................: ${ARM_CC}"
 545 echo "    STM32L support..............: ${HAVE_ARM_M3_CC}"
 546 echo "    LPC11U14 support............: ${HAVE_ARM_M0_CC}"
 547 echo "    AVR compiler................: ${AVR_CC} ${AVR_OBJCOPY}"
 548 echo "    AVR support.................: ${HAVE_AVR_CC}"
 549 echo "    Android support.............: ${HAVE_ANDROID_SDK}"
 550 echo "    Android release support.....: ${ANDROID_RELEASE}"
 551 echo "    STlink support..............: ${HAVE_STLINK}"
 552 echo "    Newlib-nano support.........: ${NEWLIB_NANO}"
 553 echo "    i386 and amd64 libaltos.....: ${MULTI_ARCH}"
 554 echo "    install shared mime info....: ${INSTALL_SHARED_MIME_INFO}"
 555 echo ""
 556 echo "  Java"
 557 echo "    freetts.....................: ${FREETTS}"
 558 echo "    jfreechart..................: ${JFREECHART}"
 559 echo "    jcommon.....................: ${JCOMMON}"
 560 echo "    JVM include.................: ${JVM_INCLUDE}"
 561 echo "    Google maps API key.........: ${HAVE_GOOGLE_KEY}"
 562 if test x${ANDROID_SDK} != "xno"; then
 563 echo ""
 564 echo "  Android path"
 565 echo "    Android SDK.................: ${ANDROID_SDK}"
 566 fi
 567 echo ""