+
+#elif defined _MULLONG_ASM_LARGE
+
+void
+_mullong_dummy (void) _naked
+{
+ _asm
+
+ __mullong:
+ __mululong: ; obsolete
+ __mulslong: ; obsolete
+
+ .globl __mullong
+ .globl __mululong ; obsolete
+ .globl __mulslong ; obsolete
+
+ ; the result c will be stored in r4...r7
+ #define c0 r4
+ #define c1 r5
+ #define c2 r6
+ #define c3 r7
+
+ ; c0 a0 * b0
+ ; c1 a1 * b0 + a0 * b1
+ ; c2 a2 * b0 + a1 * b1 + a0 * b2
+ ; c3 a3 * b0 + a2 * b1 + a1 * b2 + a0 * b3
+
+ .area XSEG (XDATA)
+
+ __mullong_PARM_2:
+ __mululong_PARM_2: ; obsolete
+ __mulslong_PARM_2: ; obsolete
+
+ .globl __mullong_PARM_2
+ .globl __mululong_PARM_2 ; obsolete
+ .globl __mulslong_PARM_2 ; obsolete
+
+ .ds 4
+
+ .area CSEG (CODE)
+
+ ; parameter a comes in a, b, dph, dpl
+ mov r0,dpl ; save parameter a
+ mov r1,dph
+ mov r2,b
+ mov r3,a
+
+ #define a0 r0
+ #define a1 r1
+ #define a2 r2
+ #define a3 r3
+
+ ; Byte 0
+ mov b,a0
+ mov dptr,#__mullong_PARM_2
+ movx a,@dptr ; b0
+ mul ab ; a0 * b0
+ mov c0,a
+ mov c1,b
+
+ ; Byte 1
+ mov b,a1
+ movx a,@dptr ; b0
+ mul ab ; a1 * b0
+ add a,c1
+ mov c1,a
+ clr a
+ addc a,b
+ mov c2,a
+
+
+ mov b,a0
+ inc dptr ; b1
+ movx a,@dptr
+ mul ab ; a0 * b1
+ add a,c1
+ mov c1,a
+ mov a,b
+ addc a,c2
+ mov c2,a
+ clr a
+ rlc a
+ mov c3,a
+
+ ; Byte 2
+ mov b,a1
+ movx a,@dptr ; b1
+ mul ab ; a1 * b1
+ add a,c2
+ mov c2,a
+ mov a,b
+ addc a,c3
+ mov c3,a
+
+ mov b,a0
+ inc dptr ; b2
+ movx a,@dptr
+ mul ab ; a0 * b2
+ add a,c2
+ mov c2,a
+ mov a,b
+ addc a,c3
+ mov c3,a
+
+ mov b,a2
+ mov dptr,#__mullong_PARM_2
+ movx a,@dptr ; b0
+ mul ab ; a2 * b0
+ add a,c2
+ mov c2,a
+ mov a,b
+ addc a,c3
+ mov c3,a
+
+ ; Byte 3
+ mov b,a3
+ movx a,@dptr ; b0
+ mul ab ; a3 * b0
+ add a,c3
+ mov c3,a
+
+ mov b,a2
+ inc dptr ; b1
+ movx a,@dptr
+ mul ab ; a2 * b1
+ add a,c3
+ mov c3,a
+
+ mov b,a1
+ inc dptr ; b2
+ movx a,@dptr
+ mul ab ; a1 * b2
+ add a,c3
+ mov c3,a
+
+ mov b,a0
+ inc dptr ; b3
+ movx a,@dptr
+ mul ab ; a0 * b3
+ add a,c3
+
+ mov b,c2
+ mov dph,c1
+ mov dpl,c0
+ ret
+
+ _endasm ;
+}
+
+#else // _MULLONG_ASM