git.gag.com Git - fw/altos/blob - configure.ac

   1 dnl
   2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
   3 dnl
   4 dnl  This program is free software; you can redistribute it and/or modify
   5 dnl  it under the terms of the GNU General Public License as published by
   6 dnl  the Free Software Foundation; either version 2 of the License, or
   7 dnl  (at your option) any later version.
   8 dnl
   9 dnl  This program is distributed in the hope that it will be useful, but
  10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 dnl  General Public License for more details.
  13 dnl
  14 dnl  You should have received a copy of the GNU General Public License along
  15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
  16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17 dnl
  18 dnl Process this file with autoconf to create configure.
  19
  20 AC_PREREQ(2.57)
  21 AC_INIT([altos], 1.9)
  22 ANDROID_VERSION=18
  23 AC_CONFIG_SRCDIR([src/kernel/ao.h])
  24 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  25 AM_MAINTAINER_MODE
  26
  27 RELEASE_DATE=2018-12-31
  28 AC_SUBST(RELEASE_DATE)
  29
  30 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
  31 AC_SUBST(VERSION_DASH)
  32 AC_SUBST(ANDROID_VERSION)
  33
  34 dnl ==========================================================================
  35 dnl Java library versions
  36
  37 ALTOSUILIB_VERSION=13
  38 ALTOSLIB_VERSION=13
  39
  40 AC_SUBST(ALTOSLIB_VERSION)
  41 AC_DEFINE(ALTOSLIB_VERSION,$ALTOSLIB_VERSION,[Version of the AltosLib package])
  42 AC_SUBST(ALTOSUILIB_VERSION)
  43 AC_DEFINE(ALTOSUILIB_VERSION,$ALTOSUILIB_VERSION,[Version of the AltosUILib package])
  44
  45 dnl ==========================================================================
  46
  47 AM_CONFIG_HEADER(config.h)
  48
  49 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
  50         [Set freetts class path (default /usr/share/java)]),
  51         [FREETTS=$withval], [FREETTS=/usr/share/java])
  52
  53 AC_SUBST(FREETTS)
  54
  55 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
  56         [Set jfreechart class path (default /usr/share/java)]),
  57         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
  58
  59 AC_SUBST(JFREECHART)
  60
  61 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
  62         [Set jcommon class path (default /usr/share/java)]),
  63         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
  64
  65 AC_SUBST(JCOMMON)
  66
  67 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm-include=PATH],
  68         [Set jvm include path for jni builds (default searches in /usr/lib/jvm)]),
  69         [JVM_INCLUDE=$withval], [JVM_INCLUDE=auto])
  70
  71 if test "x$JVM_INCLUDE" = "xauto"; then
  72         AC_MSG_CHECKING([JVM include files])
  73         for jvm in default-java java-6-openjdk java-6-sun; do
  74                 if test "x$JVM_INCLUDE" = "xauto"; then
  75                         INCLUDE="/usr/lib/jvm/$jvm/include"
  76                         if test -f "$INCLUDE"/jni.h; then
  77                                 JVM_INCLUDE="$INCLUDE"
  78                         fi
  79                 fi
  80         done
  81         if test "x$JVM_INCLUDE" = "xauto"; then
  82                 AC_MSG_ERROR([no JVM include files found])
  83         fi
  84         AC_MSG_RESULT([$JVM_INCLUDE])
  85 fi
  86
  87 AC_SUBST(JVM_INCLUDE)
  88
  89 AC_ARG_WITH(android, AS_HELP_STRING([--with-android=PATH],
  90         [Set android SDK path (default searches in a variety of places)]),
  91         [ANDROID_SDK=$withval], [ANDROID_SDK=${ANDROID_SDK:-auto}])
  92
  93 if test "x$ANDROID_SDK" = "xauto"; then
  94         AC_MSG_CHECKING([Android SDK])
  95         for sdk in ../android/android-sdk-linux ../android/android-sdk ../android-sdk ../android-sdk-linux $HOME/android; do
  96                 if test "x$ANDROID_SDK" = "xauto"; then
  97                         SDK="$sdk"
  98                         if test -f "$SDK/SDK Readme.txt"; then
  99                                 ANDROID_SDK=`readlink -m "$SDK"`
 100                         fi
 101                 fi
 102         done
 103         if test "x$ANDROID_SDK" = "xauto"; then
 104                 AC_MSG_NOTICE([no Android SDK found])
 105                 ANDROID_SDK=no
 106         fi
 107         AC_MSG_RESULT([$ANDROID_SDK])
 108 fi
 109 if test "x$ANDROID_SDK" != "xno"; then
 110         AC_MSG_CHECKING([Android SDK version])
 111         SDK_VERSION=`grep -i '^Pkg.Revision=' $ANDROID_SDK/tools/source.properties | cut -f2- -d= | sed s/^r//`
 112         SDK_MAJOR_VERSION="`echo $SDK_VERSION | sed 's/[[^0-9]].*//'`"
 113         if test "$SDK_MAJOR_VERSION" -lt 17 ; then
 114                 AC_MSG_NOTICE([SDK version $SDK_VERSION is too old. Need >= r17])
 115                 ANDROID_SDK=no
 116         else
 117                 AC_MSG_RESULT([$SDK_VERSION])
 118         fi
 119 fi
 120 if test "x$ANDROID_SDK" != "xno"; then
 121         AC_MSG_CHECKING([Android SDK API Level])
 122         if test -f "$ANDROID_SDK/platforms/android-10/source.properties"; then
 123                 API_LEVEL=`sed -ne 's/^AndroidVersion.ApiLevel=//p' $ANDROID_SDK/platforms/android-10/source.properties`
 124                 if test "$API_LEVEL" = "10"; then
 125                         AC_MSG_RESULT([$API_LEVEL])
 126                 else
 127                         AC_MSG_NOTICE([API Level 10 not installed correctly.])
 128                         ANDROID_SDK=no
 129                 fi
 130         else
 131                 AC_MSG_NOTICE([API Level 10 not installed, but is required.])
 132                 ANDROID_SDK=no
 133         fi
 134 fi
 135 if test "x$ANDROID_SDK" != "xno"; then
 136         AC_MSG_CHECKING([Android SDK required extras])
 137         if test -f "$ANDROID_SDK/extras/android/support/source.properties"; then
 138                 ANDROID_SUPPORT_LIB_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/android/support/source.properties`
 139                 if test -f "$ANDROID_SDK/extras/google/google_play_services/source.properties"; then
 140                         GOOGLE_PLAY_SERVICES_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/google/google_play_services/source.properties`
 141                         AC_MSG_RESULT([$ANDROID_SUPPORT_LIB_NAME, $GOOGLE_PLAY_SERVICES_NAME])
 142                 else
 143                         AC_MSG_NOTICE([Google Play Services library not installed.])
 144                         ANDROID_SDK=no
 145                 fi
 146         else
 147                 AC_MSG_NOTICE([Android Support Library not installed.])
 148                 ANDROID_SDK=no
 149         fi
 150 fi
 151
 152 ANDROID_RELEASE=no
 153 if test "x$ANDROID_SDK" != "xno"; then
 154         HAVE_ANDROID_SDK="yes"
 155         if test -f "$HOME/altusmetrumllc/google-play-release.keystore" -a -f "$HOME/altusmetrumllc/google-play-passphrase"; then
 156                 ANDROID_RELEASE=yes
 157         fi
 158 else
 159         HAVE_ANDROID_SDK="no"
 160 fi
 161
 162 AM_CONDITIONAL([ANDROID], [test x$ANDROID_SDK != xno])
 163 AM_CONDITIONAL([ANDROID_RELEASE], [test x$ANDROID_RELEASE = xyes])
 164
 165 AC_SUBST(ANDROID_SDK)
 166
 167 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
 168             [Set the directory to install the 'fat-install' distribution files to (defaults to no such target)]),
 169             [FATDIR=$withval], [FATDIR=none])
 170
 171 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
 172
 173 AC_SUBST(FATDIR)
 174
 175 AC_ARG_WITH(google-key, AS_HELP_STRING([--with-google-key=PATH],
 176             [Set the file to read the AltosDroid maps API key from (defaults to ~/altusmetrumllc/google-altosdroid-maps-api-key)]),
 177             [GOOGLEKEYFILE=$withval], [GOOGLEKEYFILE=$HOME/altusmetrumllc/google-altosdroid-maps-api-key])
 178
 179 if test -r "$GOOGLEKEYFILE" -a -s "$GOOGLEKEYFILE"; then
 180         GOOGLEKEY=`cat "$GOOGLEKEYFILE"`
 181         HAVE_GOOGLE_KEY="yes"
 182 else
 183         GOOGLEKEY='null'
 184         HAVE_GOOGLE_KEY="no"
 185 fi
 186
 187 WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs"
 188 AC_SUBST(WARN_CFLAGS)
 189
 190 AC_ARG_ENABLE(faketime, AS_HELP_STRING([--enable-faketime],
 191               [Use faketime program to ensure pdf files are reproducible (default=no)]),
 192               [FAKETIME=$enableval], [FAKETIME=no])
 193
 194 AM_CONDITIONAL(FAKETIME, [test x$FAKETIME = xyes])
 195
 196 AC_SUBST(GOOGLEKEY)
 197
 198 AC_PROG_CC
 199 AC_PROG_INSTALL
 200 AC_PROG_LN_S
 201 AC_PROG_LIBTOOL
 202 PKG_PROG_PKG_CONFIG
 203
 204 WARN_CFLAGS=""
 205 if test "x$GCC" = "xyes"; then
 206         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
 207         -Wmissing-prototypes -Wmissing-declarations \
 208         -Wnested-externs -fno-strict-aliasing"
 209         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
 210         [Can use #warning in C files])
 211 fi
 212 AC_SUBST(WARN_CFLAGS)
 213
 214 #
 215 # Configure ARM compiler for STM32L and LPC11U14
 216 #
 217
 218 AC_ARG_WITH([arm-cc],
 219             [AS_HELP_STRING([--with-arm-cc],
 220                             [Name of ARM C compiler])],
 221             [],
 222             [with_arm_cc=auto])
 223
 224 if test "x$with_arm_cc" != "xno"; then
 225         if test "x$with_arm_cc" = "xauto"; then
 226                 with_arm_cc="arm-none-eabi-gcc"
 227                 AC_CHECK_PROG([HAVE_ARM_CC],[$with_arm_cc], yes, no)
 228         else
 229                 HAVE_ARM_CC=yes
 230         fi
 231 else
 232         HAVE_ARM_CC=no
 233 fi
 234
 235 if test "x$HAVE_ARM_CC" = "xno"; then
 236         AC_MSG_WARN([Arm compiler not found, ARM binaries will not be built])
 237 else
 238         ARM_CC=$with_arm_cc
 239 fi
 240 AC_SUBST(HAVE_ARM_CC)
 241 AC_SUBST(ARM_CC)
 242
 243 if test "x$HAVE_ARM_CC" = "xyes"; then
 244         save_CC="$CC"
 245         save_CFLAGS="$CFLAGS"
 246         save_LIBS="$LIBS"
 247         CC="$ARM_CC"
 248         CFLAGS="-mthumb -mcpu=cortex-m0"
 249         LIBS="-ffreestanding -nostdlib"
 250         AC_LANG_PUSH([C])
 251
 252         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m0])
 253         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 254                           [HAVE_ARM_M0_CC=yes],
 255                           [HAVE_ARM_M0_CC=no])
 256         AC_MSG_RESULT([$HAVE_ARM_M0_CC])
 257
 258         CFLAGS="-mthumb -mcpu=cortex-m3"
 259         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m3])
 260         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 261                           [HAVE_ARM_M3_CC=yes],
 262                           [HAVE_ARM_M3_CC=no])
 263         AC_MSG_RESULT([$HAVE_ARM_M3_CC])
 264
 265         AC_LANG_POP([C])
 266         LIBS="$save_LIBS"
 267         CFLAGS="$save_CFLAGS"
 268         CC="$save_CC"
 269 else
 270         HAVE_ARM_M3_CC=no
 271         HAVE_ARM_M0_CC=no
 272 fi
 273 AC_SUBST(HAVE_ARM_M3_CC)
 274 AC_SUBST(HAVE_ARM_M0_CC)
 275
 276 if test "x$HAVE_ARM_M3_CC" = "xno"; then
 277         AC_MSG_WARN([No cortex-m3 arm compiler found, STM32L binaries will not be built])
 278 fi
 279
 280 if test "x$HAVE_ARM_M0_CC" = "xno"; then
 281         AC_MSG_WARN([No cortex-m0 arm compiler found, LPC11U14 binaries will not be built])
 282 fi
 283
 284 AC_ARG_WITH([newlib-nano],
 285             [AS_HELP_STRING([--with-newlib-nano],
 286                             [Root of newlib nano install])],
 287             [],
 288             [with_newlib_nano=auto])
 289
 290 HAVE_NEWLIB_NANO=no
 291 if test "x$with_newlib_nano" != "xno"; then
 292         if test "x$with_newlib_nano" = "xauto"; then
 293                 for d in /usr/local/lib/newlib-nano /usr/lib/newlib-nano; do
 294                         if test "x$with_newlib_nano" = "xauto" -a -d "$d"; then
 295                                 with_newlib_nano="$d"
 296                                 HAVE_NEWLIB_NANO=yes
 297                         fi
 298                 done
 299         else
 300                 HAVE_NEWLIB_NANO=yes
 301         fi
 302 fi
 303
 304 if test "x$HAVE_NEWLIB_NANO" = "xno"; then
 305         AC_MSG_WARN([No newlib-nano library found, ARM binaries will not be built])
 306         HAVE_ARM_M3_CC=no
 307         HAVE_ARM_M0_CC=no
 308 else
 309         NEWLIB_NANO="$with_newlib_nano"
 310 fi
 311
 312 AC_SUBST(HAVE_NEWLIB_NANO)
 313 AC_SUBST(NEWLIB_NANO)
 314
 315 #
 316 # Configure AVR compiler
 317 #
 318
 319 AC_ARG_WITH([avr-cc],
 320             [AS_HELP_STRING([--with-avr-cc],
 321                             [Name of AVR C compiler])],
 322             [],
 323             [with_avr_cc=auto])
 324
 325 if test "x$with_avr_cc" != "xno"; then
 326         if test "x$with_avr_cc" = "xauto"; then
 327                 with_avr_cc="avr-gcc"
 328                 AC_CHECK_PROG([HAVE_AVR_CC],[$with_avr_cc], yes, no)
 329         else
 330                 HAVE_AVR_CC=yes
 331         fi
 332 else
 333         HAVE_AVR_CC=no
 334 fi
 335
 336 AC_ARG_WITH([avr-objcopy],
 337             [AS_HELP_STRING([--with-avr-objcopy],
 338                             [Name of AVR objcopy])],
 339             [],
 340             [with_avr_objcopy=auto])
 341
 342 if test "x$with_avr_objcopy" != "xno"; then
 343         if test "x$with_avr_objcopy" = "xauto"; then
 344                 with_avr_objcopy="avr-objcopy"
 345                 AC_CHECK_PROG([HAVE_AVR_OBJCOPY],[$with_avr_objcopy], yes, no)
 346         else
 347                 HAVE_AVR_OBJCOPY=yes
 348         fi
 349 else
 350         HAVE_AVR_OBJCOPY=no
 351 fi
 352
 353 if test "x$HAVE_AVR_CC" = "xno" -o "x$HAVE_AVR_OBJCOPY" = "xno"; then
 354         AC_MSG_WARN([AVR compiler and objcopy not found, atmel binaries will not be built])
 355         HAVE_AVR_CC=no
 356 else
 357         save_CC="$CC"
 358         save_CFLAGS="$CFLAGS"
 359         save_LIBS="$LIBS"
 360
 361         CC="$with_avr_cc"
 362         CFLAGS="-mmcu=attiny85"
 363         AC_LANG_PUSH([C])
 364         AC_MSG_CHECKING([if ]$with_avr_cc[ can link programs])
 365         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 366                           [AVR_LINK=yes],
 367                           [AVR_LINK=no])
 368         AC_MSG_RESULT([$AVR_LINK])
 369         AC_LANG_POP([C])
 370
 371         LIBS="$save_LIBS"
 372         CFLAGS="$save_CFLAGS"
 373         CC="$save_CC"
 374
 375         if test "x$AVR_LINK" = xyes; then
 376                 AVR_CC=$with_avr_cc
 377                 AVR_OBJCOPY=$with_avr_objcopy
 378         else
 379                 HAVE_AVR_CC=no;
 380         fi
 381 fi
 382
 383 AC_SUBST(AVR_CC)
 384 AC_SUBST(AVR_OBJCOPY)
 385 AC_SUBST(HAVE_AVR_CC)
 386
 387 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
 388 if test "x$HAVE_NICKLE" = "xno"; then
 389         AC_MSG_ERROR([Please install nickle to build AltOs])
 390 fi
 391
 392 AC_CHECK_PROG([HAVE_ASCIIDOCTOR_PDF], [asciidoctor-pdf], yes, no)
 393 if test "x$HAVE_ASCIIDOCTOR_PDF" = "xno"; then
 394         AC_MSG_WARN([asciidoctor-pdf not found, PDF docs will not be built])
 395 fi
 396 AM_CONDITIONAL([ASCIIDOCTOR_PDF], [test x$HAVE_ASCIIDOCTOR_PDF != xno])
 397
 398 PKG_CHECK_MODULES([JANSSON], [jansson])
 399
 400 AC_ARG_WITH([readline],
 401             [AS_HELP_STRING([--with-readline],
 402                               [enable readline functionality in ao-dbg @<:@default=auto@:>@])],
 403               [],
 404               [with_readline=auto])
 405
 406 LIBREADLINE_LIBS=
 407
 408 if test x"$with_readline" != "xno"; then
 409         AC_CHECK_LIB([readline], [main],
 410                       [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 411                        AC_DEFINE([HAVE_LIBREADLINE], [1],
 412                          [Define if you have libreadline])],
 413                       [if test "x$with_readline" != xauto; then
 414                          AC_MSG_ERROR([--with-readline was given, but test for readline failed])
 415                        fi],
 416                        -lncurses)
 417 fi
 418
 419 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
 420
 421 AC_CHECK_HEADERS(libelf.h libelf/libelf.h, [break])
 422 AC_CHECK_HEADERS(gelf.h libelf/gelf.h, [break])
 423
 424 AC_ARG_WITH([stlink],
 425             [AS_HELP_STRING([--with-stlink],
 426                             [Build tools that use the stlink library (default: auto)])],
 427             [],
 428             [with_stlink=auto])
 429
 430 if test x"$with_stlink" != "xno"; then
 431         PKG_CHECK_MODULES([STLINK], [stlink], [HAVE_STLINK=yes], [HAVE_STLINK=no])
 432         if test x"$HAVE_STLINK" = "xno" -a x"$with_stlink" != "xauto"; then
 433                 AC_MSG_ERROR([--with-stlink was given, but stlink was not found])
 434         fi
 435 else
 436         HAVE_STLINK=no
 437 fi
 438
 439 if test x"$HAVE_STLINK" = "xyes"; then
 440         AC_DEFINE(HAVE_STLINK,1,[Using STlink library])
 441 fi
 442
 443 AM_CONDITIONAL([LIBSTLINK], [test x$HAVE_STLINK = xyes])
 444
 445 AC_ARG_ENABLE([multi-arch],
 446               [AS_HELP_STRING([--enable-multi-arch],
 447                               [enable building both i386 and amd64 libraries (default=auto)])],
 448               [MULTI_ARCH=$enableval],
 449               [MULTI_ARCH=auto])
 450
 451 case x"$MULTI_ARCH" in
 452 xauto)
 453         arch=`uname -m`
 454         case x"$arch" in
 455         xx86_64|xi*86)
 456                 save_CFLAGS="$CFLAGS"
 457                 save_LIBS="$LIBS"
 458                 LIBS="-ldl"
 459                 CFLAGS="-m64"
 460                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 461                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 462                                 [M64_LINK=yes],
 463                                 [M64_LINK=no])
 464                 AC_MSG_RESULT([$M64_LINK])
 465                 CFLAGS="-m32"
 466                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 467                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 468                                 [M32_LINK=yes],
 469                                 [M32_LINK=no])
 470                 AC_MSG_RESULT([$M32_LINK])
 471                 CFLAGS="$save_CFLAGS"
 472                 LIBS="$save_LIBS"
 473                 case x"$M64_LINK"x"$M32_LINK" in
 474                 xyesxyes)
 475                         MULTI_ARCH=yes
 476                         ;;
 477                 *)
 478                         MULTI_ARCH=no
 479                         ;;
 480                 esac
 481                 ;;
 482         *)
 483                 MULTI_ARCH=no
 484                 ;;
 485         esac
 486         ;;
 487 xyes|xno)
 488         ;;
 489 *)
 490         MULTI_ARCH="no"
 491         ;;
 492 esac
 493
 494 AM_CONDITIONAL([MULTI_ARCH], [test x$MULTI_ARCH = xyes])
 495
 496 AC_ARG_ENABLE([install-shared-mime-info],
 497               [AS_HELP_STRING([--disable-install-shared-mime-info],
 498                               [disable installing shared mime info files (default=yes)])],
 499               [INSTALL_SHARED_MIME_INFO=$enableval],
 500               [INSTALL_SHARED_MIME_INFO=yes])
 501
 502 AM_CONDITIONAL([INSTALL_SHARED_MIME_INFO], [test x$INSTALL_SHARED_MIME_INFO = xyes])
 503
 504 AC_OUTPUT([
 505 Makefile
 506 src/Makedefs
 507 src/chaoskey-v1.0/org.altusmetrum.ChaosKey.metainfo.xml
 508 doc/Makefile
 509 altoslib/Makefile
 510 altoslib/AltosVersion.java
 511 icon/Makefile
 512 altosuilib/Makefile
 513 altosui/Makefile
 514 altosui/Info.plist
 515 altosui/altos-windows.nsi
 516 libaltos/Makefile
 517 micropeak/Makefile
 518 micropeak/Info.plist
 519 micropeak/micropeak-windows.nsi
 520 telegps/Makefile
 521 telegps/Info.plist
 522 telegps/telegps-windows.nsi
 523 altosdroid/Makefile
 524 altosdroid/local.properties
 525 altosdroid/AndroidManifest.xml
 526 ao-tools/Makefile
 527 ao-tools/lib/Makefile
 528 ao-tools/ao-rawload/Makefile
 529 ao-tools/ao-dbg/Makefile
 530 ao-tools/ao-bitbang/Makefile
 531 ao-tools/ao-eeprom/Makefile
 532 ao-tools/ao-list/Makefile
 533 ao-tools/ao-load/Makefile
 534 ao-tools/ao-telem/Makefile
 535 ao-tools/ao-stmload/Makefile
 536 ao-tools/ao-send-telem/Makefile
 537 ao-tools/ao-sky-flash/Makefile
 538 ao-tools/ao-dumpflash/Makefile
 539 ao-tools/ao-edit-telem/Makefile
 540 ao-tools/ao-dump-up/Makefile
 541 ao-tools/ao-elftohex/Makefile
 542 ao-tools/ao-usbload/Makefile
 543 ao-tools/ao-flash/Makefile
 544 ao-tools/ao-test-igniter/Makefile
 545 ao-tools/ao-test-baro/Makefile
 546 ao-tools/ao-test-flash/Makefile
 547 ao-tools/ao-cal-accel/Makefile
 548 ao-tools/ao-cal-freq/Makefile
 549 ao-tools/ao-test-gps/Makefile
 550 ao-tools/ao-usbtrng/Makefile
 551 ao-tools/ao-makebin/Makefile
 552 ao-utils/Makefile
 553 map-server/Makefile
 554 map-server/altos-mapd/Makefile
 555 map-server/altos-map/Makefile
 556 map-server/altos-mapj/Makefile
 557 src/Version
 558 ])
 559
 560 echo ""
 561 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 562 echo ""
 563 echo "  Configuration"
 564 echo "    Arm compiler................: ${ARM_CC}"
 565 echo "    STM32L support..............: ${HAVE_ARM_M3_CC}"
 566 echo "    LPC11U14 support............: ${HAVE_ARM_M0_CC}"
 567 echo "    AVR compiler................: ${AVR_CC} ${AVR_OBJCOPY}"
 568 echo "    AVR support.................: ${HAVE_AVR_CC}"
 569 echo "    Android support.............: ${HAVE_ANDROID_SDK}"
 570 echo "    Android release support.....: ${ANDROID_RELEASE}"
 571 echo "    STlink support..............: ${HAVE_STLINK}"
 572 echo "    Newlib-nano support.........: ${NEWLIB_NANO}"
 573 echo "    i386 and amd64 libaltos.....: ${MULTI_ARCH}"
 574 echo "    install shared mime info....: ${INSTALL_SHARED_MIME_INFO}"
 575 echo ""
 576 echo "  Java"
 577 echo "    freetts.....................: ${FREETTS}"
 578 echo "    jfreechart..................: ${JFREECHART}"
 579 echo "    jcommon.....................: ${JCOMMON}"
 580 echo "    JVM include.................: ${JVM_INCLUDE}"
 581 echo "    AltosDroid maps API key.....: ${HAVE_GOOGLE_KEY}"
 582 if test x${ANDROID_SDK} != "xno"; then
 583 echo ""
 584 echo "  Android path"
 585 echo "    Android SDK.................: ${ANDROID_SDK}"
 586 fi
 587 echo ""