git.gag.com Git - fw/altos/blob - configure.ac

   1 dnl
   2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
   3 dnl
   4 dnl  This program is free software; you can redistribute it and/or modify
   5 dnl  it under the terms of the GNU General Public License as published by
   6 dnl  the Free Software Foundation; either version 2 of the License, or
   7 dnl  (at your option) any later version.
   8 dnl
   9 dnl  This program is distributed in the hope that it will be useful, but
  10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 dnl  General Public License for more details.
  13 dnl
  14 dnl  You should have received a copy of the GNU General Public License along
  15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
  16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17 dnl
  18 dnl Process this file with autoconf to create configure.
  19
  20 AC_PREREQ(2.57)
  21 AC_INIT([altos], 1.7)
  22 ANDROID_VERSION=14
  23 AC_CONFIG_SRCDIR([src/kernel/ao.h])
  24 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  25 AM_MAINTAINER_MODE
  26
  27 RELEASE_DATE=2017-04-24
  28 AC_SUBST(RELEASE_DATE)
  29
  30 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
  31 AC_SUBST(VERSION_DASH)
  32 AC_SUBST(ANDROID_VERSION)
  33
  34 dnl ==========================================================================
  35 dnl Java library versions
  36
  37 ALTOSUILIB_VERSION=11
  38 ALTOSLIB_VERSION=11
  39
  40 AC_SUBST(ALTOSLIB_VERSION)
  41 AC_DEFINE(ALTOSLIB_VERSION,$ALTOSLIB_VERSION,[Version of the AltosLib package])
  42 AC_SUBST(ALTOSUILIB_VERSION)
  43 AC_DEFINE(ALTOSUILIB_VERSION,$ALTOSUILIB_VERSION,[Version of the AltosUILib package])
  44
  45 dnl ==========================================================================
  46
  47 AM_CONFIG_HEADER(config.h)
  48
  49 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
  50         [Set freetts class path (default /usr/share/java)]),
  51         [FREETTS=$withval], [FREETTS=/usr/share/java])
  52
  53 AC_SUBST(FREETTS)
  54
  55 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
  56         [Set jfreechart class path (default /usr/share/java)]),
  57         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
  58
  59 AC_SUBST(JFREECHART)
  60
  61 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
  62         [Set jcommon class path (default /usr/share/java)]),
  63         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
  64
  65 AC_SUBST(JCOMMON)
  66
  67 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm-include=PATH],
  68         [Set jvm include path for jni builds (default searches in /usr/lib/jvm)]),
  69         [JVM_INCLUDE=$withval], [JVM_INCLUDE=auto])
  70
  71 if test "x$JVM_INCLUDE" = "xauto"; then
  72         AC_MSG_CHECKING([JVM include files])
  73         for jvm in default-java java-6-openjdk java-6-sun; do
  74                 if test "x$JVM_INCLUDE" = "xauto"; then
  75                         INCLUDE="/usr/lib/jvm/$jvm/include"
  76                         if test -f "$INCLUDE"/jni.h; then
  77                                 JVM_INCLUDE="$INCLUDE"
  78                         fi
  79                 fi
  80         done
  81         if test "x$JVM_INCLUDE" = "xauto"; then
  82                 AC_MSG_ERROR([no JVM include files found])
  83         fi
  84         AC_MSG_RESULT([$JVM_INCLUDE])
  85 fi
  86
  87 AC_SUBST(JVM_INCLUDE)
  88
  89 AC_ARG_WITH(android, AS_HELP_STRING([--with-android=PATH],
  90         [Set android SDK path (default searches in a variety of places)]),
  91         [ANDROID_SDK=$withval], [ANDROID_SDK=${ANDROID_SDK:-auto}])
  92
  93 if test "x$ANDROID_SDK" = "xauto"; then
  94         AC_MSG_CHECKING([Android SDK])
  95         for sdk in ../android/android-sdk-linux ../android/android-sdk ../android-sdk ../android-sdk-linux $HOME/android; do
  96                 if test "x$ANDROID_SDK" = "xauto"; then
  97                         SDK="$sdk"
  98                         if test -f "$SDK/SDK Readme.txt"; then
  99                                 ANDROID_SDK=`readlink -m "$SDK"`
 100                         fi
 101                 fi
 102         done
 103         if test "x$ANDROID_SDK" = "xauto"; then
 104                 AC_MSG_NOTICE([no Android SDK found])
 105                 ANDROID_SDK=no
 106         fi
 107         AC_MSG_RESULT([$ANDROID_SDK])
 108 fi
 109 if test "x$ANDROID_SDK" != "xno"; then
 110         AC_MSG_CHECKING([Android SDK version])
 111         SDK_VERSION=`grep -i '^Pkg.Revision=' $ANDROID_SDK/tools/source.properties | cut -f2- -d= | sed s/^r//`
 112         SDK_MAJOR_VERSION="`echo $SDK_VERSION | sed 's/[[^0-9]].*//'`"
 113         if test "$SDK_MAJOR_VERSION" -lt 17 ; then
 114                 AC_MSG_NOTICE([SDK version $SDK_VERSION is too old. Need >= r17])
 115                 ANDROID_SDK=no
 116         else
 117                 AC_MSG_RESULT([$SDK_VERSION])
 118         fi
 119 fi
 120 if test "x$ANDROID_SDK" != "xno"; then
 121         AC_MSG_CHECKING([Android SDK API Level])
 122         if test -f "$ANDROID_SDK/platforms/android-10/source.properties"; then
 123                 API_LEVEL=`sed -ne 's/^AndroidVersion.ApiLevel=//p' $ANDROID_SDK/platforms/android-10/source.properties`
 124                 if test "$API_LEVEL" = "10"; then
 125                         AC_MSG_RESULT([$API_LEVEL])
 126                 else
 127                         AC_MSG_NOTICE([API Level 10 not installed correctly.])
 128                         ANDROID_SDK=no
 129                 fi
 130         else
 131                 AC_MSG_NOTICE([API Level 10 not installed, but is required.])
 132                 ANDROID_SDK=no
 133         fi
 134 fi
 135 if test "x$ANDROID_SDK" != "xno"; then
 136         AC_MSG_CHECKING([Android SDK required extras])
 137         if test -f "$ANDROID_SDK/extras/android/support/source.properties"; then
 138                 ANDROID_SUPPORT_LIB_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/android/support/source.properties`
 139                 if test -f "$ANDROID_SDK/extras/google/google_play_services/source.properties"; then
 140                         GOOGLE_PLAY_SERVICES_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/google/google_play_services/source.properties`
 141                         AC_MSG_RESULT([$ANDROID_SUPPORT_LIB_NAME, $GOOGLE_PLAY_SERVICES_NAME])
 142                 else
 143                         AC_MSG_NOTICE([Google Play Services library not installed.])
 144                         ANDROID_SDK=no
 145                 fi
 146         else
 147                 AC_MSG_NOTICE([Android Support Library not installed.])
 148                 ANDROID_SDK=no
 149         fi
 150 fi
 151
 152 ANDROID_RELEASE=no
 153 if test "x$ANDROID_SDK" != "xno"; then
 154         HAVE_ANDROID_SDK="yes"
 155         if test -f "$HOME/altusmetrumllc/google-play-release.keystore" -a -f "$HOME/altusmetrumllc/google-play-passphrase"; then
 156                 ANDROID_RELEASE=yes
 157         fi
 158 else
 159         HAVE_ANDROID_SDK="no"
 160 fi
 161
 162 AM_CONDITIONAL([ANDROID], [test x$ANDROID_SDK != xno])
 163 AM_CONDITIONAL([ANDROID_RELEASE], [test x$ANDROID_RELEASE = xyes])
 164
 165 AC_SUBST(ANDROID_SDK)
 166
 167 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
 168             [Set the directory to install the 'fat' distribution files to (defaults to not installing)]),
 169             [FATDIR=$withval], [FATDIR=none])
 170
 171 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
 172
 173 AC_SUBST(FATDIR)
 174
 175 AC_ARG_WITH(google-key, AS_HELP_STRING([--with-google-key=PATH],
 176             [Set the file to read the google maps API key from (defaults to ~/altusmetrumllc/google-maps-api-key)]),
 177             [GOOGLEKEYFILE=$withval], [GOOGLEKEYFILE=$HOME/altusmetrumllc/google-maps-api-key])
 178
 179 if test -r "$GOOGLEKEYFILE" -a -s "$GOOGLEKEYFILE"; then
 180         GOOGLEKEY=`cat "$GOOGLEKEYFILE"`
 181         HAVE_GOOGLE_KEY="yes"
 182 else
 183         GOOGLEKEY='null'
 184         HAVE_GOOGLE_KEY="no"
 185 fi
 186
 187 AC_SUBST(GOOGLEKEY)
 188
 189 AC_PROG_CC
 190 AC_PROG_INSTALL
 191 AC_PROG_LN_S
 192 AC_PROG_LIBTOOL
 193 PKG_PROG_PKG_CONFIG
 194
 195 CFLAGS="-g"
 196 WARN_CFLAGS=""
 197 if test "x$GCC" = "xyes"; then
 198         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
 199         -Wmissing-prototypes -Wmissing-declarations \
 200         -Wnested-externs -fno-strict-aliasing"
 201         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
 202         [Can use #warning in C files])
 203 fi
 204 AC_SUBST(WARN_CFLAGS)
 205
 206 #
 207 # Configure SDCC
 208 #
 209
 210 AC_ARG_WITH([sdcc],
 211             [AS_HELP_STRING([--with-sdcc],
 212                             [Name of SDCC])],
 213             [],
 214             [with_sdcc=auto])
 215
 216 if test "x$with_sdcc" != "xno"; then
 217         if test "x$with_sdcc" = "xauto"; then
 218                 with_sdcc="sdcc"
 219                 AC_CHECK_PROG([HAVE_SDCC],[$with_sdcc], yes, no)
 220         else
 221                 HAVE_SDCC=yes
 222         fi
 223 else
 224         HAVE_SDCC=no
 225 fi
 226
 227 if test "x$HAVE_SDCC" = "xno"; then
 228         AC_MSG_WARN([SDCC not found, cc1111 binaries will not be built])
 229 else
 230         SDCC=$with_sdcc
 231 fi
 232
 233 AC_SUBST(SDCC)
 234 AC_SUBST(HAVE_SDCC)
 235
 236 #
 237 # Configure ARM compiler for STM32L and LPC11U14
 238 #
 239
 240 AC_ARG_WITH([arm-cc],
 241             [AS_HELP_STRING([--with-arm-cc],
 242                             [Name of ARM C compiler])],
 243             [],
 244             [with_arm_cc=auto])
 245
 246 if test "x$with_arm_cc" != "xno"; then
 247         if test "x$with_arm_cc" = "xauto"; then
 248                 with_arm_cc="arm-none-eabi-gcc"
 249                 AC_CHECK_PROG([HAVE_ARM_CC],[$with_arm_cc], yes, no)
 250         else
 251                 HAVE_ARM_CC=yes
 252         fi
 253 else
 254         HAVE_ARM_CC=no
 255 fi
 256
 257 if test "x$HAVE_ARM_CC" = "xno"; then
 258         AC_MSG_WARN([Arm compiler not found, ARM binaries will not be built])
 259 else
 260         ARM_CC=$with_arm_cc
 261 fi
 262 AC_SUBST(HAVE_ARM_CC)
 263 AC_SUBST(ARM_CC)
 264
 265 if test -d pdclib -a x"$HAVE_ARM_CC" = xyes; then
 266         PDCLIB_ROOT='$(TOPDIR)/../pdclib-root'
 267         PDCLIB_INCLUDES='-I$(TOPDIR)/../pdclib-root/include'
 268         PDCLIB_LIBS_M0='-L$(TOPDIR)/../pdclib-root/lib -lpdclib-cortex-m0'
 269         PDCLIB_LIBS_M3='-L$(TOPDIR)/../pdclib-root/lib -lpdclib-cortex-m3'
 270         HAVE_PDCLIB=yes
 271 else
 272         PDCLIB_INCLUDES=''
 273         PDCLIB_LIBS_M0='-lpdclib-cortex-m0'
 274         PDCLIB_LIBS_M3='-lpdclib-cortex-m3'
 275         HAVE_PDCLIB=no
 276 fi
 277
 278 AM_CONDITIONAL(PDCLIB, [test x$HAVE_PDCLIB = xyes])
 279
 280 AC_SUBST(PDCLIB_INCLUDES)
 281 AC_SUBST(PDCLIB_LIBS_M0)
 282 AC_SUBST(PDCLIB_LIBS_M3)
 283 AC_SUBST(PDCLIB_ROOT)
 284 AC_SUBST(HAVE_PDCLIB)
 285
 286 if test "x$HAVE_ARM_CC" = "xyes"; then
 287         save_CC="$CC"
 288         save_CFLAGS="$CFLAGS"
 289         save_LIBS="$LIBS"
 290         CC="$ARM_CC"
 291         CFLAGS="-mthumb -mcpu=cortex-m0"
 292         LIBS="-ffreestanding -nostdlib"
 293         AC_LANG_PUSH([C])
 294
 295         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m0])
 296         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 297                           [HAVE_ARM_M0_CC=yes],
 298                           [HAVE_ARM_M0_CC=no])
 299         AC_MSG_RESULT([$HAVE_ARM_M0_CC])
 300
 301         CFLAGS="-mthumb -mcpu=cortex-m3"
 302         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m3])
 303         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 304                           [HAVE_ARM_M3_CC=yes],
 305                           [HAVE_ARM_M3_CC=no])
 306         AC_MSG_RESULT([$HAVE_ARM_M3_CC])
 307
 308         if test x$HAVE_PDCLIB != xyes; then
 309                 AC_CHECK_LIB(pdclib-cortex-m0,memcpy,
 310                              [],
 311                              [HAVE_ARM_M0_CC=no])
 312
 313                 AC_CHECK_LIB(pdclib-cortex-m3,memcpy,
 314                              [],
 315                              [HAVE_ARM_M3_CC=no])
 316         fi
 317
 318         AC_LANG_POP([C])
 319         LIBS="$save_LIBS"
 320         CFLAGS="$save_CFLAGS"
 321         CC="$save_CC"
 322 else
 323         HAVE_ARM_M3_CC=no
 324         HAVE_ARM_M0_CC=no
 325 fi
 326 AC_SUBST(HAVE_ARM_M3_CC)
 327 AC_SUBST(HAVE_ARM_M0_CC)
 328
 329 if test "x$HAVE_ARM_M3_CC" = "xno"; then
 330         AC_MSG_WARN([No cortex-m3 arm compiler found, STM32L binaries will not be built])
 331 fi
 332
 333 if test "x$HAVE_ARM_M0_CC" = "xno"; then
 334         AC_MSG_WARN([No cortex-m0 arm compiler found, LPC11U14 binaries will not be built])
 335 fi
 336
 337 #
 338 # Configure AVR compiler
 339 #
 340
 341 AC_ARG_WITH([avr-cc],
 342             [AS_HELP_STRING([--with-avr-cc],
 343                             [Name of AVR C compiler])],
 344             [],
 345             [with_avr_cc=auto])
 346
 347 if test "x$with_avr_cc" != "xno"; then
 348         if test "x$with_avr_cc" = "xauto"; then
 349                 with_avr_cc="avr-gcc"
 350                 AC_CHECK_PROG([HAVE_AVR_CC],[$with_avr_cc], yes, no)
 351         else
 352                 HAVE_AVR_CC=yes
 353         fi
 354 else
 355         HAVE_AVR_CC=no
 356 fi
 357
 358 AC_ARG_WITH([avr-objcopy],
 359             [AS_HELP_STRING([--with-avr-objcopy],
 360                             [Name of AVR objcopy])],
 361             [],
 362             [with_avr_objcopy=auto])
 363
 364 if test "x$with_avr_objcopy" != "xno"; then
 365         if test "x$with_avr_objcopy" = "xauto"; then
 366                 with_avr_objcopy="avr-objcopy"
 367                 AC_CHECK_PROG([HAVE_AVR_OBJCOPY],[$with_avr_objcopy], yes, no)
 368         else
 369                 HAVE_AVR_OBJCOPY=yes
 370         fi
 371 else
 372         HAVE_AVR_OBJCOPY=no
 373 fi
 374
 375 if test "x$HAVE_AVR_CC" = "xno" -o "x$HAVE_AVR_OBJCOPY" = "xno"; then
 376         AC_MSG_WARN([AVR compiler and objcopy not found, atmel binaries will not be built])
 377         HAVE_AVR_CC=no
 378 else
 379         save_CC="$CC"
 380         save_CFLAGS="$CFLAGS"
 381         save_LIBS="$LIBS"
 382
 383         CC="$with_avr_cc"
 384         CFLAGS="-mmcu=attiny85"
 385         AC_LANG_PUSH([C])
 386         AC_MSG_CHECKING([if ]$with_avr_cc[ can link programs])
 387         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 388                           [AVR_LINK=yes],
 389                           [AVR_LINK=no])
 390         AC_MSG_RESULT([$AVR_LINK])
 391         AC_LANG_POP([C])
 392
 393         LIBS="$save_LIBS"
 394         CFLAGS="$save_CFLAGS"
 395         CC="$save_CC"
 396
 397         if test "x$AVR_LINK" = xyes; then
 398                 AVR_CC=$with_avr_cc
 399                 AVR_OBJCOPY=$with_avr_objcopy
 400         else
 401                 HAVE_AVR_CC=no;
 402         fi
 403 fi
 404
 405 AC_SUBST(AVR_CC)
 406 AC_SUBST(AVR_OBJCOPY)
 407 AC_SUBST(HAVE_AVR_CC)
 408
 409 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
 410 if test "x$HAVE_NICKLE" = "xno"; then
 411         AC_MSG_ERROR([Please install nickle to build AltOs])
 412 fi
 413
 414 AC_ARG_WITH([readline],
 415             [AS_HELP_STRING([--with-readline],
 416                               [enable readline functionality in ao-dbg @<:@default=auto@:>@])],
 417               [],
 418               [with_readline=auto])
 419
 420 LIBREADLINE_LIBS=
 421
 422 if test x"$with_readline" != "xno"; then
 423         AC_CHECK_LIB([readline], [main],
 424                       [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 425                        AC_DEFINE([HAVE_LIBREADLINE], [1],
 426                          [Define if you have libreadline])],
 427                       [if test "x$with_readline" != xauto; then
 428                          AC_MSG_ERROR([--with-readline was given, but test for readline failed])
 429                        fi],
 430                        -lncurses)
 431 fi
 432
 433 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
 434
 435 AC_CHECK_HEADERS(libelf.h libelf/libelf.h, [break])
 436 AC_CHECK_HEADERS(gelf.h libelf/gelf.h, [break])
 437
 438 AC_ARG_WITH([stlink],
 439             [AS_HELP_STRING([--with-stlink],
 440                             [Build tools that use the stlink library (default: auto)])],
 441             [],
 442             [with_stlink=auto])
 443
 444 if test x"$with_stlink" != "xno"; then
 445         PKG_CHECK_MODULES([STLINK], [stlink], [HAVE_STLINK=yes], [HAVE_STLINK=no])
 446         if test x"$HAVE_STLINK" = "xno" -a x"$with_stlink" != "xauto"; then
 447                 AC_MSG_ERROR([--with-stlink was given, but stlink was not found])
 448         fi
 449 else
 450         HAVE_STLINK=no
 451 fi
 452
 453 if test x"$HAVE_STLINK" = "xyes"; then
 454         AC_DEFINE(HAVE_STLINK,1,[Using STlink library])
 455 fi
 456
 457 AM_CONDITIONAL([LIBSTLINK], [test x$HAVE_STLINK = xyes])
 458
 459 AC_ARG_ENABLE([multi-arch],
 460               [AS_HELP_STRING([--enable-multi-arch],
 461                               [enable building both i386 and amd64 libraries (default=auto)])],
 462               [MULTI_ARCH=$enableval],
 463               [MULTI_ARCH=auto])
 464
 465 case x"$MULTI_ARCH" in
 466 xauto)
 467         arch=`uname -m`
 468         case x"$arch" in
 469         xx86_64|xi*86)
 470                 save_CFLAGS="$CFLAGS"
 471                 save_LIBS="$LIBS"
 472                 LIBS="-ldl"
 473                 CFLAGS="-m64"
 474                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 475                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 476                                 [M64_LINK=yes],
 477                                 [M64_LINK=no])
 478                 AC_MSG_RESULT([$M64_LINK])
 479                 CFLAGS="-m32"
 480                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 481                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 482                                 [M32_LINK=yes],
 483                                 [M32_LINK=no])
 484                 AC_MSG_RESULT([$M32_LINK])
 485                 CFLAGS="$save_CFLAGS"
 486                 LIBS="$save_LIBS"
 487                 case x"$M64_LINK"x"$M32_LINK" in
 488                 xyesxyes)
 489                         MULTI_ARCH=yes
 490                         ;;
 491                 *)
 492                         MULTI_ARCH=no
 493                         ;;
 494                 esac
 495                 ;;
 496         *)
 497                 MULTI_ARCH=no
 498                 ;;
 499         esac
 500         ;;
 501 xyes|xno)
 502         ;;
 503 *)
 504         MULTI_ARCH="no"
 505         ;;
 506 esac
 507
 508 AM_CONDITIONAL([MULTI_ARCH], [test x$MULTI_ARCH = xyes])
 509
 510 AC_ARG_ENABLE([install-shared-mime-info],
 511               [AS_HELP_STRING([--disable-install-shared-mime-info],
 512                               [disable installing shared mime info files (default=yes)])],
 513               [INSTALL_SHARED_MIME_INFO=$enableval],
 514               [INSTALL_SHARED_MIME_INFO=yes])
 515
 516 AM_CONDITIONAL([INSTALL_SHARED_MIME_INFO], [test x$INSTALL_SHARED_MIME_INFO = xyes])
 517
 518 AC_OUTPUT([
 519 Makefile
 520 src/Makedefs
 521 src/chaoskey-v1.0/org.altusmetrum.ChaosKey.metainfo.xml
 522 altoslib/Makefile
 523 altoslib/AltosVersion.java
 524 icon/Makefile
 525 altosuilib/Makefile
 526 altosui/Makefile
 527 altosui/Info.plist
 528 altosui/altos-windows.nsi
 529 libaltos/Makefile
 530 micropeak/Makefile
 531 micropeak/Info.plist
 532 micropeak/micropeak-windows.nsi
 533 telegps/Makefile
 534 telegps/Info.plist
 535 telegps/telegps-windows.nsi
 536 altosdroid/Makefile
 537 altosdroid/local.properties
 538 altosdroid/AndroidManifest.xml
 539 ao-tools/Makefile
 540 ao-tools/lib/Makefile
 541 ao-tools/ao-rawload/Makefile
 542 ao-tools/ao-dbg/Makefile
 543 ao-tools/ao-bitbang/Makefile
 544 ao-tools/ao-eeprom/Makefile
 545 ao-tools/ao-list/Makefile
 546 ao-tools/ao-load/Makefile
 547 ao-tools/ao-telem/Makefile
 548 ao-tools/ao-stmload/Makefile
 549 ao-tools/ao-send-telem/Makefile
 550 ao-tools/ao-sky-flash/Makefile
 551 ao-tools/ao-dumpflash/Makefile
 552 ao-tools/ao-edit-telem/Makefile
 553 ao-tools/ao-dump-up/Makefile
 554 ao-tools/ao-elftohex/Makefile
 555 ao-tools/ao-usbload/Makefile
 556 ao-tools/ao-flash/Makefile
 557 ao-tools/ao-test-igniter/Makefile
 558 ao-tools/ao-test-baro/Makefile
 559 ao-tools/ao-test-flash/Makefile
 560 ao-tools/ao-cal-accel/Makefile
 561 ao-tools/ao-cal-freq/Makefile
 562 ao-tools/ao-test-gps/Makefile
 563 ao-tools/ao-usbtrng/Makefile
 564 ao-tools/ao-chaosread/Makefile
 565 ao-tools/ao-makebin/Makefile
 566 ao-utils/Makefile
 567 src/Version
 568 ])
 569
 570 echo ""
 571 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 572 echo ""
 573 echo "  Configuration"
 574 echo "    Arm compiler................: ${ARM_CC}"
 575 echo "    STM32L support..............: ${HAVE_ARM_M3_CC}"
 576 echo "    LPC11U14 support............: ${HAVE_ARM_M0_CC}"
 577 echo "    SDCC........................: ${SDCC}"
 578 echo "    CC1111 support..............: ${HAVE_SDCC}"
 579 echo "    AVR compiler................: ${AVR_CC} ${AVR_OBJCOPY}"
 580 echo "    AVR support.................: ${HAVE_AVR_CC}"
 581 echo "    Android support.............: ${HAVE_ANDROID_SDK}"
 582 echo "    Android release support.....: ${ANDROID_RELEASE}"
 583 echo "    STlink support..............: ${HAVE_STLINK}"
 584 echo "    Local pdclib................: ${HAVE_PDCLIB}"
 585 echo "    i386 and amd64 libaltos.....: ${MULTI_ARCH}"
 586 echo "    install shared mime info....: ${INSTALL_SHARED_MIME_INFO}"
 587 echo ""
 588 echo "  Java"
 589 echo "    freetts.....................: ${FREETTS}"
 590 echo "    jfreechart..................: ${JFREECHART}"
 591 echo "    jcommon.....................: ${JCOMMON}"
 592 echo "    JVM include.................: ${JVM_INCLUDE}"
 593 echo "    Google maps API key.........: ${HAVE_GOOGLE_KEY}"
 594 if test x${ANDROID_SDK} != "xno"; then
 595 echo ""
 596 echo "  Android path"
 597 echo "    Android SDK.................: ${ANDROID_SDK}"
 598 fi
 599 echo ""