+/* Assembler-functions are provided for:
+ mcs51 small
+ mcs51 small stack-auto
+*/
+
+#include <stdbool.h>
+
+#if !defined(SDCC_USE_XSTACK) && !defined(_SDCC_NO_ASM_LIB_FUNCS)
+# if defined(SDCC_mcs51)
+# if defined(SDCC_MODEL_SMALL)
+# if defined(SDCC_STACK_AUTO)
+# define _DIVUINT_ASM_SMALL_AUTO
+# else
+# define _DIVUINT_ASM_SMALL
+# endif
+# endif
+# endif
+#endif
+
+#if defined _DIVUINT_ASM_SMALL || defined _DIVUINT_ASM_SMALL_AUTO
+
+static void
+_divuint_dummy (void) __naked
+{
+ __asm
+
+ .globl __divuint
+
+__divuint:
+
+ #define count r2
+ #define reste_l r3
+ #define reste_h r4
+ #define xl dpl
+ #define xh dph
+
+#if defined(SDCC_PARMS_IN_BANK1)
+ #define yl (b1_0)
+ #define yh (b1_1)
+#else // SDCC_PARMS_IN_BANK1
+ #if defined(SDCC_STACK_AUTO)
+
+ .globl __divint
+
+ mov a,sp
+ add a,#-2 ; 2 bytes return address
+ mov r0,a ; r0 points to yh
+ mov a,@r0 ; load yh
+ mov r1,a
+ dec r0
+ mov a,@r0 ; load yl
+ mov r0,a
+
+ #define yl r0
+ #define yh r1
+
+__divint: ; entry point for __divsint
+
+
+ #else // SDCC_STACK_AUTO
+
+ #if defined(SDCC_NOOVERLAY)
+ .area DSEG (DATA)
+ #else
+ .area OSEG (OVR,DATA)
+ #endif
+
+ .globl __divuint_PARM_2
+ .globl __divsint_PARM_2
+
+__divuint_PARM_2:
+__divsint_PARM_2:
+ .ds 2
+
+ .area CSEG (CODE)
+
+ #define yl (__divuint_PARM_2)
+ #define yh (__divuint_PARM_2 + 1)
+
+ #endif // SDCC_STACK_AUTO
+#endif // SDCC_PARMS_IN_BANK1
+
+ mov count,#16
+ clr a
+ mov reste_l,a
+ mov reste_h,a
+
+loop:
+ mov a,xl ; x <<= 1
+ add a,acc
+ mov xl,a
+ mov a,xh
+ rlc a
+ mov xh,a
+
+ mov a,reste_l ; reste <<= 1
+ rlc a ; feed in carry
+ mov reste_l,a
+ mov a,reste_h
+ rlc a
+ mov reste_h,a
+
+ mov a,reste_l ; reste - y
+ subb a,yl ; here carry is always clear, because
+ ; reste <<= 1 never overflows
+ mov b,a
+ mov a,reste_h
+ subb a,yh
+
+ jc smaller ; reste >= y?
+
+ mov reste_h,a ; -> yes; reste = reste - y;
+ mov reste_l,b
+ orl xl,#1
+smaller: ; -> no
+ djnz count,loop
+ ret
+
+ __endasm;
+}
+
+#else // defined _DIVUINT_ASM_SMALL || defined _DIVUINT_ASM_SMALL_AUTO
+