git.gag.com Git - fw/openocd/blob - src/flash/startup.tcl

   1 # Defines basic Tcl procs for OpenOCD flash module
   2
   3 #
   4 # program utility proc
   5 # usage: program filename
   6 # optional args: verify, reset, exit and address
   7 #
   8
   9 proc program_error {description exit} {
  10         if {$exit == 1} {
  11                 echo $description
  12                 shutdown error
  13         }
  14
  15         error $description
  16 }
  17
  18 proc program {filename args} {
  19         set exit 0
  20         set needsflash 1
  21
  22         foreach arg $args {
  23                 if {[string equal $arg "preverify"]} {
  24                         set preverify 1
  25                 } elseif {[string equal $arg "verify"]} {
  26                         set verify 1
  27                 } elseif {[string equal $arg "reset"]} {
  28                         set reset 1
  29                 } elseif {[string equal $arg "exit"]} {
  30                         set exit 1
  31                 } else {
  32                         set address $arg
  33                 }
  34         }
  35
  36         # Set variables
  37         set filename \{$filename\}
  38         if {[info exists address]} {
  39                 set flash_args "$filename $address"
  40         } else {
  41                 set flash_args "$filename"
  42         }
  43
  44
  45         # make sure init is called
  46         if {[catch {init}] != 0} {
  47                 program_error "** OpenOCD init failed **" 1
  48         }
  49
  50         # reset target and call any init scripts
  51         if {[catch {reset init}] != 0} {
  52                 program_error "** Unable to reset target **" $exit
  53         }
  54
  55         # Check whether programming is needed
  56         if {[info exists preverify]} {
  57                 echo "**pre-verifying**"
  58                 if {[catch {eval verify_image $flash_args}] == 0} {
  59                         echo "**Verified OK - No flashing**"
  60                         set needsflash 0
  61                 }
  62         }
  63
  64         # start programming phase
  65         if {$needsflash == 1} {
  66                 echo "** Programming Started **"
  67
  68                 if {[catch {eval flash write_image erase $flash_args}] == 0} {
  69                         echo "** Programming Finished **"
  70                         if {[info exists verify]} {
  71                                 # verify phase
  72                                 echo "** Verify Started **"
  73                                 if {[catch {eval verify_image $flash_args}] == 0} {
  74                                         echo "** Verified OK **"
  75                                 } else {
  76                                         program_error "** Verify Failed **" $exit
  77                                 }
  78                         }
  79                 } else {
  80                         program_error "** Programming Failed **" $exit
  81                 }
  82         }
  83
  84         if {[info exists reset]} {
  85                 # reset target if requested
  86                 if {$exit == 1} {
  87                         # also disable target polling, we are shutting down anyway
  88                         poll off
  89                 }
  90                 echo "** Resetting Target **"
  91                 reset run
  92         }
  93
  94
  95         if {$exit == 1} {
  96                 shutdown
  97         }
  98         return
  99 }
 100
 101 add_help_text program "write an image to flash, address is only required for binary images. verify, reset, exit are optional"
 102 add_usage_text program "<filename> \[address\] \[pre-verify\] \[verify\] \[reset\] \[exit\]"
 103
 104 # stm32[f0x|f3x] uses the same flash driver as the stm32f1x
 105 proc stm32f0x args { eval stm32f1x $args }
 106 proc stm32f3x args { eval stm32f1x $args }
 107
 108 # stm32[f4x|f7x] uses the same flash driver as the stm32f2x
 109 proc stm32f4x args { eval stm32f2x $args }
 110 proc stm32f7x args { eval stm32f2x $args }
 111
 112 # stm32lx driver supports both STM32 L0 and L1 devices
 113 proc stm32l0x args { eval stm32lx $args }
 114 proc stm32l1x args { eval stm32lx $args }
 115
 116 # stm32[g0|g4|wb|wl] uses the same flash driver as the stm32l4x
 117 proc stm32g0x args { eval stm32l4x $args }
 118 proc stm32g4x args { eval stm32l4x $args }
 119 proc stm32wbx args { eval stm32l4x $args }
 120 proc stm32wlx args { eval stm32l4x $args }
 121
 122 # ease migration to updated flash driver
 123 proc stm32x args {
 124         echo "DEPRECATED! use 'stm32f1x $args' not 'stm32x $args'"
 125         eval stm32f1x $args
 126 }
 127
 128 proc stm32f2xxx args {
 129         echo "DEPRECATED! use 'stm32f2x $args' not 'stm32f2xxx $args'"
 130         eval stm32f2x $args
 131 }