git.gag.com Git - fw/altos/blob - configure.ac

   1 dnl
   2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
   3 dnl
   4 dnl  This program is free software; you can redistribute it and/or modify
   5 dnl  it under the terms of the GNU General Public License as published by
   6 dnl  the Free Software Foundation; either version 2 of the License, or
   7 dnl  (at your option) any later version.
   8 dnl
   9 dnl  This program is distributed in the hope that it will be useful, but
  10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 dnl  General Public License for more details.
  13 dnl
  14 dnl  You should have received a copy of the GNU General Public License along
  15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
  16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17 dnl
  18 dnl Process this file with autoconf to create configure.
  19
  20 AC_PREREQ(2.57)
  21 AC_INIT([altos], 1.8.6.1)
  22 ANDROID_VERSION=17
  23 AC_CONFIG_SRCDIR([src/kernel/ao.h])
  24 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  25 AM_MAINTAINER_MODE
  26
  27 RELEASE_DATE=2018-06-17
  28 AC_SUBST(RELEASE_DATE)
  29
  30 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
  31 AC_SUBST(VERSION_DASH)
  32 AC_SUBST(ANDROID_VERSION)
  33
  34 dnl ==========================================================================
  35 dnl Java library versions
  36
  37 ALTOSUILIB_VERSION=13
  38 ALTOSLIB_VERSION=13
  39
  40 AC_SUBST(ALTOSLIB_VERSION)
  41 AC_DEFINE(ALTOSLIB_VERSION,$ALTOSLIB_VERSION,[Version of the AltosLib package])
  42 AC_SUBST(ALTOSUILIB_VERSION)
  43 AC_DEFINE(ALTOSUILIB_VERSION,$ALTOSUILIB_VERSION,[Version of the AltosUILib package])
  44
  45 dnl ==========================================================================
  46
  47 AM_CONFIG_HEADER(config.h)
  48
  49 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
  50         [Set freetts class path (default /usr/share/java)]),
  51         [FREETTS=$withval], [FREETTS=/usr/share/java])
  52
  53 AC_SUBST(FREETTS)
  54
  55 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
  56         [Set jfreechart class path (default /usr/share/java)]),
  57         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
  58
  59 AC_SUBST(JFREECHART)
  60
  61 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
  62         [Set jcommon class path (default /usr/share/java)]),
  63         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
  64
  65 AC_SUBST(JCOMMON)
  66
  67 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm-include=PATH],
  68         [Set jvm include path for jni builds (default searches in /usr/lib/jvm)]),
  69         [JVM_INCLUDE=$withval], [JVM_INCLUDE=auto])
  70
  71 if test "x$JVM_INCLUDE" = "xauto"; then
  72         AC_MSG_CHECKING([JVM include files])
  73         for jvm in default-java java-6-openjdk java-6-sun; do
  74                 if test "x$JVM_INCLUDE" = "xauto"; then
  75                         INCLUDE="/usr/lib/jvm/$jvm/include"
  76                         if test -f "$INCLUDE"/jni.h; then
  77                                 JVM_INCLUDE="$INCLUDE"
  78                         fi
  79                 fi
  80         done
  81         if test "x$JVM_INCLUDE" = "xauto"; then
  82                 AC_MSG_ERROR([no JVM include files found])
  83         fi
  84         AC_MSG_RESULT([$JVM_INCLUDE])
  85 fi
  86
  87 AC_SUBST(JVM_INCLUDE)
  88
  89 AC_ARG_WITH(android, AS_HELP_STRING([--with-android=PATH],
  90         [Set android SDK path (default searches in a variety of places)]),
  91         [ANDROID_SDK=$withval], [ANDROID_SDK=${ANDROID_SDK:-auto}])
  92
  93 if test "x$ANDROID_SDK" = "xauto"; then
  94         AC_MSG_CHECKING([Android SDK])
  95         for sdk in ../android/android-sdk-linux ../android/android-sdk ../android-sdk ../android-sdk-linux $HOME/android; do
  96                 if test "x$ANDROID_SDK" = "xauto"; then
  97                         SDK="$sdk"
  98                         if test -f "$SDK/SDK Readme.txt"; then
  99                                 ANDROID_SDK=`readlink -m "$SDK"`
 100                         fi
 101                 fi
 102         done
 103         if test "x$ANDROID_SDK" = "xauto"; then
 104                 AC_MSG_NOTICE([no Android SDK found])
 105                 ANDROID_SDK=no
 106         fi
 107         AC_MSG_RESULT([$ANDROID_SDK])
 108 fi
 109 if test "x$ANDROID_SDK" != "xno"; then
 110         AC_MSG_CHECKING([Android SDK version])
 111         SDK_VERSION=`grep -i '^Pkg.Revision=' $ANDROID_SDK/tools/source.properties | cut -f2- -d= | sed s/^r//`
 112         SDK_MAJOR_VERSION="`echo $SDK_VERSION | sed 's/[[^0-9]].*//'`"
 113         if test "$SDK_MAJOR_VERSION" -lt 17 ; then
 114                 AC_MSG_NOTICE([SDK version $SDK_VERSION is too old. Need >= r17])
 115                 ANDROID_SDK=no
 116         else
 117                 AC_MSG_RESULT([$SDK_VERSION])
 118         fi
 119 fi
 120 if test "x$ANDROID_SDK" != "xno"; then
 121         AC_MSG_CHECKING([Android SDK API Level])
 122         if test -f "$ANDROID_SDK/platforms/android-10/source.properties"; then
 123                 API_LEVEL=`sed -ne 's/^AndroidVersion.ApiLevel=//p' $ANDROID_SDK/platforms/android-10/source.properties`
 124                 if test "$API_LEVEL" = "10"; then
 125                         AC_MSG_RESULT([$API_LEVEL])
 126                 else
 127                         AC_MSG_NOTICE([API Level 10 not installed correctly.])
 128                         ANDROID_SDK=no
 129                 fi
 130         else
 131                 AC_MSG_NOTICE([API Level 10 not installed, but is required.])
 132                 ANDROID_SDK=no
 133         fi
 134 fi
 135 if test "x$ANDROID_SDK" != "xno"; then
 136         AC_MSG_CHECKING([Android SDK required extras])
 137         if test -f "$ANDROID_SDK/extras/android/support/source.properties"; then
 138                 ANDROID_SUPPORT_LIB_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/android/support/source.properties`
 139                 if test -f "$ANDROID_SDK/extras/google/google_play_services/source.properties"; then
 140                         GOOGLE_PLAY_SERVICES_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/google/google_play_services/source.properties`
 141                         AC_MSG_RESULT([$ANDROID_SUPPORT_LIB_NAME, $GOOGLE_PLAY_SERVICES_NAME])
 142                 else
 143                         AC_MSG_NOTICE([Google Play Services library not installed.])
 144                         ANDROID_SDK=no
 145                 fi
 146         else
 147                 AC_MSG_NOTICE([Android Support Library not installed.])
 148                 ANDROID_SDK=no
 149         fi
 150 fi
 151
 152 ANDROID_RELEASE=no
 153 if test "x$ANDROID_SDK" != "xno"; then
 154         HAVE_ANDROID_SDK="yes"
 155         if test -f "$HOME/altusmetrumllc/google-play-release.keystore" -a -f "$HOME/altusmetrumllc/google-play-passphrase"; then
 156                 ANDROID_RELEASE=yes
 157         fi
 158 else
 159         HAVE_ANDROID_SDK="no"
 160 fi
 161
 162 AM_CONDITIONAL([ANDROID], [test x$ANDROID_SDK != xno])
 163 AM_CONDITIONAL([ANDROID_RELEASE], [test x$ANDROID_RELEASE = xyes])
 164
 165 AC_SUBST(ANDROID_SDK)
 166
 167 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
 168             [Set the directory to install the 'fat-install' distribution files to (defaults to no such target)]),
 169             [FATDIR=$withval], [FATDIR=none])
 170
 171 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
 172
 173 AC_SUBST(FATDIR)
 174
 175 AC_ARG_WITH(google-key, AS_HELP_STRING([--with-google-key=PATH],
 176             [Set the file to read the google maps API key from (defaults to ~/altusmetrumllc/google-maps-api-key)]),
 177             [GOOGLEKEYFILE=$withval], [GOOGLEKEYFILE=$HOME/altusmetrumllc/google-maps-api-key])
 178
 179 if test -r "$GOOGLEKEYFILE" -a -s "$GOOGLEKEYFILE"; then
 180         GOOGLEKEY=`cat "$GOOGLEKEYFILE"`
 181         HAVE_GOOGLE_KEY="yes"
 182 else
 183         GOOGLEKEY='null'
 184         HAVE_GOOGLE_KEY="no"
 185 fi
 186
 187 AC_ARG_ENABLE(faketime, AS_HELP_STRING([--enable-faketime],
 188               [Use faketime program to ensure pdf files are reproducible (default=no)]),
 189               [FAKETIME=$enableval], [FAKETIME=no])
 190
 191 AM_CONDITIONAL(FAKETIME, [test x$FAKETIME = xyes])
 192
 193 AC_SUBST(GOOGLEKEY)
 194
 195 AC_PROG_CC
 196 AC_PROG_INSTALL
 197 AC_PROG_LN_S
 198 AC_PROG_LIBTOOL
 199 PKG_PROG_PKG_CONFIG
 200
 201 CFLAGS="-g"
 202 WARN_CFLAGS=""
 203 if test "x$GCC" = "xyes"; then
 204         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
 205         -Wmissing-prototypes -Wmissing-declarations \
 206         -Wnested-externs -fno-strict-aliasing"
 207         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
 208         [Can use #warning in C files])
 209 fi
 210 AC_SUBST(WARN_CFLAGS)
 211
 212 #
 213 # Configure SDCC
 214 #
 215
 216 AC_ARG_WITH([sdcc],
 217             [AS_HELP_STRING([--with-sdcc],
 218                             [Name of SDCC])],
 219             [],
 220             [with_sdcc=auto])
 221
 222 if test "x$with_sdcc" != "xno"; then
 223         if test "x$with_sdcc" = "xauto"; then
 224                 with_sdcc="sdcc"
 225                 AC_CHECK_PROG([HAVE_SDCC],[$with_sdcc], yes, no)
 226         else
 227                 HAVE_SDCC=yes
 228         fi
 229 else
 230         HAVE_SDCC=no
 231 fi
 232
 233 if test "x$HAVE_SDCC" = "xno"; then
 234         AC_MSG_WARN([SDCC not found, cc1111 binaries will not be built])
 235 else
 236         SDCC=$with_sdcc
 237 fi
 238
 239 AC_SUBST(SDCC)
 240 AC_SUBST(HAVE_SDCC)
 241
 242 #
 243 # Configure ARM compiler for STM32L and LPC11U14
 244 #
 245
 246 AC_ARG_WITH([arm-cc],
 247             [AS_HELP_STRING([--with-arm-cc],
 248                             [Name of ARM C compiler])],
 249             [],
 250             [with_arm_cc=auto])
 251
 252 if test "x$with_arm_cc" != "xno"; then
 253         if test "x$with_arm_cc" = "xauto"; then
 254                 with_arm_cc="arm-none-eabi-gcc"
 255                 AC_CHECK_PROG([HAVE_ARM_CC],[$with_arm_cc], yes, no)
 256         else
 257                 HAVE_ARM_CC=yes
 258         fi
 259 else
 260         HAVE_ARM_CC=no
 261 fi
 262
 263 if test "x$HAVE_ARM_CC" = "xno"; then
 264         AC_MSG_WARN([Arm compiler not found, ARM binaries will not be built])
 265 else
 266         ARM_CC=$with_arm_cc
 267 fi
 268 AC_SUBST(HAVE_ARM_CC)
 269 AC_SUBST(ARM_CC)
 270
 271 if test -d pdclib -a x"$HAVE_ARM_CC" = xyes; then
 272         PDCLIB_ROOT='$(TOPDIR)/../pdclib-root'
 273         PDCLIB_INCLUDES='-I$(TOPDIR)/../pdclib-root/include'
 274         PDCLIB_LIBS_M0='-L$(TOPDIR)/../pdclib-root/lib -lpdclib-cortex-m0'
 275         PDCLIB_LIBS_M3='-L$(TOPDIR)/../pdclib-root/lib -lpdclib-cortex-m3'
 276         HAVE_PDCLIB=yes
 277 else
 278         PDCLIB_INCLUDES=''
 279         PDCLIB_LIBS_M0='-lpdclib-cortex-m0'
 280         PDCLIB_LIBS_M3='-lpdclib-cortex-m3'
 281         HAVE_PDCLIB=no
 282 fi
 283
 284 AM_CONDITIONAL(PDCLIB, [test x$HAVE_PDCLIB = xyes])
 285
 286 AC_SUBST(PDCLIB_INCLUDES)
 287 AC_SUBST(PDCLIB_LIBS_M0)
 288 AC_SUBST(PDCLIB_LIBS_M3)
 289 AC_SUBST(PDCLIB_ROOT)
 290 AC_SUBST(HAVE_PDCLIB)
 291
 292 if test "x$HAVE_ARM_CC" = "xyes"; then
 293         save_CC="$CC"
 294         save_CFLAGS="$CFLAGS"
 295         save_LIBS="$LIBS"
 296         CC="$ARM_CC"
 297         CFLAGS="-mthumb -mcpu=cortex-m0"
 298         LIBS="-ffreestanding -nostdlib"
 299         AC_LANG_PUSH([C])
 300
 301         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m0])
 302         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 303                           [HAVE_ARM_M0_CC=yes],
 304                           [HAVE_ARM_M0_CC=no])
 305         AC_MSG_RESULT([$HAVE_ARM_M0_CC])
 306
 307         CFLAGS="-mthumb -mcpu=cortex-m3"
 308         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m3])
 309         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 310                           [HAVE_ARM_M3_CC=yes],
 311                           [HAVE_ARM_M3_CC=no])
 312         AC_MSG_RESULT([$HAVE_ARM_M3_CC])
 313
 314         if test x$HAVE_PDCLIB != xyes; then
 315                 AC_CHECK_LIB(pdclib-cortex-m0,memcpy,
 316                              [],
 317                              [HAVE_ARM_M0_CC=no])
 318
 319                 AC_CHECK_LIB(pdclib-cortex-m3,memcpy,
 320                              [],
 321                              [HAVE_ARM_M3_CC=no])
 322         fi
 323
 324         AC_LANG_POP([C])
 325         LIBS="$save_LIBS"
 326         CFLAGS="$save_CFLAGS"
 327         CC="$save_CC"
 328 else
 329         HAVE_ARM_M3_CC=no
 330         HAVE_ARM_M0_CC=no
 331 fi
 332 AC_SUBST(HAVE_ARM_M3_CC)
 333 AC_SUBST(HAVE_ARM_M0_CC)
 334
 335 if test "x$HAVE_ARM_M3_CC" = "xno"; then
 336         AC_MSG_WARN([No cortex-m3 arm compiler found, STM32L binaries will not be built])
 337 fi
 338
 339 if test "x$HAVE_ARM_M0_CC" = "xno"; then
 340         AC_MSG_WARN([No cortex-m0 arm compiler found, LPC11U14 binaries will not be built])
 341 fi
 342
 343 #
 344 # Configure AVR compiler
 345 #
 346
 347 AC_ARG_WITH([avr-cc],
 348             [AS_HELP_STRING([--with-avr-cc],
 349                             [Name of AVR C compiler])],
 350             [],
 351             [with_avr_cc=auto])
 352
 353 if test "x$with_avr_cc" != "xno"; then
 354         if test "x$with_avr_cc" = "xauto"; then
 355                 with_avr_cc="avr-gcc"
 356                 AC_CHECK_PROG([HAVE_AVR_CC],[$with_avr_cc], yes, no)
 357         else
 358                 HAVE_AVR_CC=yes
 359         fi
 360 else
 361         HAVE_AVR_CC=no
 362 fi
 363
 364 AC_ARG_WITH([avr-objcopy],
 365             [AS_HELP_STRING([--with-avr-objcopy],
 366                             [Name of AVR objcopy])],
 367             [],
 368             [with_avr_objcopy=auto])
 369
 370 if test "x$with_avr_objcopy" != "xno"; then
 371         if test "x$with_avr_objcopy" = "xauto"; then
 372                 with_avr_objcopy="avr-objcopy"
 373                 AC_CHECK_PROG([HAVE_AVR_OBJCOPY],[$with_avr_objcopy], yes, no)
 374         else
 375                 HAVE_AVR_OBJCOPY=yes
 376         fi
 377 else
 378         HAVE_AVR_OBJCOPY=no
 379 fi
 380
 381 if test "x$HAVE_AVR_CC" = "xno" -o "x$HAVE_AVR_OBJCOPY" = "xno"; then
 382         AC_MSG_WARN([AVR compiler and objcopy not found, atmel binaries will not be built])
 383         HAVE_AVR_CC=no
 384 else
 385         save_CC="$CC"
 386         save_CFLAGS="$CFLAGS"
 387         save_LIBS="$LIBS"
 388
 389         CC="$with_avr_cc"
 390         CFLAGS="-mmcu=attiny85"
 391         AC_LANG_PUSH([C])
 392         AC_MSG_CHECKING([if ]$with_avr_cc[ can link programs])
 393         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 394                           [AVR_LINK=yes],
 395                           [AVR_LINK=no])
 396         AC_MSG_RESULT([$AVR_LINK])
 397         AC_LANG_POP([C])
 398
 399         LIBS="$save_LIBS"
 400         CFLAGS="$save_CFLAGS"
 401         CC="$save_CC"
 402
 403         if test "x$AVR_LINK" = xyes; then
 404                 AVR_CC=$with_avr_cc
 405                 AVR_OBJCOPY=$with_avr_objcopy
 406         else
 407                 HAVE_AVR_CC=no;
 408         fi
 409 fi
 410
 411 AC_SUBST(AVR_CC)
 412 AC_SUBST(AVR_OBJCOPY)
 413 AC_SUBST(HAVE_AVR_CC)
 414
 415 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
 416 if test "x$HAVE_NICKLE" = "xno"; then
 417         AC_MSG_ERROR([Please install nickle to build AltOs])
 418 fi
 419
 420 AC_ARG_WITH([readline],
 421             [AS_HELP_STRING([--with-readline],
 422                               [enable readline functionality in ao-dbg @<:@default=auto@:>@])],
 423               [],
 424               [with_readline=auto])
 425
 426 LIBREADLINE_LIBS=
 427
 428 if test x"$with_readline" != "xno"; then
 429         AC_CHECK_LIB([readline], [main],
 430                       [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 431                        AC_DEFINE([HAVE_LIBREADLINE], [1],
 432                          [Define if you have libreadline])],
 433                       [if test "x$with_readline" != xauto; then
 434                          AC_MSG_ERROR([--with-readline was given, but test for readline failed])
 435                        fi],
 436                        -lncurses)
 437 fi
 438
 439 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
 440
 441 AC_CHECK_HEADERS(libelf.h libelf/libelf.h, [break])
 442 AC_CHECK_HEADERS(gelf.h libelf/gelf.h, [break])
 443
 444 AC_ARG_WITH([stlink],
 445             [AS_HELP_STRING([--with-stlink],
 446                             [Build tools that use the stlink library (default: auto)])],
 447             [],
 448             [with_stlink=auto])
 449
 450 if test x"$with_stlink" != "xno"; then
 451         PKG_CHECK_MODULES([STLINK], [stlink], [HAVE_STLINK=yes], [HAVE_STLINK=no])
 452         if test x"$HAVE_STLINK" = "xno" -a x"$with_stlink" != "xauto"; then
 453                 AC_MSG_ERROR([--with-stlink was given, but stlink was not found])
 454         fi
 455 else
 456         HAVE_STLINK=no
 457 fi
 458
 459 if test x"$HAVE_STLINK" = "xyes"; then
 460         AC_DEFINE(HAVE_STLINK,1,[Using STlink library])
 461 fi
 462
 463 AM_CONDITIONAL([LIBSTLINK], [test x$HAVE_STLINK = xyes])
 464
 465 AC_ARG_ENABLE([multi-arch],
 466               [AS_HELP_STRING([--enable-multi-arch],
 467                               [enable building both i386 and amd64 libraries (default=auto)])],
 468               [MULTI_ARCH=$enableval],
 469               [MULTI_ARCH=auto])
 470
 471 case x"$MULTI_ARCH" in
 472 xauto)
 473         arch=`uname -m`
 474         case x"$arch" in
 475         xx86_64|xi*86)
 476                 save_CFLAGS="$CFLAGS"
 477                 save_LIBS="$LIBS"
 478                 LIBS="-ldl"
 479                 CFLAGS="-m64"
 480                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 481                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 482                                 [M64_LINK=yes],
 483                                 [M64_LINK=no])
 484                 AC_MSG_RESULT([$M64_LINK])
 485                 CFLAGS="-m32"
 486                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 487                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 488                                 [M32_LINK=yes],
 489                                 [M32_LINK=no])
 490                 AC_MSG_RESULT([$M32_LINK])
 491                 CFLAGS="$save_CFLAGS"
 492                 LIBS="$save_LIBS"
 493                 case x"$M64_LINK"x"$M32_LINK" in
 494                 xyesxyes)
 495                         MULTI_ARCH=yes
 496                         ;;
 497                 *)
 498                         MULTI_ARCH=no
 499                         ;;
 500                 esac
 501                 ;;
 502         *)
 503                 MULTI_ARCH=no
 504                 ;;
 505         esac
 506         ;;
 507 xyes|xno)
 508         ;;
 509 *)
 510         MULTI_ARCH="no"
 511         ;;
 512 esac
 513
 514 AM_CONDITIONAL([MULTI_ARCH], [test x$MULTI_ARCH = xyes])
 515
 516 AC_ARG_ENABLE([install-shared-mime-info],
 517               [AS_HELP_STRING([--disable-install-shared-mime-info],
 518                               [disable installing shared mime info files (default=yes)])],
 519               [INSTALL_SHARED_MIME_INFO=$enableval],
 520               [INSTALL_SHARED_MIME_INFO=yes])
 521
 522 AM_CONDITIONAL([INSTALL_SHARED_MIME_INFO], [test x$INSTALL_SHARED_MIME_INFO = xyes])
 523
 524 AC_OUTPUT([
 525 Makefile
 526 src/Makedefs
 527 src/chaoskey-v1.0/org.altusmetrum.ChaosKey.metainfo.xml
 528 doc/Makefile
 529 altoslib/Makefile
 530 altoslib/AltosVersion.java
 531 icon/Makefile
 532 altosuilib/Makefile
 533 altosui/Makefile
 534 altosui/Info.plist
 535 altosui/altos-windows.nsi
 536 libaltos/Makefile
 537 micropeak/Makefile
 538 micropeak/Info.plist
 539 micropeak/micropeak-windows.nsi
 540 telegps/Makefile
 541 telegps/Info.plist
 542 telegps/telegps-windows.nsi
 543 altosdroid/Makefile
 544 altosdroid/local.properties
 545 altosdroid/AndroidManifest.xml
 546 ao-tools/Makefile
 547 ao-tools/lib/Makefile
 548 ao-tools/ao-rawload/Makefile
 549 ao-tools/ao-dbg/Makefile
 550 ao-tools/ao-bitbang/Makefile
 551 ao-tools/ao-eeprom/Makefile
 552 ao-tools/ao-list/Makefile
 553 ao-tools/ao-load/Makefile
 554 ao-tools/ao-telem/Makefile
 555 ao-tools/ao-stmload/Makefile
 556 ao-tools/ao-send-telem/Makefile
 557 ao-tools/ao-sky-flash/Makefile
 558 ao-tools/ao-dumpflash/Makefile
 559 ao-tools/ao-edit-telem/Makefile
 560 ao-tools/ao-dump-up/Makefile
 561 ao-tools/ao-elftohex/Makefile
 562 ao-tools/ao-usbload/Makefile
 563 ao-tools/ao-flash/Makefile
 564 ao-tools/ao-test-igniter/Makefile
 565 ao-tools/ao-test-baro/Makefile
 566 ao-tools/ao-test-flash/Makefile
 567 ao-tools/ao-cal-accel/Makefile
 568 ao-tools/ao-cal-freq/Makefile
 569 ao-tools/ao-test-gps/Makefile
 570 ao-tools/ao-usbtrng/Makefile
 571 ao-tools/ao-chaosread/Makefile
 572 ao-tools/ao-makebin/Makefile
 573 ao-utils/Makefile
 574 map-server/Makefile
 575 map-server/altos-mapd/Makefile
 576 map-server/altos-map/Makefile
 577 src/Version
 578 ])
 579
 580 echo ""
 581 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 582 echo ""
 583 echo "  Configuration"
 584 echo "    Arm compiler................: ${ARM_CC}"
 585 echo "    STM32L support..............: ${HAVE_ARM_M3_CC}"
 586 echo "    LPC11U14 support............: ${HAVE_ARM_M0_CC}"
 587 echo "    SDCC........................: ${SDCC}"
 588 echo "    CC1111 support..............: ${HAVE_SDCC}"
 589 echo "    AVR compiler................: ${AVR_CC} ${AVR_OBJCOPY}"
 590 echo "    AVR support.................: ${HAVE_AVR_CC}"
 591 echo "    Android support.............: ${HAVE_ANDROID_SDK}"
 592 echo "    Android release support.....: ${ANDROID_RELEASE}"
 593 echo "    STlink support..............: ${HAVE_STLINK}"
 594 echo "    Local pdclib................: ${HAVE_PDCLIB}"
 595 echo "    i386 and amd64 libaltos.....: ${MULTI_ARCH}"
 596 echo "    install shared mime info....: ${INSTALL_SHARED_MIME_INFO}"
 597 echo ""
 598 echo "  Java"
 599 echo "    freetts.....................: ${FREETTS}"
 600 echo "    jfreechart..................: ${JFREECHART}"
 601 echo "    jcommon.....................: ${JCOMMON}"
 602 echo "    JVM include.................: ${JVM_INCLUDE}"
 603 echo "    Google maps API key.........: ${HAVE_GOOGLE_KEY}"
 604 if test x${ANDROID_SDK} != "xno"; then
 605 echo ""
 606 echo "  Android path"
 607 echo "    Android SDK.................: ${ANDROID_SDK}"
 608 fi
 609 echo ""