git.gag.com Git - fw/altos/blob - configure.ac

   1 dnl
   2 dnl  Copyright © 2008,2009 Keith Packard <keithp@keithp.com>
   3 dnl
   4 dnl  This program is free software; you can redistribute it and/or modify
   5 dnl  it under the terms of the GNU General Public License as published by
   6 dnl  the Free Software Foundation; either version 2 of the License, or
   7 dnl  (at your option) any later version.
   8 dnl
   9 dnl  This program is distributed in the hope that it will be useful, but
  10 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 dnl  General Public License for more details.
  13 dnl
  14 dnl  You should have received a copy of the GNU General Public License along
  15 dnl  with this program; if not, write to the Free Software Foundation, Inc.,
  16 dnl  59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  17 dnl
  18 dnl Process this file with autoconf to create configure.
  19
  20 AC_PREREQ(2.57)
  21 AC_INIT([altos], 1.9)
  22 ANDROID_VERSION=18
  23 AC_CONFIG_SRCDIR([src/kernel/ao.h])
  24 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  25 AM_MAINTAINER_MODE
  26
  27 RELEASE_DATE=2018-12-31
  28 AC_SUBST(RELEASE_DATE)
  29
  30 VERSION_DASH=`echo $VERSION | sed 's/\./-/g'`
  31 AC_SUBST(VERSION_DASH)
  32 AC_SUBST(ANDROID_VERSION)
  33
  34 dnl ==========================================================================
  35 dnl Java library versions
  36
  37 ALTOSUILIB_VERSION=13
  38 ALTOSLIB_VERSION=13
  39
  40 AC_SUBST(ALTOSLIB_VERSION)
  41 AC_DEFINE(ALTOSLIB_VERSION,$ALTOSLIB_VERSION,[Version of the AltosLib package])
  42 AC_SUBST(ALTOSUILIB_VERSION)
  43 AC_DEFINE(ALTOSUILIB_VERSION,$ALTOSUILIB_VERSION,[Version of the AltosUILib package])
  44
  45 dnl ==========================================================================
  46
  47 AM_CONFIG_HEADER(config.h)
  48
  49 AC_ARG_WITH(freetts, AS_HELP_STRING([--with-freetts=PATH],
  50         [Set freetts class path (default /usr/share/java)]),
  51         [FREETTS=$withval], [FREETTS=/usr/share/java])
  52
  53 AC_SUBST(FREETTS)
  54
  55 AC_ARG_WITH(jfreechart, AS_HELP_STRING([--with-jfreechart=PATH],
  56         [Set jfreechart class path (default /usr/share/java)]),
  57         [JFREECHART=$withval], [JFREECHART=/usr/share/java])
  58
  59 AC_SUBST(JFREECHART)
  60
  61 AC_ARG_WITH(jcommon, AS_HELP_STRING([--with-jcommon=PATH],
  62         [Set jcommon class path (default /usr/share/java)]),
  63         [JCOMMON=$withval], [JCOMMON=/usr/share/java])
  64
  65 AC_SUBST(JCOMMON)
  66
  67 AC_ARG_WITH(jvm, AS_HELP_STRING([--with-jvm=PATH],
  68         [Set jvm path for java builds (default searches in /usr/lib/jvm)]),
  69         [JVM=$withval], [JVM=auto])
  70
  71 if test "x$JVM" = "xauto"; then
  72         AC_MSG_CHECKING([JVM])
  73         for jvm in default-java java-6-openjdk java-7-openjdk java-8-openjdk java-9-openjdk java-10-openjdk java-11-openjdk java-12-openjdk java-13-openjdk java-6-sun java-8-openjdk-amd64; do
  74                 if test "x$JVM" = "xauto"; then
  75                         INCLUDE="/usr/lib/jvm/$jvm/include"
  76                         if test -f "$INCLUDE"/jni.h; then
  77                                 JVM=/usr/lib/jvm/"$jvm"
  78                         fi
  79                 fi
  80         done
  81         if test "x$JVM" = "xauto"; then
  82                 AC_MSG_ERROR([no JVM files found])
  83         fi
  84         AC_MSG_RESULT([$JVM])
  85 fi
  86
  87 AC_ARG_WITH(java-version, AS_HELP_STRING([--with-java-version=7],
  88                                          [Set java language compatibility version (default is 7)]),
  89            [JAVA_VERSION=$withval], [JAVA_VERSION=7])
  90
  91 JAVAC="$JVM"/bin/javac
  92 JAVA="$JVM"/bin/java
  93 JVM_INCLUDE="$JVM"/include
  94 JAVAC_VERSION_FLAGS="-target 1.$JAVA_VERSION -source 1.$JAVA_VERSION"
  95
  96 AC_SUBST(JAVAC)
  97 AC_SUBST(JAVA)
  98 AC_SUBST(JVM)
  99 AC_SUBST(JVM_INCLUDE)
 100 AC_SUBST(JAVAC_VERSION_FLAGS)
 101
 102
 103 AC_ARG_WITH(android, AS_HELP_STRING([--with-android=PATH],
 104         [Set android SDK path (default searches in a variety of places)]),
 105         [ANDROID_SDK=$withval], [ANDROID_SDK=${ANDROID_SDK:-auto}])
 106
 107 if test "x$ANDROID_SDK" = "xauto"; then
 108         AC_MSG_CHECKING([Android SDK])
 109         for sdk in ../android/android-sdk-linux ../android/android-sdk ../android-sdk ../android-sdk-linux $HOME/android; do
 110                 if test "x$ANDROID_SDK" = "xauto"; then
 111                         SDK="$sdk"
 112                         if test -f "$SDK/SDK Readme.txt"; then
 113                                 ANDROID_SDK=`readlink -m "$SDK"`
 114                         fi
 115                 fi
 116         done
 117         if test "x$ANDROID_SDK" = "xauto"; then
 118                 AC_MSG_NOTICE([no Android SDK found])
 119                 ANDROID_SDK=no
 120         fi
 121         AC_MSG_RESULT([$ANDROID_SDK])
 122 fi
 123 if test "x$ANDROID_SDK" != "xno"; then
 124         AC_MSG_CHECKING([Android SDK version])
 125         SDK_VERSION=`grep -i '^Pkg.Revision=' $ANDROID_SDK/tools/source.properties | cut -f2- -d= | sed s/^r//`
 126         SDK_MAJOR_VERSION="`echo $SDK_VERSION | sed 's/[[^0-9]].*//'`"
 127         if test "$SDK_MAJOR_VERSION" -lt 17 ; then
 128                 AC_MSG_NOTICE([SDK version $SDK_VERSION is too old. Need >= r17])
 129                 ANDROID_SDK=no
 130         else
 131                 AC_MSG_RESULT([$SDK_VERSION])
 132         fi
 133 fi
 134 if test "x$ANDROID_SDK" != "xno"; then
 135         AC_MSG_CHECKING([Android SDK API Level])
 136         if test -f "$ANDROID_SDK/platforms/android-10/source.properties"; then
 137                 API_LEVEL=`sed -ne 's/^AndroidVersion.ApiLevel=//p' $ANDROID_SDK/platforms/android-10/source.properties`
 138                 if test "$API_LEVEL" = "10"; then
 139                         AC_MSG_RESULT([$API_LEVEL])
 140                 else
 141                         AC_MSG_NOTICE([API Level 10 not installed correctly.])
 142                         ANDROID_SDK=no
 143                 fi
 144         else
 145                 AC_MSG_NOTICE([API Level 10 not installed, but is required.])
 146                 ANDROID_SDK=no
 147         fi
 148 fi
 149 if test "x$ANDROID_SDK" != "xno"; then
 150         AC_MSG_CHECKING([Android SDK required extras])
 151         if test -f "$ANDROID_SDK/extras/android/support/source.properties"; then
 152                 ANDROID_SUPPORT_LIB_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/android/support/source.properties`
 153                 if test -f "$ANDROID_SDK/extras/google/google_play_services/source.properties"; then
 154                         GOOGLE_PLAY_SERVICES_NAME=`sed -ne 's/^Extra.NameDisplay=//p' $ANDROID_SDK/extras/google/google_play_services/source.properties`
 155                         AC_MSG_RESULT([$ANDROID_SUPPORT_LIB_NAME, $GOOGLE_PLAY_SERVICES_NAME])
 156                 else
 157                         AC_MSG_NOTICE([Google Play Services library not installed.])
 158                         ANDROID_SDK=no
 159                 fi
 160         else
 161                 AC_MSG_NOTICE([Android Support Library not installed.])
 162                 ANDROID_SDK=no
 163         fi
 164 fi
 165
 166 ANDROID_RELEASE=no
 167 if test "x$ANDROID_SDK" != "xno"; then
 168         HAVE_ANDROID_SDK="yes"
 169         if test -f "$HOME/altusmetrumllc/google-play-release.keystore" -a -f "$HOME/altusmetrumllc/google-play-passphrase"; then
 170                 ANDROID_RELEASE=yes
 171         fi
 172 else
 173         HAVE_ANDROID_SDK="no"
 174 fi
 175
 176 AM_CONDITIONAL([ANDROID], [test x$ANDROID_SDK != xno])
 177 AM_CONDITIONAL([ANDROID_RELEASE], [test x$ANDROID_RELEASE = xyes])
 178
 179 AC_SUBST(ANDROID_SDK)
 180
 181 AC_ARG_WITH(fat-dir, AS_HELP_STRING([--with-fat-dir=PATH],
 182             [Set the directory to install the 'fat-install' distribution files to (defaults to no such target)]),
 183             [FATDIR=$withval], [FATDIR=none])
 184
 185 AM_CONDITIONAL(FATINSTALL, [test "x$FATDIR" != "xnone"])
 186
 187 AC_SUBST(FATDIR)
 188
 189 AC_ARG_WITH(google-key, AS_HELP_STRING([--with-google-key=PATH],
 190             [Set the file to read the AltosDroid maps API key from (defaults to ~/altusmetrumllc/google-altosdroid-maps-api-key)]),
 191             [GOOGLEKEYFILE=$withval], [GOOGLEKEYFILE=$HOME/altusmetrumllc/google-altosdroid-maps-api-key])
 192
 193 if test -r "$GOOGLEKEYFILE" -a -s "$GOOGLEKEYFILE"; then
 194         GOOGLEKEY=`cat "$GOOGLEKEYFILE"`
 195         HAVE_GOOGLE_KEY="yes"
 196 else
 197         GOOGLEKEY='null'
 198         HAVE_GOOGLE_KEY="no"
 199 fi
 200
 201 WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs"
 202 AC_SUBST(WARN_CFLAGS)
 203
 204 AC_ARG_ENABLE(faketime, AS_HELP_STRING([--enable-faketime],
 205               [Use faketime program to ensure pdf files are reproducible (default=no)]),
 206               [FAKETIME=$enableval], [FAKETIME=no])
 207
 208 AM_CONDITIONAL(FAKETIME, [test x$FAKETIME = xyes])
 209
 210 AC_SUBST(GOOGLEKEY)
 211
 212 AC_PROG_CC
 213 AC_PROG_INSTALL
 214 AC_PROG_LN_S
 215 AC_PROG_LIBTOOL
 216 PKG_PROG_PKG_CONFIG
 217
 218 WARN_CFLAGS=""
 219 if test "x$GCC" = "xyes"; then
 220         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
 221         -Wmissing-prototypes -Wmissing-declarations \
 222         -Wnested-externs -fno-strict-aliasing"
 223         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
 224         [Can use #warning in C files])
 225 fi
 226 AC_SUBST(WARN_CFLAGS)
 227
 228 #
 229 # Configure ARM compiler for STM32L and LPC11U14
 230 #
 231
 232 AC_ARG_WITH([arm-cc],
 233             [AS_HELP_STRING([--with-arm-cc],
 234                             [Name of ARM C compiler])],
 235             [],
 236             [with_arm_cc=auto])
 237
 238 if test "x$with_arm_cc" != "xno"; then
 239         if test "x$with_arm_cc" = "xauto"; then
 240                 with_arm_cc="arm-none-eabi-gcc"
 241                 AC_CHECK_PROG([HAVE_ARM_CC],[$with_arm_cc], yes, no)
 242         else
 243                 HAVE_ARM_CC=yes
 244         fi
 245 else
 246         HAVE_ARM_CC=no
 247 fi
 248
 249 if test "x$HAVE_ARM_CC" = "xno"; then
 250         AC_MSG_WARN([Arm compiler not found, ARM binaries will not be built])
 251 else
 252         ARM_CC=$with_arm_cc
 253 fi
 254 AC_SUBST(HAVE_ARM_CC)
 255 AC_SUBST(ARM_CC)
 256
 257 if test "x$HAVE_ARM_CC" = "xyes"; then
 258         save_CC="$CC"
 259         save_CFLAGS="$CFLAGS"
 260         save_LIBS="$LIBS"
 261         CC="$ARM_CC"
 262         CFLAGS="-mthumb -mcpu=cortex-m0"
 263         LIBS="-ffreestanding -nostdlib"
 264         AC_LANG_PUSH([C])
 265
 266         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m0])
 267         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 268                           [HAVE_ARM_M0_CC=yes],
 269                           [HAVE_ARM_M0_CC=no])
 270         AC_MSG_RESULT([$HAVE_ARM_M0_CC])
 271
 272         CFLAGS="-mthumb -mcpu=cortex-m3"
 273         AC_MSG_CHECKING([if ]$ARM_CC[ supports cortex-m3])
 274         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int i;])],
 275                           [HAVE_ARM_M3_CC=yes],
 276                           [HAVE_ARM_M3_CC=no])
 277         AC_MSG_RESULT([$HAVE_ARM_M3_CC])
 278
 279         AC_LANG_POP([C])
 280         LIBS="$save_LIBS"
 281         CFLAGS="$save_CFLAGS"
 282         CC="$save_CC"
 283 else
 284         HAVE_ARM_M3_CC=no
 285         HAVE_ARM_M0_CC=no
 286 fi
 287 AC_SUBST(HAVE_ARM_M3_CC)
 288 AC_SUBST(HAVE_ARM_M0_CC)
 289
 290 if test "x$HAVE_ARM_M3_CC" = "xno"; then
 291         AC_MSG_WARN([No cortex-m3 arm compiler found, STM32L binaries will not be built])
 292 fi
 293
 294 if test "x$HAVE_ARM_M0_CC" = "xno"; then
 295         AC_MSG_WARN([No cortex-m0 arm compiler found, LPC11U14 binaries will not be built])
 296 fi
 297
 298 AC_ARG_WITH([newlib-nano],
 299             [AS_HELP_STRING([--with-newlib-nano],
 300                             [Root of newlib nano install])],
 301             [],
 302             [with_newlib_nano=auto])
 303
 304 HAVE_NEWLIB_NANO=no
 305 if test "x$with_newlib_nano" != "xno"; then
 306         if test "x$with_newlib_nano" = "xauto"; then
 307                 for d in /usr/local/lib/newlib-nano /usr/lib/newlib-nano; do
 308                         if test "x$with_newlib_nano" = "xauto" -a -d "$d"; then
 309                                 with_newlib_nano="$d"
 310                                 HAVE_NEWLIB_NANO=yes
 311                         fi
 312                 done
 313         else
 314                 HAVE_NEWLIB_NANO=yes
 315         fi
 316 fi
 317
 318 if test "x$HAVE_NEWLIB_NANO" = "xno"; then
 319         AC_MSG_WARN([No newlib-nano library found, ARM binaries will not be built])
 320         HAVE_ARM_M3_CC=no
 321         HAVE_ARM_M0_CC=no
 322 else
 323         NEWLIB_NANO="$with_newlib_nano"
 324 fi
 325
 326 AC_SUBST(HAVE_NEWLIB_NANO)
 327 AC_SUBST(NEWLIB_NANO)
 328
 329 #
 330 # Configure AVR compiler
 331 #
 332
 333 AC_ARG_WITH([avr-cc],
 334             [AS_HELP_STRING([--with-avr-cc],
 335                             [Name of AVR C compiler])],
 336             [],
 337             [with_avr_cc=auto])
 338
 339 if test "x$with_avr_cc" != "xno"; then
 340         if test "x$with_avr_cc" = "xauto"; then
 341                 with_avr_cc="avr-gcc"
 342                 AC_CHECK_PROG([HAVE_AVR_CC],[$with_avr_cc], yes, no)
 343         else
 344                 HAVE_AVR_CC=yes
 345         fi
 346 else
 347         HAVE_AVR_CC=no
 348 fi
 349
 350 AC_ARG_WITH([avr-objcopy],
 351             [AS_HELP_STRING([--with-avr-objcopy],
 352                             [Name of AVR objcopy])],
 353             [],
 354             [with_avr_objcopy=auto])
 355
 356 if test "x$with_avr_objcopy" != "xno"; then
 357         if test "x$with_avr_objcopy" = "xauto"; then
 358                 with_avr_objcopy="avr-objcopy"
 359                 AC_CHECK_PROG([HAVE_AVR_OBJCOPY],[$with_avr_objcopy], yes, no)
 360         else
 361                 HAVE_AVR_OBJCOPY=yes
 362         fi
 363 else
 364         HAVE_AVR_OBJCOPY=no
 365 fi
 366
 367 if test "x$HAVE_AVR_CC" = "xno" -o "x$HAVE_AVR_OBJCOPY" = "xno"; then
 368         AC_MSG_WARN([AVR compiler and objcopy not found, atmel binaries will not be built])
 369         HAVE_AVR_CC=no
 370 else
 371         save_CC="$CC"
 372         save_CFLAGS="$CFLAGS"
 373         save_LIBS="$LIBS"
 374
 375         CC="$with_avr_cc"
 376         CFLAGS="-mmcu=attiny85"
 377         AC_LANG_PUSH([C])
 378         AC_MSG_CHECKING([if ]$with_avr_cc[ can link programs])
 379         AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 380                           [AVR_LINK=yes],
 381                           [AVR_LINK=no])
 382         AC_MSG_RESULT([$AVR_LINK])
 383         AC_LANG_POP([C])
 384
 385         LIBS="$save_LIBS"
 386         CFLAGS="$save_CFLAGS"
 387         CC="$save_CC"
 388
 389         if test "x$AVR_LINK" = xyes; then
 390                 AVR_CC=$with_avr_cc
 391                 AVR_OBJCOPY=$with_avr_objcopy
 392         else
 393                 HAVE_AVR_CC=no;
 394         fi
 395 fi
 396
 397 AC_SUBST(AVR_CC)
 398 AC_SUBST(AVR_OBJCOPY)
 399 AC_SUBST(HAVE_AVR_CC)
 400
 401 AC_CHECK_PROG([HAVE_NICKLE], [nickle], yes, no)
 402 if test "x$HAVE_NICKLE" = "xno"; then
 403         AC_MSG_ERROR([Please install nickle to build AltOs])
 404 fi
 405
 406 AC_CHECK_PROG([HAVE_ASCIIDOCTOR_PDF], [asciidoctor-pdf], yes, no)
 407 if test "x$HAVE_ASCIIDOCTOR_PDF" = "xno"; then
 408         AC_MSG_WARN([asciidoctor-pdf not found, PDF docs will not be built])
 409 fi
 410 AM_CONDITIONAL([ASCIIDOCTOR_PDF], [test x$HAVE_ASCIIDOCTOR_PDF != xno])
 411
 412 AC_ARG_WITH([strip-nondeterminism],
 413             [AS_HELP_STRING([--with-strip-nondeterminism],
 414                             [Name of non-deterministic build data stripping tool])],
 415             [],
 416             [with_strip_nondeterminism=auto])
 417
 418 if test "x$with_strip_nondeterminism" != "xno"; then
 419         if test "x$with_strip_nondeterminism" = "xauto"; then
 420                 with_strip_nondeterminism="strip-nondeterminism"
 421                 AC_CHECK_PROG([HAVE_STRIP_NONDETERMINISM],[$with_strip_nondeterminism], yes, no)
 422         else
 423                 HAVE_STRIP_NONDETERMINISM=yes
 424         fi
 425 else
 426         HAVE_STRIP_NONDETERMINISM=no
 427 fi
 428 AM_CONDITIONAL([STRIP_NONDETERMINISM], [test x$HAVE_STRIP_NONDETERMINISM != xno])
 429 AC_SUBST(STRIP_NONDETERMINISM, "$with_strip_nondeterminism")
 430
 431 PKG_CHECK_MODULES([JANSSON], [jansson])
 432
 433 AC_ARG_WITH([readline],
 434             [AS_HELP_STRING([--with-readline],
 435                               [enable readline functionality in ao-dbg @<:@default=auto@:>@])],
 436               [],
 437               [with_readline=auto])
 438
 439 LIBREADLINE_LIBS=
 440
 441 if test x"$with_readline" != "xno"; then
 442         AC_CHECK_LIB([readline], [main],
 443                       [AC_SUBST([LIBREADLINE], ["-lreadline -lncurses"])
 444                        AC_DEFINE([HAVE_LIBREADLINE], [1],
 445                          [Define if you have libreadline])],
 446                       [if test "x$with_readline" != xauto; then
 447                          AC_MSG_ERROR([--with-readline was given, but test for readline failed])
 448                        fi],
 449                        -lncurses)
 450 fi
 451
 452 PKG_CHECK_MODULES([LIBUSB], [libusb-1.0])
 453
 454 AC_CHECK_HEADERS(libelf.h libelf/libelf.h, [break])
 455 AC_CHECK_HEADERS(gelf.h libelf/gelf.h, [break])
 456
 457 AC_ARG_WITH([stlink],
 458             [AS_HELP_STRING([--with-stlink],
 459                             [Build tools that use the stlink library (default: auto)])],
 460             [],
 461             [with_stlink=auto])
 462
 463 if test x"$with_stlink" != "xno"; then
 464         PKG_CHECK_MODULES([STLINK], [stlink], [HAVE_STLINK=yes], [HAVE_STLINK=no])
 465         if test x"$HAVE_STLINK" = "xno" -a x"$with_stlink" != "xauto"; then
 466                 AC_MSG_ERROR([--with-stlink was given, but stlink was not found])
 467         fi
 468 else
 469         HAVE_STLINK=no
 470 fi
 471
 472 if test x"$HAVE_STLINK" = "xyes"; then
 473         AC_DEFINE(HAVE_STLINK,1,[Using STlink library])
 474 fi
 475
 476 AM_CONDITIONAL([LIBSTLINK], [test x$HAVE_STLINK = xyes])
 477
 478 AC_ARG_ENABLE([multi-arch],
 479               [AS_HELP_STRING([--enable-multi-arch],
 480                               [enable building both i386 and amd64 libraries (default=auto)])],
 481               [MULTI_ARCH=$enableval],
 482               [MULTI_ARCH=auto])
 483
 484 case x"$MULTI_ARCH" in
 485 xauto)
 486         arch=`uname -m`
 487         case x"$arch" in
 488         xx86_64|xi*86)
 489                 save_CFLAGS="$CFLAGS"
 490                 save_LIBS="$LIBS"
 491                 LIBS="-ldl"
 492                 CFLAGS="-m64"
 493                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 494                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 495                                 [M64_LINK=yes],
 496                                 [M64_LINK=no])
 497                 AC_MSG_RESULT([$M64_LINK])
 498                 CFLAGS="-m32"
 499                 AC_MSG_CHECKING([if ]$CC[ ]$CFLAGS[ can link programs])
 500                 AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
 501                                 [M32_LINK=yes],
 502                                 [M32_LINK=no])
 503                 AC_MSG_RESULT([$M32_LINK])
 504                 CFLAGS="$save_CFLAGS"
 505                 LIBS="$save_LIBS"
 506                 case x"$M64_LINK"x"$M32_LINK" in
 507                 xyesxyes)
 508                         MULTI_ARCH=yes
 509                         ;;
 510                 *)
 511                         MULTI_ARCH=no
 512                         ;;
 513                 esac
 514                 ;;
 515         *)
 516                 MULTI_ARCH=no
 517                 ;;
 518         esac
 519         ;;
 520 xyes|xno)
 521         ;;
 522 *)
 523         MULTI_ARCH="no"
 524         ;;
 525 esac
 526
 527 AM_CONDITIONAL([MULTI_ARCH], [test x$MULTI_ARCH = xyes])
 528
 529 AC_ARG_ENABLE([install-shared-mime-info],
 530               [AS_HELP_STRING([--disable-install-shared-mime-info],
 531                               [disable installing shared mime info files (default=yes)])],
 532               [INSTALL_SHARED_MIME_INFO=$enableval],
 533               [INSTALL_SHARED_MIME_INFO=yes])
 534
 535 AM_CONDITIONAL([INSTALL_SHARED_MIME_INFO], [test x$INSTALL_SHARED_MIME_INFO = xyes])
 536
 537 AC_OUTPUT([
 538 Makefile
 539 src/Makedefs
 540 src/chaoskey-v1.0/org.altusmetrum.ChaosKey.metainfo.xml
 541 doc/Makefile
 542 altoslib/Makefile
 543 altoslib/AltosVersion.java
 544 icon/Makefile
 545 altosuilib/Makefile
 546 altosui/Makefile
 547 altosui/Info.plist
 548 altosui/altos-windows.nsi
 549 libaltos/Makefile
 550 micropeak/Makefile
 551 micropeak/Info.plist
 552 micropeak/micropeak-windows.nsi
 553 telegps/Makefile
 554 telegps/Info.plist
 555 telegps/telegps-windows.nsi
 556 altosdroid/Makefile
 557 altosdroid/local.properties
 558 altosdroid/app/src/main/AndroidManifest.xml
 559 ao-tools/Makefile
 560 ao-tools/lib/Makefile
 561 ao-tools/ao-rawload/Makefile
 562 ao-tools/ao-dbg/Makefile
 563 ao-tools/ao-bitbang/Makefile
 564 ao-tools/ao-eeprom/Makefile
 565 ao-tools/ao-list/Makefile
 566 ao-tools/ao-load/Makefile
 567 ao-tools/ao-telem/Makefile
 568 ao-tools/ao-stmload/Makefile
 569 ao-tools/ao-send-telem/Makefile
 570 ao-tools/ao-sky-flash/Makefile
 571 ao-tools/ao-dumpflash/Makefile
 572 ao-tools/ao-edit-telem/Makefile
 573 ao-tools/ao-dump-up/Makefile
 574 ao-tools/ao-elftohex/Makefile
 575 ao-tools/ao-usbload/Makefile
 576 ao-tools/ao-flash/Makefile
 577 ao-tools/ao-test-igniter/Makefile
 578 ao-tools/ao-test-baro/Makefile
 579 ao-tools/ao-test-flash/Makefile
 580 ao-tools/ao-cal-accel/Makefile
 581 ao-tools/ao-cal-freq/Makefile
 582 ao-tools/ao-test-gps/Makefile
 583 ao-tools/ao-usbtrng/Makefile
 584 ao-tools/ao-makebin/Makefile
 585 ao-utils/Makefile
 586 map-server/Makefile
 587 map-server/altos-mapd/Makefile
 588 map-server/altos-map/Makefile
 589 map-server/altos-mapj/Makefile
 590 ])
 591
 592 echo ""
 593 echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
 594 echo ""
 595 echo "  Configuration"
 596 echo "    Arm compiler................: ${ARM_CC}"
 597 echo "    STM32L support..............: ${HAVE_ARM_M3_CC}"
 598 echo "    LPC11U14 support............: ${HAVE_ARM_M0_CC}"
 599 echo "    AVR compiler................: ${AVR_CC} ${AVR_OBJCOPY}"
 600 echo "    AVR support.................: ${HAVE_AVR_CC}"
 601 echo "    Android support.............: ${HAVE_ANDROID_SDK}"
 602 echo "    Android release support.....: ${ANDROID_RELEASE}"
 603 echo "    STlink support..............: ${HAVE_STLINK}"
 604 echo "    Newlib-nano support.........: ${NEWLIB_NANO}"
 605 echo "    i386 and amd64 libaltos.....: ${MULTI_ARCH}"
 606 echo "    install shared mime info....: ${INSTALL_SHARED_MIME_INFO}"
 607 echo "    Strip jar timestamps........: ${STRIP_NONDETERMINISM}"
 608 echo ""
 609 echo "  Java"
 610 echo "    freetts.....................: ${FREETTS}"
 611 echo "    jfreechart..................: ${JFREECHART}"
 612 echo "    jcommon.....................: ${JCOMMON}"
 613 echo "    JVM include.................: ${JVM_INCLUDE}"
 614 echo "    AltosDroid maps API key.....: ${HAVE_GOOGLE_KEY}"
 615 if test x${ANDROID_SDK} != "xno"; then
 616 echo ""
 617 echo "  Android path"
 618 echo "    Android SDK.................: ${ANDROID_SDK}"
 619 fi
 620 echo ""