git.gag.com Git - fw/openocd/blob - testing/examples/STR912Test/prj/str912_rom.ld

   1 /***********************************************************************************\r
   2 *       Copyright 2005 Anglia Design\r
   3 *       This demo code and associated components are provided as is and has no warranty,\r
   4 *       implied or otherwise.  You are free to use/modify any of the provided\r
   5 *       code at your own risk in your applications with the expressed limitation\r
   6 *       of liability (see below)\r
   7 * \r
   8 *       LIMITATION OF LIABILITY:   ANGLIA OR ANGLIA DESIGNS SHALL NOT BE LIABLE FOR ANY\r
   9 *       LOSS OF PROFITS, LOSS OF USE, LOSS OF DATA, INTERRUPTION OF BUSINESS, NOR FOR\r
  10 *       INDIRECT, SPECIAL, INCIDENTAL OR CONSEQUENTIAL DAMAGES OF ANY KIND WHETHER UNDER\r
  11 *       THIS AGREEMENT OR OTHERWISE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGES.\r
  12 *\r
  13 *       Author                  : Spencer Oliver\r
  14 *       Web                     : www.anglia-designs.com\r
  15 *\r
  16 ***********************************************************************************/\r
  17 \r
  18 /* Stack Sizes */\r
  19 \r
  20         _STACKSIZE     = 1024;\r
  21         _STACKSIZE_IRQ = 256;\r
  22         _STACKSIZE_FIQ = 0;\r
  23         _STACKSIZE_SVC = 1024;\r
  24         _STACKSIZE_ABT = 0;\r
  25         _STACKSIZE_UND = 0;\r
  26         _HEAPSIZE      = 1024;\r
  27 \r
  28 /* Memory Definitions */\r
  29 \r
  30 MEMORY\r
  31 {\r
  32         CODE (rx) : ORIGIN = 0x00000000, LENGTH = 0x00080000\r
  33         DATA (rw) : ORIGIN = 0x04000000, LENGTH = 0x00018000\r
  34 }\r
  35 \r
  36 /* Section Definitions */\r
  37 \r
  38 SECTIONS\r
  39 {\r
  40         /* first section is .text which is used for code */\r
  41 \r
  42         .text :\r
  43         {\r
  44                 CREATE_OBJECT_SYMBOLS\r
  45                 KEEP(*(.vectors))\r
  46                 KEEP(*(.init))\r
  47                 *(.text .text.*)\r
  48                 *(.gnu.linkonce.t.*)\r
  49                 *(.glue_7t) *(.glue_7) *(.vfp11_veneer)\r
  50                 KEEP(*(.fini))\r
  51                 *(.gcc_except_table)\r
  52         } >CODE =0\r
  53         . = ALIGN(4);\r
  54 \r
  55         /* .ctors .dtors are used for c++ constructors/destructors */\r
  56         \r
  57         .ctors :\r
  58         {\r
  59                 PROVIDE(__ctors_start__ = .);\r
  60                 KEEP(*(SORT(.ctors.*)))\r
  61                 KEEP(*(.ctors))\r
  62                 PROVIDE(__ctors_end__ = .);\r
  63         } >CODE\r
  64 \r
  65         .dtors :\r
  66         {\r
  67                 PROVIDE(__dtors_start__ = .); \r
  68                 KEEP(*(SORT(.dtors.*)))\r
  69                 KEEP(*(.dtors))\r
  70                 PROVIDE(__dtors_end__ = .);\r
  71         } >CODE\r
  72         \r
  73         /* .rodata section which is used for read-only data (constants) */\r
  74 \r
  75         .rodata :\r
  76         {\r
  77                 *(.rodata .rodata.*)\r
  78                 *(.gnu.linkonce.r.*)\r
  79         } >CODE\r
  80         . = ALIGN(4);\r
  81 \r
  82         .init_array :\r
  83         {\r
  84                 *(.init)\r
  85         *(.fini)\r
  86                 PROVIDE_HIDDEN (__preinit_array_start = .);\r
  87                 KEEP (*(.preinit_array))\r
  88                 PROVIDE_HIDDEN (__preinit_array_end = .);\r
  89                 PROVIDE_HIDDEN (__init_array_start = .);\r
  90                 KEEP (*(SORT(.init_array.*)))\r
  91                 KEEP (*(.init_array))\r
  92                 PROVIDE_HIDDEN (__init_array_end = .);\r
  93                 PROVIDE_HIDDEN (__fini_array_start = .);\r
  94                 KEEP (*(.fini_array))\r
  95                 KEEP (*(SORT(.fini_array.*)))\r
  96                 PROVIDE_HIDDEN (__fini_array_end = .);\r
  97         } >CODE\r
  98 \r
  99         . = ALIGN(4);\r
 100 \r
 101         /* .ARM.exidx is sorted, so has to go in its own output section.  */\r
 102         __exidx_start = .;\r
 103         .ARM.exidx :\r
 104         {\r
 105                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)\r
 106         } >CODE\r
 107         __exidx_end = .;\r
 108 \r
 109         _etext = .;\r
 110         PROVIDE (etext = .);\r
 111 \r
 112         /* .data section which is used for initialized data */\r
 113 \r
 114         .data : AT (_etext)\r
 115         {\r
 116                 __data_start = .;\r
 117                 *(.data .data.*)\r
 118                 *(.gnu.linkonce.d.*)\r
 119                 SORT(CONSTRUCTORS)\r
 120                 . = ALIGN(4);\r
 121                 *(.fastrun .fastrun.*)\r
 122         } >DATA\r
 123         . = ALIGN(4);\r
 124         \r
 125         _edata = .;\r
 126         PROVIDE (edata = .);\r
 127 \r
 128         /* .bss section which is used for uninitialized data */\r
 129 \r
 130         .bss :\r
 131         {\r
 132                 __bss_start = .;\r
 133                 __bss_start__ = .;\r
 134                 *(.bss .bss.*)\r
 135                 *(.gnu.linkonce.b.*)\r
 136                 *(COMMON)\r
 137                 . = ALIGN(4);\r
 138         } >DATA\r
 139         . = ALIGN(4);\r
 140         __bss_end__ = .;\r
 141         \r
 142         _end = .;\r
 143         PROVIDE(end = .);\r
 144 \r
 145         /* .heap section which is used for memory allocation */\r
 146         \r
 147         .heap (NOLOAD) :\r
 148         {\r
 149                 __heap_start__ = .;\r
 150                 *(.heap)\r
 151                 . = MAX(__heap_start__ + _HEAPSIZE , .);\r
 152         } >DATA\r
 153         __heap_end__ = __heap_start__ + SIZEOF(.heap);\r
 154         \r
 155         /* .stack section - user mode stack */\r
 156         \r
 157         .stack (__heap_end__ + 3) / 4 * 4 (NOLOAD) :\r
 158         {\r
 159                 __stack_start__ = .;\r
 160                 *(.stack)\r
 161                 . = MAX(__stack_start__ + _STACKSIZE , .);\r
 162         } >DATA\r
 163         __stack_end__ = __stack_start__ + SIZEOF(.stack);\r
 164 \r
 165         /* .stack_irq section */\r
 166         \r
 167         .stack_irq (__stack_end__ + 3) / 4 * 4 (NOLOAD) :\r
 168         {\r
 169                 __stack_irq_start__ = .;\r
 170                 *(.stack_irq)\r
 171                 . = MAX(__stack_irq_start__ + _STACKSIZE_IRQ , .);\r
 172         } >DATA\r
 173         __stack_irq_end__ = __stack_irq_start__ + SIZEOF(.stack_irq);\r
 174 \r
 175         /* .stack_fiq section */\r
 176         \r
 177         .stack_fiq (__stack_irq_end__ + 3) / 4 * 4 (NOLOAD) :\r
 178         {\r
 179                 __stack_fiq_start__ = .;\r
 180                 *(.stack_fiq)\r
 181             . = MAX(__stack_fiq_start__ + _STACKSIZE_FIQ , .);\r
 182         } >DATA\r
 183         __stack_fiq_end__ = __stack_fiq_start__ + SIZEOF(.stack_fiq);\r
 184 \r
 185         /* .stack_svc section */\r
 186         \r
 187         .stack_svc (__stack_fiq_end__ + 3) / 4 * 4 (NOLOAD) :\r
 188         {\r
 189                 __stack_svc_start__ = .;\r
 190                 *(.stack_svc)\r
 191                 . = MAX(__stack_svc_start__ + _STACKSIZE_SVC , .);\r
 192         } >DATA\r
 193         __stack_svc_end__ = __stack_svc_start__ + SIZEOF(.stack_svc);\r
 194 \r
 195         /* .stack_abt section */\r
 196         \r
 197         .stack_abt (__stack_svc_end__ + 3) / 4 * 4 (NOLOAD) :\r
 198         {\r
 199                 __stack_abt_start__ = .;\r
 200                 *(.stack_abt)\r
 201                 . = MAX(__stack_abt_start__ + _STACKSIZE_ABT , .);\r
 202         } >DATA\r
 203         __stack_abt_end__ = __stack_abt_start__ + SIZEOF(.stack_abt);\r
 204 \r
 205         /* .stack_und section */\r
 206         \r
 207         .stack_und (__stack_abt_end__ + 3) / 4 * 4 (NOLOAD) :\r
 208         {\r
 209                 __stack_und_start__ = .;\r
 210                 *(.stack_und)\r
 211         . = MAX(__stack_und_start__ + _STACKSIZE_UND , .);\r
 212         } >DATA\r
 213         __stack_und_end__ = __stack_und_start__ + SIZEOF(.stack_und);\r
 214   \r
 215         /* Stabs debugging sections.  */\r
 216         .stab          0 : { *(.stab) }\r
 217         .stabstr       0 : { *(.stabstr) }\r
 218         .stab.excl     0 : { *(.stab.excl) }\r
 219         .stab.exclstr  0 : { *(.stab.exclstr) }\r
 220         .stab.index    0 : { *(.stab.index) }\r
 221         .stab.indexstr 0 : { *(.stab.indexstr) }\r
 222         .comment       0 : { *(.comment) }\r
 223         /* DWARF debug sections.\r
 224                 Symbols in the DWARF debugging sections are relative to the beginning\r
 225                 of the section so we begin them at 0.  */\r
 226         /* DWARF 1 */\r
 227         .debug          0 : { *(.debug) }\r
 228         .line           0 : { *(.line) }\r
 229         /* GNU DWARF 1 extensions */\r
 230         .debug_srcinfo  0 : { *(.debug_srcinfo) }\r
 231         .debug_sfnames  0 : { *(.debug_sfnames) }\r
 232         /* DWARF 1.1 and DWARF 2 */\r
 233         .debug_aranges  0 : { *(.debug_aranges) }\r
 234         .debug_pubnames 0 : { *(.debug_pubnames) }\r
 235         /* DWARF 2 */\r
 236         .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }\r
 237         .debug_abbrev   0 : { *(.debug_abbrev) }\r
 238         .debug_line     0 : { *(.debug_line) }\r
 239         .debug_frame    0 : { *(.debug_frame) }\r
 240         .debug_str      0 : { *(.debug_str) }\r
 241         .debug_loc      0 : { *(.debug_loc) }\r
 242         .debug_macinfo  0 : { *(.debug_macinfo) }\r
 243         /* SGI/MIPS DWARF 2 extensions */\r
 244         .debug_weaknames 0 : { *(.debug_weaknames) }\r
 245         .debug_funcnames 0 : { *(.debug_funcnames) }\r
 246         .debug_typenames 0 : { *(.debug_typenames) }\r
 247         .debug_varnames  0 : { *(.debug_varnames) }     \r
 248 }\r
 249 \r