git.gag.com Git - fw/sdcc/blob - support/scripts/sdcc.nsi

   1 # sdcc.nsi - NSIS installer script for SDCC
   2 #
   3 # Copyright (c) 2003-2006 Borut Razem
   4 #
   5 # This file is part of sdcc.
   6 #
   7 #  This software is provided 'as-is', without any express or implied
   8 #  warranty.  In no event will the authors be held liable for any damages
   9 #  arising from the use of this software.
  10 #
  11 #  Permission is granted to anyone to use this software for any purpose,
  12 #  including commercial applications, and to alter it and redistribute it
  13 #  freely, subject to the following restrictions:
  14 #
  15 #  1. The origin of this software must not be misrepresented; you must not
  16 #     claim that you wrote the original software. If you use this software
  17 #     in a product, an acknowledgment in the product documentation would be
  18 #     appreciated but is not required.
  19 #  2. Altered source versions must be plainly marked as such, and must not be
  20 #     misrepresented as being the original software.
  21 #  3. This notice may not be removed or altered from any source distribution.
  22 #
  23 #  Borut Razem
  24 #  borut.razem@siol.net
  25
  26 # How to create WIN32 setup.exe
  27 #
  28 # - unpack WIN32 mingw daily snapshot sdcc-snapshot-i586-mingw32msvc-yyyymmdd.zip
  29 #   to a clean directory (the option to create directories should be enabled).
  30 #   A sub directory sdcc is created (referenced as PKGDIR in continuation).
  31 # - copy files sdcc/support/scripts/sdcc.ico and sdcc/support/scripts/sdcc.nsi
  32 #   (this file) from the sdcc Subversion snapshot to the PKGDIR directory
  33 # - copy file COPYING from the sdcc Subversion snapshot to the PKGDIR directory,
  34 #   rename it to COPYING.TXT and convert file COPYING to DOS format:
  35 #   unix2dos COPYING.TXT
  36 # - run NSIS installer from PKGDIR directory:
  37 #   "c:\Program Files\NSIS\makensis.exe" sdcc.nsi
  38 # - A setup file setup.exe is created in PKGDIR directory.
  39 #   Rename it to sdcc_yyyymmdd_setup.exe and upload it
  40 #   to sdcc download repository at sourceforge.net
  41 #
  42 #
  43 # How to upload secc setup.exe tosourceforge.net
  44 #
  45 # Execute following commands from the cmd prompt:
  46 # - sftp sdcc.sourceforge.net
  47 # - cd /home/groups/s/sd/sdcc/htdocs/snapshots/i586-mingw32msvc-setup
  48 # - put sdcc_yyyymmdd_setup.exe
  49 # - quit
  50
  51
  52 !include "MUI.nsh"
  53
  54 SetCompressor /SOLID lzma
  55
  56 !define SDCC_ROOT "."
  57
  58 !define DEV_ROOT "${SDCC_ROOT}"
  59
  60 !system "unix2dos ${SDCC_ROOT}\doc\ChangeLog_head.txt" = 0
  61 !system "unix2dos ${SDCC_ROOT}\doc\README.TXT" = 0
  62
  63 InstType "Full (Bin, ucSim, SDCDB, Doc, Lib, Src)"
  64 InstType "Medium (Bin, ucSim, SDCDB, Doc, Lib)"
  65 InstType "Compact (Bin, ucSim, SDCDB, Doc)"
  66
  67 ;--------------------------------
  68 ;Variables
  69
  70 Var MUI_STARTMENUPAGE_VARIABLE
  71
  72 ;--------------------------------
  73 !define MUI_ABORTWARNING
  74
  75 !insertmacro MUI_PAGE_WELCOME
  76 !insertmacro MUI_PAGE_LICENSE "${SDCC_ROOT}\COPYING.TXT"
  77 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "SDCC"
  78 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKLM"
  79 !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC"
  80 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "NSIS:StartMenuDir"
  81 !define MUI_STARTMENUPAGE_NODISABLE
  82 !insertmacro MUI_PAGE_STARTMENU Application $MUI_STARTMENUPAGE_VARIABLE
  83 !insertmacro MUI_PAGE_COMPONENTS
  84 !insertmacro MUI_PAGE_DIRECTORY
  85 !insertmacro MUI_PAGE_INSTFILES
  86 !insertmacro MUI_PAGE_FINISH
  87
  88 !insertmacro MUI_UNPAGE_INSTFILES
  89
  90 !insertmacro MUI_LANGUAGE "English"
  91
  92 Name "SDCC"
  93 BrandingText ""
  94 OutFile "setup.exe"
  95 InstallDir "$PROGRAMFILES\SDCC"
  96 ShowInstDetails show
  97 ShowUnInstDetails show
  98
  99 Function .onInit
 100   ;Uninstall the old version, if present
 101   ReadRegStr $R0 HKLM \
 102   "Software\Microsoft\Windows\CurrentVersion\Uninstall\$(^Name)" \
 103   "UninstallString"
 104   StrCmp $R0 "" inst
 105
 106   MessageBox MB_OKCANCEL|MB_ICONEXCLAMATION \
 107   "$(^Name) is already installed. $\n$\nClick 'OK' to remove the \
 108   previous version or 'Cancel' to cancel this upgrade." \
 109   IDOK uninst
 110   Abort
 111
 112 uninst:
 113   ; Run the uninstaller
 114   ClearErrors
 115   ExecWait '$R0 _?=$INSTDIR' ;Do not copy the uninstaller to a temp file
 116
 117   ;IfErrors no_remove_uninstaller
 118   ;  ;You can either use Delete /REBOOTOK in the uninstaller or add some code
 119   ;  ;here to remove to remove the uninstaller. Use a registry key to check
 120   ;  ;whether the user has chosen to uninstall. If you are using an uninstaller
 121   ;  ;components page, make sure all sections are uninstalled.
 122   ;no_remove_uninstaller:
 123
 124   Goto done
 125 inst:
 126
 127   ; Install the new version
 128   MessageBox MB_YESNO|MB_ICONQUESTION "This will install $(^Name). Do you wish to continue?" IDYES +2
 129   Abort
 130
 131 done:
 132 FunctionEnd
 133
 134 Section -Common
 135   SetOutPath "$INSTDIR"
 136   File ".\sdcc.ico"
 137   File "${SDCC_ROOT}\COPYING.TXT"
 138 SectionEnd
 139
 140 Section "SDCC application files"
 141   SectionIn 1 2 3 RO
 142   SetOutPath "$INSTDIR\bin"
 143   File "${SDCC_ROOT}\bin\as-gbz80.exe"
 144   File "${SDCC_ROOT}\bin\as-hc08.exe"
 145   File "${SDCC_ROOT}\bin\as-z80.exe"
 146   File "${SDCC_ROOT}\bin\asx8051.exe"
 147   File "${SDCC_ROOT}\bin\aslink.exe"
 148   File "${SDCC_ROOT}\bin\link-gbz80.exe"
 149   File "${SDCC_ROOT}\bin\link-hc08.exe"
 150   File "${SDCC_ROOT}\bin\link-z80.exe"
 151   File "${SDCC_ROOT}\bin\makebin.exe"
 152   File "${SDCC_ROOT}\bin\packihx.exe"
 153   File "${SDCC_ROOT}\bin\sdcc.exe"
 154   File "${SDCC_ROOT}\bin\sdcclib.exe"
 155   File "${SDCC_ROOT}\bin\sdcpp.exe"
 156 SectionEnd
 157
 158 Section "ucSim application files"
 159   SectionIn 1 2 3
 160   SetOutPath "$INSTDIR\bin"
 161   File "${SDCC_ROOT}\bin\s51.exe"
 162   File "${SDCC_ROOT}\bin\savr.exe"
 163   File "${SDCC_ROOT}\bin\shc08.exe"
 164   File "${SDCC_ROOT}\bin\sz80.exe"
 165 SectionEnd
 166
 167 Section "SDCDB files"
 168   SectionIn 1 2 3
 169   File "${SDCC_ROOT}\bin\sdcdb.exe"
 170   File "${SDCC_ROOT}\bin\sdcdb.el"
 171   File "${SDCC_ROOT}\bin\sdcdbsrc.el"
 172 SectionEnd
 173
 174 Section "SDCC documentation"
 175   SectionIn 1 2 3
 176   SetOutPath "$INSTDIR\doc"
 177 !ifdef FULL_DOC
 178   File /r "${SDCC_ROOT}\doc\*"
 179 !else
 180   File "${SDCC_ROOT}\doc\ChangeLog_head.txt"
 181   File "${SDCC_ROOT}\doc\README.TXT"
 182 !endif
 183 SectionEnd
 184
 185 Section "SDCC include files"
 186   SectionIn 1 2
 187   SetOutPath "$INSTDIR\include\asm\default"
 188   File "${DEV_ROOT}\include\asm\default\features.h"
 189   SetOutPath "$INSTDIR\include\asm\ds390"
 190   File "${DEV_ROOT}\include\asm\ds390\features.h"
 191   SetOutPath "$INSTDIR\include\asm\gbz80"
 192   File "${DEV_ROOT}\include\asm\gbz80\features.h"
 193   SetOutPath "$INSTDIR\include\asm\mcs51"
 194   File "${DEV_ROOT}\include\asm\mcs51\features.h"
 195   SetOutPath "$INSTDIR\include\asm\pic"
 196   File "${DEV_ROOT}\include\asm\pic\features.h"
 197   SetOutPath "$INSTDIR\include\asm\pic16"
 198   File "${DEV_ROOT}\include\asm\pic16\features.h"
 199   SetOutPath "$INSTDIR\include\asm\z80"
 200   File "${DEV_ROOT}\include\asm\z80\features.h"
 201   SetOutPath "$INSTDIR\include\hc08"
 202   File "${DEV_ROOT}\include\hc08\*.h"
 203   SetOutPath "$INSTDIR\include\mcs51"
 204   File "${DEV_ROOT}\include\mcs51\*.h"
 205   SetOutPath "$INSTDIR\include\pic"
 206   File "${DEV_ROOT}\include\pic\*.h"
 207   File "${DEV_ROOT}\include\pic\*.txt"
 208   File "${DEV_ROOT}\include\pic\*.inc"
 209   SetOutPath "$INSTDIR\include\pic16"
 210   File "${DEV_ROOT}\include\pic16\*.h"
 211   SetOutPath "$INSTDIR\include\z80"
 212   File "${DEV_ROOT}\include\z80\*.h"
 213   SetOutPath "$INSTDIR\include"
 214   File "${DEV_ROOT}\include\*.h"
 215 SectionEnd
 216
 217 Section "SDCC DS390 library"
 218   SectionIn 1 2
 219   SetOutPath "$INSTDIR\lib\ds390"
 220   File "${DEV_ROOT}\lib\ds390\*.rel"
 221   File "${DEV_ROOT}\lib\ds390\*.lib"
 222 SectionEnd
 223
 224 Section "SDCC DS400 library"
 225   SectionIn 1 2
 226   SetOutPath "$INSTDIR\lib\ds400"
 227   File "${DEV_ROOT}\lib\ds400\*.rel"
 228   File "${DEV_ROOT}\lib\ds400\*.lib"
 229 SectionEnd
 230
 231 Section "SDCC GBZ80 library"
 232   SectionIn 1 2
 233   SetOutPath "$INSTDIR\lib\gbz80"
 234   File "${DEV_ROOT}\lib\gbz80\*.o"
 235   File "${DEV_ROOT}\lib\gbz80\*.lib"
 236 SectionEnd
 237
 238 Section "SDCC Z80 library"
 239   SectionIn 1 2
 240   SetOutPath "$INSTDIR\lib\z80"
 241   File "${DEV_ROOT}\lib\z80\*.o"
 242   File "${DEV_ROOT}\lib\z80\*.lib"
 243 SectionEnd
 244
 245 Section "SDCC small model library"
 246   SectionIn 1 2
 247   SetOutPath "$INSTDIR\lib\small"
 248   File "${DEV_ROOT}\lib\small\*.rel"
 249   File "${DEV_ROOT}\lib\small\*.lib"
 250 SectionEnd
 251
 252 Section "SDCC medium model library"
 253   SectionIn 1 2
 254   SetOutPath "$INSTDIR\lib\medium"
 255   File "${DEV_ROOT}\lib\medium\*.rel"
 256   File "${DEV_ROOT}\lib\medium\*.lib"
 257 SectionEnd
 258
 259 Section "SDCC large model library"
 260   SectionIn 1 2
 261   SetOutPath "$INSTDIR\lib\large"
 262   File "${DEV_ROOT}\lib\large\*.rel"
 263   File "${DEV_ROOT}\lib\large\*.lib"
 264 SectionEnd
 265
 266 Section "SDCC small-stack-auto model library"
 267   SectionIn 1 2
 268   SetOutPath "$INSTDIR\lib\small-stack-auto"
 269   File "${DEV_ROOT}\lib\small-stack-auto\*.rel"
 270   File "${DEV_ROOT}\lib\small-stack-auto\*.lib"
 271 SectionEnd
 272
 273 Section "SDCC HC08 library"
 274   SectionIn 1 2
 275   SetOutPath "$INSTDIR\lib\hc08"
 276   File "${DEV_ROOT}\lib\hc08\*.rel"
 277   File "${DEV_ROOT}\lib\hc08\*.lib"
 278 SectionEnd
 279
 280 Section "SDCC PIC16 library"
 281   SectionIn 1 2
 282   SetOutPath "$INSTDIR\lib\pic16"
 283   File "${DEV_ROOT}\lib\pic16\*.o"
 284   File "${DEV_ROOT}\lib\pic16\*.lib"
 285 SectionEnd
 286
 287 Section "SDCC PIC library"
 288   SectionIn 1 2
 289   SetOutPath "$INSTDIR\lib\pic"
 290   File "${DEV_ROOT}\lib\pic\*.lib"
 291 SectionEnd
 292
 293 Section "SDCC library sources"
 294   SectionIn 1
 295   SetOutPath "$INSTDIR\lib\src\ds390\examples"
 296   File "${DEV_ROOT}\lib\src\ds390\examples\MOVED"
 297
 298   SetOutPath "$INSTDIR\lib\src\ds390"
 299   File "${DEV_ROOT}\lib\src\ds390\*.c"
 300 #  File "${DEV_ROOT}\lib\src\ds390\Makefile"
 301
 302   SetOutPath "$INSTDIR\lib\src\ds400"
 303   File "${DEV_ROOT}\lib\src\ds400\*.c"
 304 #  File "${DEV_ROOT}\lib\src\ds400\Makefile"
 305
 306   SetOutPath "$INSTDIR\lib\src\gbz80"
 307   File "${DEV_ROOT}\lib\src\gbz80\*.c"
 308   File "${DEV_ROOT}\lib\src\gbz80\*.s"
 309 #  File "${DEV_ROOT}\lib\src\gbz80\Makefile"
 310
 311   SetOutPath "$INSTDIR\lib\src\z80"
 312   File "${DEV_ROOT}\lib\src\z80\*.c"
 313   File "${DEV_ROOT}\lib\src\z80\*.s"
 314 #  File "${DEV_ROOT}\lib\src\z80\Makefile"
 315
 316   SetOutPath "$INSTDIR\lib\src\hc08"
 317   File "${DEV_ROOT}\lib\src\hc08\*.c"
 318 #  File "${DEV_ROOT}\lib\src\hc08\Makefile"
 319
 320   SetOutPath "$INSTDIR\lib\src\mcs51"
 321   File "${DEV_ROOT}\lib\src\mcs51\*.asm"
 322 #  File "${DEV_ROOT}\lib\src\mcs51\Makefile"
 323
 324   SetOutPath "$INSTDIR\lib\src\small"
 325 #  File "${DEV_ROOT}\lib\src\small\Makefile"
 326
 327   SetOutPath "$INSTDIR\lib\src\medium"
 328 #  File "${DEV_ROOT}\lib\src\medium\Makefile"
 329
 330   SetOutPath "$INSTDIR\lib\src\large"
 331 #  File "${DEV_ROOT}\lib\src\large\Makefile"
 332
 333   SetOutPath "$INSTDIR\lib\src\pic"
 334 #  File "${DEV_ROOT}\lib\src\pic\configure"
 335 #  File "${DEV_ROOT}\lib\src\pic\configure.in"
 336 #  File "${DEV_ROOT}\lib\src\pic\GPL"
 337 #  File "${DEV_ROOT}\lib\src\pic\LGPL"
 338 #  File "${DEV_ROOT}\lib\src\pic\Makefile"
 339 #  File "${DEV_ROOT}\lib\src\pic\Makefile.common"
 340 #  File "${DEV_ROOT}\lib\src\pic\Makefile.common.in"
 341 #  File "${DEV_ROOT}\lib\src\pic\Makefile.rules"
 342 #  File "${DEV_ROOT}\lib\src\pic\Makefile.subdir"
 343 #  File "${DEV_ROOT}\lib\src\pic\NEWS"
 344 #  File "${DEV_ROOT}\lib\src\pic\README"
 345   File "${DEV_ROOT}\lib\src\pic\TEMPLATE.c"
 346   File "${DEV_ROOT}\lib\src\pic\TEMPLATE.S"
 347
 348   SetOutPath "$INSTDIR\lib\src\pic\libsdcc"
 349   File "${DEV_ROOT}\lib\src\pic\libsdcc\*.c"
 350   File "${DEV_ROOT}\lib\src\pic\libsdcc\*.S"
 351   File "${DEV_ROOT}\lib\src\pic\libsdcc\*.inc"
 352 #  File "${DEV_ROOT}\lib\src\pic\libsdcc\Makefile"
 353
 354   SetOutPath "$INSTDIR\lib\src\pic\libdev"
 355   File "${DEV_ROOT}\lib\src\pic\libdev\*.c"
 356 #  File "${DEV_ROOT}\lib\src\pic\libdev\Makefile"
 357
 358   SetOutPath "$INSTDIR\lib\src\pic\libm"
 359   File "${DEV_ROOT}\lib\src\pic\libm\*.c"
 360
 361   SetOutPath "$INSTDIR\lib\src\pic16"
 362 #  File "${DEV_ROOT}\lib\src\pic16\configure"
 363 #  File "${DEV_ROOT}\lib\src\pic16\configure.in"
 364 #  File "${DEV_ROOT}\lib\src\pic16\COPYING"
 365 #  File "${DEV_ROOT}\lib\src\pic16\Makefile"
 366 #  File "${DEV_ROOT}\lib\src\pic16\Makefile.common"
 367 #  File "${DEV_ROOT}\lib\src\pic16\Makefile.common.in"
 368 #  File "${DEV_ROOT}\lib\src\pic16\Makefile.rules"
 369 #  File "${DEV_ROOT}\lib\src\pic16\Makefile.subdir"
 370 #  File "${DEV_ROOT}\lib\src\pic16\pics.all"
 371 #  File "${DEV_ROOT}\lib\src\pic16\pics.build"
 372 #  File "${DEV_ROOT}\lib\src\pic16\README"
 373
 374   SetOutPath "$INSTDIR\lib\src\pic16\debug"
 375 #  File "${DEV_ROOT}\lib\src\pic16\debug\Makefile"
 376
 377   SetOutPath "$INSTDIR\lib\src\pic16\debug\gstack"
 378 #  File "${DEV_ROOT}\lib\src\pic16\debug\gstack\Makefile"
 379   File "${DEV_ROOT}\lib\src\pic16\debug\gstack\*.c"
 380
 381   SetOutPath "$INSTDIR\lib\src\pic16\libc"
 382 #  File "${DEV_ROOT}\lib\src\pic16\libc\Makefile"
 383
 384   SetOutPath "$INSTDIR\lib\src\pic16\libc\ctype"
 385   File "${DEV_ROOT}\lib\src\pic16\libc\ctype\*.c"
 386 #  File "${DEV_ROOT}\lib\src\pic16\libc\ctype\Makefile"
 387
 388   SetOutPath "$INSTDIR\lib\src\pic16\libc\delay"
 389   File "${DEV_ROOT}\lib\src\pic16\libc\delay\*.S"
 390 #  File "${DEV_ROOT}\lib\src\pic16\libc\delay\Makefile"
 391
 392   SetOutPath "$INSTDIR\lib\src\pic16\libc\stdio"
 393   File "${DEV_ROOT}\lib\src\pic16\libc\stdio\*.c"
 394 #  File "${DEV_ROOT}\lib\src\pic16\libc\stdio\Makefile"
 395
 396   SetOutPath "$INSTDIR\lib\src\pic16\libc\stdlib"
 397   File "${DEV_ROOT}\lib\src\pic16\libc\stdlib\*.c"
 398   File "${DEV_ROOT}\lib\src\pic16\libc\stdlib\*.S"
 399 #  File "${DEV_ROOT}\lib\src\pic16\libc\stdlib\Makefile"
 400
 401   SetOutPath "$INSTDIR\lib\src\pic16\libc\string"
 402   File "${DEV_ROOT}\lib\src\pic16\libc\string\*.c"
 403 #  File "${DEV_ROOT}\lib\src\pic16\libc\string\Makefile"
 404
 405   SetOutPath "$INSTDIR\lib\src\pic16\libc\utils"
 406   File "${DEV_ROOT}\lib\src\pic16\libc\utils\*.S"
 407 #  File "${DEV_ROOT}\lib\src\pic16\libc\utils\Makefile"
 408
 409   SetOutPath "$INSTDIR\lib\src\pic16\libdev"
 410   File "${DEV_ROOT}\lib\src\pic16\libdev\*.c"
 411 #  File "${DEV_ROOT}\lib\src\pic16\libdev\Makefile"
 412
 413   SetOutPath "$INSTDIR\lib\src\pic16\libio"
 414   File "${DEV_ROOT}\lib\src\pic16\libio\*.ignore"
 415 #  File "${DEV_ROOT}\lib\src\pic16\libio\Makefile"
 416
 417   SetOutPath "$INSTDIR\lib\src\pic16\libio\adc"
 418   File "${DEV_ROOT}\lib\src\pic16\libio\adc\*.c"
 419 #  File "${DEV_ROOT}\lib\src\pic16\libio\adc\Makefile"
 420
 421   SetOutPath "$INSTDIR\lib\src\pic16\libio\i2c"
 422   File "${DEV_ROOT}\lib\src\pic16\libio\i2c\*.c"
 423 #  File "${DEV_ROOT}\lib\src\pic16\libio\i2c\Makefile"
 424
 425   SetOutPath "$INSTDIR\lib\src\pic16\libio\usart"
 426   File "${DEV_ROOT}\lib\src\pic16\libio\usart\*.c"
 427 #  File "${DEV_ROOT}\lib\src\pic16\libio\usart\Makefile"
 428
 429   SetOutPath "$INSTDIR\lib\src\pic16\libm"
 430   File "${DEV_ROOT}\lib\src\pic16\libm\*.c"
 431 #  File "${DEV_ROOT}\lib\src\pic16\libm\Makefile"
 432
 433   SetOutPath "$INSTDIR\lib\src\pic16\libsdcc"
 434 #  File "${DEV_ROOT}\lib\src\pic16\libsdcc\Makefile"
 435
 436   SetOutPath "$INSTDIR\lib\src\pic16\libsdcc\char"
 437   File "${DEV_ROOT}\lib\src\pic16\libsdcc\char\*.c"
 438 #  File "${DEV_ROOT}\lib\src\pic16\libsdcc\char\Makefile"
 439
 440   SetOutPath "$INSTDIR\lib\src\pic16\libsdcc\fixed16x16"
 441   File "${DEV_ROOT}\lib\src\pic16\libsdcc\fixed16x16\*.c"
 442   File "${DEV_ROOT}\lib\src\pic16\libsdcc\fixed16x16\*.S"
 443 #  File "${DEV_ROOT}\lib\src\pic16\libsdcc\fixed16x16\Makefile"
 444
 445   SetOutPath "$INSTDIR\lib\src\pic16\libsdcc\float"
 446   File "${DEV_ROOT}\lib\src\pic16\libsdcc\float\*.c"
 447 #  File "${DEV_ROOT}\lib\src\pic16\libsdcc\float\Makefile"
 448
 449   SetOutPath "$INSTDIR\lib\src\pic16\libsdcc\gptr"
 450   File "${DEV_ROOT}\lib\src\pic16\libsdcc\gptr\*.c"
 451 #  File "${DEV_ROOT}\lib\src\pic16\libsdcc\gptr\Makefile"
 452
 453   SetOutPath "$INSTDIR\lib\src\pic16\libsdcc\int"
 454   File "${DEV_ROOT}\lib\src\pic16\libsdcc\int\*.c"
 455 #  File "${DEV_ROOT}\lib\src\pic16\libsdcc\int\Makefile"
 456
 457   SetOutPath "$INSTDIR\lib\src\pic16\libsdcc\long"
 458   File "${DEV_ROOT}\lib\src\pic16\libsdcc\long\*.c"
 459 #  File "${DEV_ROOT}\lib\src\pic16\libsdcc\long\Makefile"
 460
 461   SetOutPath "$INSTDIR\lib\src\pic16\libsdcc\lregs"
 462   File "${DEV_ROOT}\lib\src\pic16\libsdcc\lregs\*.c"
 463 #  File "${DEV_ROOT}\lib\src\pic16\libsdcc\lregs\Makefile"
 464
 465   SetOutPath "$INSTDIR\lib\src\pic16\libsdcc\stack"
 466   File "${DEV_ROOT}\lib\src\pic16\libsdcc\stack\*.S"
 467
 468   SetOutPath "$INSTDIR\lib\src\pic16\startup"
 469   File "${DEV_ROOT}\lib\src\pic16\startup\*.c"
 470 #  File "${DEV_ROOT}\lib\src\pic16\startup\Makefile"
 471 #  File "${DEV_ROOT}\lib\src\pic16\startup\README"
 472
 473   SetOutPath "$INSTDIR\lib\src"
 474   File "${DEV_ROOT}\lib\src\*.c"
 475 SectionEnd
 476
 477 Section -Icons
 478 !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 479   CreateDirectory "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE"
 480   CreateShortCut "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\SDCC on the Web.lnk" "$INSTDIR\sdcc.url"
 481   CreateShortCut "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\Uninstall SDCC.lnk" "$INSTDIR\uninstall.exe"
 482   CreateShortCut "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\Documentation.lnk" "$INSTDIR\doc\README.TXT" "" "$INSTDIR\sdcc.ico" "" "" "" ""
 483   CreateShortCut "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\Change Log.lnk" "$INSTDIR\doc\ChangeLog_head.txt" "" "$INSTDIR\sdcc.ico" "" "" "" ""
 484   CreateShortCut "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\GPL 2 License.lnk" "$INSTDIR\COPYING.TXT"
 485 !insertmacro MUI_STARTMENU_WRITE_END
 486 SectionEnd
 487
 488 Section -INI
 489   WriteIniStr "$INSTDIR\sdcc.url" "InternetShortcut" "URL" "http://sdcc.sourceforge.net/"
 490 SectionEnd
 491
 492 Section -PostInstall
 493   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC" "DisplayName" "SDCC"
 494   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC" "UninstallString" "$INSTDIR\uninstall.exe"
 495   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC" "Publisher" "sdcc.sourceforge.net"
 496   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC" "URLInfoAbout" "http://sdcc.sourceforge.net/"
 497   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC" "HelpLink" "http://sdcc.sourceforge.net/"
 498   WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC" "URLUpdateInfo" "http://sdcc.sourceforge.net/"
 499   WriteUninstaller "$INSTDIR\uninstall.exe"
 500 SectionEnd
 501
 502 Section -AddToPath
 503   MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "Do you want to add $INSTDIR\bin to the PATH?" IDNO +3
 504     Push "$INSTDIR\bin"
 505     Call AddToPath
 506 SectionEnd
 507
 508
 509 ;;;; Uninstaller code ;;;;
 510
 511 Function un.onInit
 512   MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "Are you sure you want to completely remove $(^Name) and all of its components?" IDYES +2
 513   Abort
 514 FunctionEnd
 515
 516 Function un.onUninstSuccess
 517   HideWindow
 518   MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) was successfully removed from your computer."
 519 FunctionEnd
 520
 521 Section Uninstall
 522   !insertmacro MUI_STARTMENU_GETFOLDER Application $MUI_STARTMENUPAGE_VARIABLE
 523
 524   Delete "$INSTDIR\sdcc.url"
 525
 526   DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC" "NSIS:StartMenuDir"
 527   DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\SDCC"
 528
 529   Delete "$INSTDIR\uninstall.exe"
 530   Delete "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\GPL 2 License.lnk"
 531   Delete "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\Change Log.lnk"
 532   Delete "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\Documentation.lnk"
 533   Delete "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\Uninstall SDCC.lnk"
 534   Delete "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE\SDCC on the Web.lnk"
 535
 536   Delete "$INSTDIR\lib\src\large\Makefile"
 537
 538   Delete "$INSTDIR\lib\src\medium\Makefile"
 539
 540   Delete "$INSTDIR\lib\src\small\Makefile"
 541
 542   Delete "$INSTDIR\lib\src\mcs51\*.asm"
 543   Delete "$INSTDIR\lib\src\mcs51\Makefile"
 544   Delete "$INSTDIR\lib\src\mcs51\README"
 545
 546   Delete "$INSTDIR\lib\src\hc08\*.c"
 547   Delete "$INSTDIR\lib\src\hc08\hc08.lib"
 548   Delete "$INSTDIR\lib\src\hc08\Makefile"
 549
 550   Delete "$INSTDIR\lib\src\z80\*.c"
 551   Delete "$INSTDIR\lib\src\z80\*.s"
 552   Delete "$INSTDIR\lib\src\z80\z80.lib"
 553   Delete "$INSTDIR\lib\src\z80\README"
 554   Delete "$INSTDIR\lib\src\z80\Makefile"
 555
 556   Delete "$INSTDIR\lib\src\gbz80\*.c"
 557   Delete "$INSTDIR\lib\src\gbz80\*.s"
 558   Delete "$INSTDIR\lib\src\gbz80\gbz80.lib"
 559   Delete "$INSTDIR\lib\src\gbz80\README"
 560   Delete "$INSTDIR\lib\src\gbz80\Makefile"
 561
 562   Delete "$INSTDIR\lib\src\ds390\*.c"
 563   Delete "$INSTDIR\lib\src\ds390\libds390.lib"
 564   Delete "$INSTDIR\lib\src\ds390\Makefile.dep"
 565   Delete "$INSTDIR\lib\src\ds390\Makefile"
 566   Delete "$INSTDIR\lib\src\ds390\examples\MOVED"
 567
 568   Delete "$INSTDIR\lib\src\ds400\*.c"
 569   Delete "$INSTDIR\lib\src\ds400\libds400.lib"
 570   Delete "$INSTDIR\lib\src\ds400\Makefile.dep"
 571   Delete "$INSTDIR\lib\src\ds400\Makefile"
 572
 573   Delete "$INSTDIR\lib\src\*.c"
 574
 575   Delete "$INSTDIR\lib\pic\*.o"
 576   Delete "$INSTDIR\lib\pic\*.lib"
 577
 578   Delete "$INSTDIR\lib\pic16\*.o"
 579   Delete "$INSTDIR\lib\pic16\*.lib"
 580
 581   Delete "$INSTDIR\lib\hc08\*.rel"
 582   Delete "$INSTDIR\lib\hc08\*.lib"
 583
 584   Delete "$INSTDIR\lib\z80\*.o"
 585   Delete "$INSTDIR\lib\z80\*.lib"
 586
 587   Delete "$INSTDIR\lib\small\*.rel"
 588   Delete "$INSTDIR\lib\small\*.lib"
 589
 590   Delete "$INSTDIR\lib\medium\*.rel"
 591   Delete "$INSTDIR\lib\medium\*.lib"
 592
 593   Delete "$INSTDIR\lib\large\*.rel"
 594   Delete "$INSTDIR\lib\large\*.lib"
 595
 596   Delete "$INSTDIR\lib\small-stack-auto\*.rel"
 597   Delete "$INSTDIR\lib\small-stack-auto\*.lib"
 598
 599   Delete "$INSTDIR\lib\gbz80\*.o"
 600   Delete "$INSTDIR\lib\gbz80\*.lib"
 601
 602   Delete "$INSTDIR\lib\ds390\*.rel"
 603   Delete "$INSTDIR\lib\ds390\*.lib"
 604
 605   Delete "$INSTDIR\lib\ds400\*.rel"
 606   Delete "$INSTDIR\lib\ds400\*.lib"
 607
 608   Delete "$INSTDIR\include\asm\z80\*.h"
 609   Delete "$INSTDIR\include\asm\pic16\*.h"
 610   Delete "$INSTDIR\include\asm\pic\*.h"
 611   Delete "$INSTDIR\include\asm\mcs51\*.h"
 612   Delete "$INSTDIR\include\asm\gbz80\*.h"
 613   Delete "$INSTDIR\include\asm\ds390\*.h"
 614   Delete "$INSTDIR\include\asm\default\*.h"
 615   Delete "$INSTDIR\include\z80\*.h"
 616   Delete "$INSTDIR\include\pic\*.h"
 617   Delete "$INSTDIR\include\pic\*.txt"
 618   Delete "$INSTDIR\include\pic\*.inc"
 619   Delete "$INSTDIR\include\pic16\*.h"
 620   Delete "$INSTDIR\include\mcs51\*.h"
 621   Delete "$INSTDIR\include\hc08\*.h"
 622   Delete "$INSTDIR\include\*.h"
 623
 624 !ifndef FULL_DOC
 625   Delete "$INSTDIR\doc\README.TXT"
 626   Delete "$INSTDIR\doc\ChangeLog_head.txt"
 627 !endif
 628
 629   Delete "$INSTDIR\bin\*.exe"
 630
 631   Delete "$INSTDIR\COPYING.TXT"
 632   Delete "$INSTDIR\sdcc.ico"
 633
 634   RMDir "$SMPROGRAMS\$MUI_STARTMENUPAGE_VARIABLE"
 635
 636   RMDir /r "$INSTDIR\lib\src\pic"
 637   RMDir /r "$INSTDIR\lib\src\pic16"
 638   RMDir "$INSTDIR\lib\src\small"
 639   RMDir "$INSTDIR\lib\src\medium"
 640   RMDir "$INSTDIR\lib\src\large"
 641   RMDir "$INSTDIR\lib\src\mcs51"
 642   RMDir "$INSTDIR\lib\src\z80"
 643   RMDir "$INSTDIR\lib\src\gbz80"
 644   RMDir "$INSTDIR\lib\src\ds390\examples"
 645   RMDir "$INSTDIR\lib\src\ds390"
 646   RMDir "$INSTDIR\lib\src\ds400"
 647   RMDir "$INSTDIR\lib\src\hc08"
 648   RMDir "$INSTDIR\lib\src"
 649
 650   RMDir "$INSTDIR\lib\pic"
 651   RMDir "$INSTDIR\lib\pic16"
 652   RMDir "$INSTDIR\lib\z80"
 653   RMDir "$INSTDIR\lib\small"
 654   RMDir "$INSTDIR\lib\medium"
 655   RMDir "$INSTDIR\lib\large"
 656   RMDir "$INSTDIR\lib\small-stack-auto"
 657   RMDir "$INSTDIR\lib\gbz80"
 658   RMDir "$INSTDIR\lib\ds390"
 659   RMDir "$INSTDIR\lib\ds400"
 660   RMDir "$INSTDIR\lib\hc08"
 661   RMDir "$INSTDIR\lib"
 662
 663   RMDir "$INSTDIR\include\asm\z80"
 664   RMDir "$INSTDIR\include\asm\pic16"
 665   RMDir "$INSTDIR\include\asm\pic"
 666   RMDir "$INSTDIR\include\asm\mcs51"
 667   RMDir "$INSTDIR\include\asm\gbz80"
 668   RMDir "$INSTDIR\include\asm\ds390"
 669   RMDir "$INSTDIR\include\asm\default"
 670   RMDir "$INSTDIR\include\asm"
 671   RMDir "$INSTDIR\include\z80"
 672   RMDir "$INSTDIR\include\pic"
 673   RMDir "$INSTDIR\include\pic16"
 674   RMDir "$INSTDIR\include\mcs51"
 675   RMDir "$INSTDIR\include\hc08"
 676   RMDir "$INSTDIR\include"
 677
 678 !ifdef FULL_DOC
 679   RMDir /r "$INSTDIR\doc"
 680 !else
 681   RMDir "$INSTDIR\doc"
 682 !endif
 683
 684   RMDir "$INSTDIR\bin"
 685
 686   RMDir "$INSTDIR"
 687
 688   Push "$INSTDIR\bin"
 689   Call un.RemoveFromPath
 690
 691   SetAutoClose true
 692 SectionEnd
 693
 694 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 695 ; Path Manipulation functions                                                 ;
 696 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 697
 698 !verbose 3
 699 !include "WinMessages.nsh"
 700 !verbose 4
 701
 702 ; AddToPath - Adds the given dir to the search path.
 703 ;        Input - head of the stack
 704 ;        Note - Win9x systems requires reboot
 705
 706 Function AddToPath
 707   Exch $0
 708   Push $1
 709   Push $2
 710   Push $3
 711   Push $4
 712
 713   ; don't add if the path doesn't exist
 714   IfFileExists $0 "" AddToPath_done
 715
 716   Call IsNT
 717   Pop $4
 718   StrCmp $4 1 +3
 719     ; Not on NT: read PATH from environment variable
 720     ReadEnvStr $1 PATH
 721     Goto +2
 722     ; On NT: read PATH from registry
 723     ReadRegStr $1 HKCU "Environment" "PATH"
 724   Push "$1;"
 725   Push "$0;"
 726   Call StrStr
 727   Pop $2
 728   StrCmp $2 "" "" AddToPath_done
 729   Push "$1;"
 730   Push "$0\;"
 731   Call StrStr
 732   Pop $2
 733   StrCmp $2 "" "" AddToPath_done
 734   GetFullPathName /SHORT $3 $0
 735   Push "$1;"
 736   Push "$3;"
 737   Call StrStr
 738   Pop $2
 739   StrCmp $2 "" "" AddToPath_done
 740   Push "$1;"
 741   Push "$3\;"
 742   Call StrStr
 743   Pop $2
 744   StrCmp $2 "" "" AddToPath_done
 745
 746   StrCmp $4 1 AddToPath_NT
 747     ; Not on NT
 748     StrCpy $1 $WINDIR 2
 749     FileOpen $1 "$1\autoexec.bat" a
 750     FileSeek $1 -1 END
 751     FileReadByte $1 $2
 752     IntCmp $2 26 0 +2 +2 ; DOS EOF
 753       FileSeek $1 -1 END ; write over EOF
 754     FileWrite $1 "$\r$\nSET PATH=%PATH%;$3$\r$\n"
 755     FileClose $1
 756     SetRebootFlag true
 757     Goto AddToPath_done
 758
 759   AddToPath_NT:
 760     ReadRegStr $1 HKCU "Environment" "PATH"
 761     StrCpy $2 $1 1 -1  ; copy last char
 762     StrCmp $2 ";" 0 +2 ; if last char == ;
 763       StrCpy $1 $1 -1  ; remove last char
 764     StrCmp $1 "" AddToPath_NTdoIt
 765       StrCpy $0 "$1;$0"
 766     AddToPath_NTdoIt:
 767       WriteRegExpandStr HKCU "Environment" "PATH" $0
 768       SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000
 769
 770   AddToPath_done:
 771     Pop $4
 772     Pop $3
 773     Pop $2
 774     Pop $1
 775     Pop $0
 776 FunctionEnd
 777
 778 ; RemoveFromPath - Remove a given dir from the path
 779 ;     Input: head of the stack
 780
 781 Function un.RemoveFromPath
 782   Exch $0
 783   Push $1
 784   Push $2
 785   Push $3
 786   Push $4
 787   Push $5
 788   Push $6
 789
 790   IntFmt $6 "%c" 26 ; DOS EOF
 791
 792   Call un.IsNT
 793   Pop $1
 794   StrCmp $1 1 unRemoveFromPath_NT
 795     ; Not on NT
 796     StrCpy $1 $WINDIR 2
 797     FileOpen $1 "$1\autoexec.bat" r
 798     GetTempFileName $4
 799     FileOpen $2 $4 w
 800     GetFullPathName /SHORT $0 $0
 801     StrCpy $0 "SET PATH=%PATH%;$0"
 802     Goto unRemoveFromPath_dosLoop
 803
 804     unRemoveFromPath_dosLoop:
 805       FileRead $1 $3
 806       StrCpy $5 $3 1 -1 ; read last char
 807       StrCmp $5 $6 0 +2 ; if DOS EOF
 808         StrCpy $3 $3 -1 ; remove DOS EOF so we can compare
 809       StrCmp $3 "$0$\r$\n" unRemoveFromPath_dosLoopRemoveLine
 810       StrCmp $3 "$0$\n" unRemoveFromPath_dosLoopRemoveLine
 811       StrCmp $3 "$0" unRemoveFromPath_dosLoopRemoveLine
 812       StrCmp $3 "" unRemoveFromPath_dosLoopEnd
 813       FileWrite $2 $3
 814       Goto unRemoveFromPath_dosLoop
 815       unRemoveFromPath_dosLoopRemoveLine:
 816         SetRebootFlag true
 817         Goto unRemoveFromPath_dosLoop
 818
 819     unRemoveFromPath_dosLoopEnd:
 820       FileClose $2
 821       FileClose $1
 822       StrCpy $1 $WINDIR 2
 823       Delete "$1\autoexec.bat"
 824       CopyFiles /SILENT $4 "$1\autoexec.bat"
 825       Delete $4
 826       Goto unRemoveFromPath_done
 827
 828   unRemoveFromPath_NT:
 829     ReadRegStr $1 HKCU "Environment" "PATH"
 830     StrCpy $5 $1 1 -1 ; copy last char
 831     StrCmp $5 ";" +2  ; if last char != ;
 832       StrCpy $1 "$1;" ; append ;
 833     Push $1
 834     Push "$0;"
 835     Call un.StrStr    ; Find `$0;` in $1
 836     Pop $2            ; pos of our dir
 837     StrCmp $2 "" unRemoveFromPath_done
 838       ; else, it is in path
 839       ; $0 - path to add
 840       ; $1 - path var
 841       StrLen $3 "$0;"
 842       StrLen $4 $2
 843       StrCpy $5 $1 -$4   ; $5 is now the part before the path to remove
 844       StrCpy $6 $2 "" $3 ; $6 is now the part after the path to remove
 845       StrCpy $3 $5$6
 846
 847       StrCpy $5 $3 1 -1  ; copy last char
 848       StrCmp $5 ";" 0 +2 ; if last char == ;
 849         StrCpy $3 $3 -1  ; remove last char
 850
 851       StrCmp $3 "" +3
 852         ; New PATH not empty: update the registry
 853         WriteRegExpandStr HKCU "Environment" "PATH" $3
 854         Goto +2
 855         ; New PATH empty: remove from the registry
 856         DeleteRegValue HKCU "Environment" "PATH"
 857       SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000
 858
 859   unRemoveFromPath_done:
 860     Pop $6
 861     Pop $5
 862     Pop $4
 863     Pop $3
 864     Pop $2
 865     Pop $1
 866     Pop $0
 867 FunctionEnd
 868
 869 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 870 ;            Utility Functions            ;
 871 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 872
 873 ; IsNT
 874 ; no input
 875 ; output, top of the stack = 1 if NT or 0 if not
 876 ;
 877 ; Usage:
 878 ;   Call IsNT
 879 ;   Pop $R0
 880 ;  ($R0 at this point is 1 or 0)
 881
 882 !macro IsNT un
 883 Function ${un}IsNT
 884   Push $0
 885   ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" CurrentVersion
 886   StrCmp $0 "" 0 IsNT_yes
 887   ; we are not NT.
 888   Pop $0
 889   Push 0
 890   Return
 891
 892   IsNT_yes:
 893     ; NT!!!
 894     Pop $0
 895     Push 1
 896 FunctionEnd
 897 !macroend
 898 !insertmacro IsNT ""
 899 !insertmacro IsNT "un."
 900
 901 ; StrStr
 902 ; input, top of stack = string to search for
 903 ;        top of stack-1 = string to search in
 904 ; output, top of stack (replaces with the portion of the string remaining)
 905 ; modifies no other variables.
 906 ;
 907 ; Usage:
 908 ;   Push "this is a long ass string"
 909 ;   Push "ass"
 910 ;   Call StrStr
 911 ;   Pop $R0
 912 ;  ($R0 at this point is "ass string")
 913
 914 !macro StrStr un
 915 Function ${un}StrStr
 916 Exch $R1   ; st=haystack,old$R1, $R1=needle
 917   Exch     ; st=old$R1,haystack
 918   Exch $R2 ; st=old$R1,old$R2, $R2=haystack
 919   Push $R3
 920   Push $R4
 921   Push $R5
 922   StrLen $R3 $R1
 923   StrCpy $R4 0
 924   ; $R1=needle
 925   ; $R2=haystack
 926   ; $R3=len(needle)
 927   ; $R4=cnt
 928   ; $R5=tmp
 929   loop:
 930     StrCpy $R5 $R2 $R3 $R4
 931     StrCmp $R5 $R1 done
 932     StrCmp $R5 "" done
 933     IntOp $R4 $R4 + 1
 934     Goto loop
 935 done:
 936   StrCpy $R1 $R2 "" $R4
 937   Pop $R5
 938   Pop $R4
 939   Pop $R3
 940   Pop $R2
 941   Exch $R1
 942 FunctionEnd
 943 !macroend
 944 !insertmacro StrStr ""
 945 !insertmacro StrStr "un."