git.gag.com Git - fw/openocd/blob - src/flash/startup.tcl

   1 # SPDX-License-Identifier: GPL-2.0-or-later
   2
   3 # Defines basic Tcl procs for OpenOCD flash module
   4
   5 #
   6 # program utility proc
   7 # usage: program filename
   8 # optional args: verify, reset, exit and address
   9 #
  10
  11 lappend _telnet_autocomplete_skip program_error
  12 proc program_error {description exit} {
  13         if {$exit == 1} {
  14                 echo $description
  15                 shutdown error
  16         }
  17
  18         error $description
  19 }
  20
  21 proc program {filename args} {
  22         set exit 0
  23         set needsflash 1
  24
  25         foreach arg $args {
  26                 if {[string equal $arg "preverify"]} {
  27                         set preverify 1
  28                 } elseif {[string equal $arg "verify"]} {
  29                         set verify 1
  30                 } elseif {[string equal $arg "reset"]} {
  31                         set reset 1
  32                 } elseif {[string equal $arg "exit"]} {
  33                         set exit 1
  34                 } else {
  35                         set address $arg
  36                 }
  37         }
  38
  39         # Set variables
  40         set filename \{$filename\}
  41         if {[info exists address]} {
  42                 set flash_args "$filename $address"
  43         } else {
  44                 set flash_args "$filename"
  45         }
  46
  47
  48         # make sure init is called
  49         if {[catch {init}] != 0} {
  50                 program_error "** OpenOCD init failed **" 1
  51         }
  52
  53         # reset target and call any init scripts
  54         if {[catch {reset init}] != 0} {
  55                 program_error "** Unable to reset target **" $exit
  56         }
  57
  58         # Check whether programming is needed
  59         if {[info exists preverify]} {
  60                 echo "**pre-verifying**"
  61                 if {[catch {eval verify_image $flash_args}] == 0} {
  62                         echo "**Verified OK - No flashing**"
  63                         set needsflash 0
  64                 }
  65         }
  66
  67         # start programming phase
  68         if {$needsflash == 1} {
  69                 echo "** Programming Started **"
  70
  71                 if {[catch {eval flash write_image erase $flash_args}] == 0} {
  72                         echo "** Programming Finished **"
  73                         if {[info exists verify]} {
  74                                 # verify phase
  75                                 echo "** Verify Started **"
  76                                 if {[catch {eval verify_image $flash_args}] == 0} {
  77                                         echo "** Verified OK **"
  78                                 } else {
  79                                         program_error "** Verify Failed **" $exit
  80                                 }
  81                         }
  82                 } else {
  83                         program_error "** Programming Failed **" $exit
  84                 }
  85         }
  86
  87         if {[info exists reset]} {
  88                 # reset target if requested
  89                 if {$exit == 1} {
  90                         # also disable target polling, we are shutting down anyway
  91                         poll off
  92                 }
  93                 echo "** Resetting Target **"
  94                 reset run
  95         }
  96
  97
  98         if {$exit == 1} {
  99                 shutdown
 100         }
 101         return
 102 }
 103
 104 add_help_text program "write an image to flash, address is only required for binary images. verify, reset, exit are optional"
 105 add_usage_text program "<filename> \[address\] \[pre-verify\] \[verify\] \[reset\] \[exit\]"
 106
 107 # stm32[f0x|f3x] uses the same flash driver as the stm32f1x
 108 proc stm32f0x args { eval stm32f1x $args }
 109 proc stm32f3x args { eval stm32f1x $args }
 110
 111 # stm32[f4x|f7x] uses the same flash driver as the stm32f2x
 112 proc stm32f4x args { eval stm32f2x $args }
 113 proc stm32f7x args { eval stm32f2x $args }
 114
 115 # stm32lx driver supports both STM32 L0 and L1 devices
 116 proc stm32l0x args { eval stm32lx $args }
 117 proc stm32l1x args { eval stm32lx $args }
 118
 119 # stm32[g0|g4|l5|u5|wb|wl] uses the same flash driver as the stm32l4x
 120 proc stm32g0x args { eval stm32l4x $args }
 121 proc stm32g4x args { eval stm32l4x $args }
 122 proc stm32l5x args { eval stm32l4x $args }
 123 proc stm32u5x args { eval stm32l4x $args }
 124 proc stm32wbx args { eval stm32l4x $args }
 125 proc stm32wlx args { eval stm32l4x $args }
 126
 127 # gd32e23x uses the same flash driver as the stm32f1x
 128 proc gd32e23x args { eval stm32f1x $args }