git.gag.com Git - fw/openocd/blob - src/flash/ocl/at91sam7x/at91sam7x_ram.ld

   1 /****************************************************************************
   2 *  Copyright (c) 2006 by Michael Fischer. All rights reserved.
   3 *
   4 *  Redistribution and use in source and binary forms, with or without
   5 *  modification, are permitted provided that the following conditions
   6 *  are met:
   7 *
   8 *  1. Redistributions of source code must retain the above copyright
   9 *     notice, this list of conditions and the following disclaimer.
  10 *  2. Redistributions in binary form must reproduce the above copyright
  11 *     notice, this list of conditions and the following disclaimer in the
  12 *     documentation and/or other materials provided with the distribution.
  13 *  3. Neither the name of the author nor the names of its contributors may
  14 *     be used to endorse or promote products derived from this software
  15 *     without specific prior written permission.
  16 *
  17 *  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  18 *  "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  19 *  LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  20 *  FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL
  21 *  THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  22 *  INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
  23 *  BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
  24 *  OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  25 *  AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  26 *  OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF
  27 *  THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  28 *  SUCH DAMAGE.
  29 *
  30 ****************************************************************************
  31 *
  32 *  History:
  33 *
  34 *  30.03.06  mifi   First Version
  35 ****************************************************************************/
  36
  37
  38 ENTRY(ResetHandler)
  39 SEARCH_DIR(.)
  40
  41 /*
  42  * Define stack size here
  43  */
  44 FIQ_STACK_SIZE = 0x0100;
  45 IRQ_STACK_SIZE = 0x0100;
  46 ABT_STACK_SIZE = 0x0100;
  47 UND_STACK_SIZE = 0x0100;
  48 SVC_STACK_SIZE = 0x0100;
  49
  50
  51 MEMORY
  52 {
  53   ram : org = 0x00200000, len = 64k
  54 }
  55
  56 /*
  57  * Do not change the next code
  58  */
  59 SECTIONS
  60 {
  61   .text :
  62   {
  63     *(.vectors);
  64     . = ALIGN(4);
  65     *(.init);
  66     . = ALIGN(4);
  67     *(.text);
  68     . = ALIGN(4);
  69     *(.rodata);
  70     . = ALIGN(4);
  71     *(.rodata*);
  72     . = ALIGN(4);
  73     *(.glue_7t);
  74     . = ALIGN(4);
  75     *(.glue_7);
  76     . = ALIGN(4);
  77     etext = .;
  78   } > ram
  79
  80   .data :
  81   {
  82     PROVIDE (__data_start = .);
  83     *(.data)
  84     . = ALIGN(4);
  85     edata = .;
  86     _edata = .;
  87     PROVIDE (__data_end = .);
  88   } > ram
  89
  90   .bss :
  91   {
  92     PROVIDE (__bss_start = .);
  93     *(.bss)
  94     *(COMMON)
  95     . = ALIGN(4);
  96     PROVIDE (__bss_end = .);
  97
  98     . = ALIGN(256);
  99
 100     PROVIDE (__stack_start = .);
 101
 102     PROVIDE (__stack_fiq_start = .);
 103     . += FIQ_STACK_SIZE;
 104     . = ALIGN(4);
 105     PROVIDE (__stack_fiq_end = .);
 106
 107     PROVIDE (__stack_irq_start = .);
 108     . += IRQ_STACK_SIZE;
 109     . = ALIGN(4);
 110     PROVIDE (__stack_irq_end = .);
 111
 112     PROVIDE (__stack_abt_start = .);
 113     . += ABT_STACK_SIZE;
 114     . = ALIGN(4);
 115     PROVIDE (__stack_abt_end = .);
 116
 117     PROVIDE (__stack_und_start = .);
 118     . += UND_STACK_SIZE;
 119     . = ALIGN(4);
 120     PROVIDE (__stack_und_end = .);
 121
 122     PROVIDE (__stack_svc_start = .);
 123     . += SVC_STACK_SIZE;
 124     . = ALIGN(4);
 125     PROVIDE (__stack_svc_end = .);
 126     PROVIDE (__stack_end = .);
 127     PROVIDE (__heap_start = .);
 128   } > ram
 129
 130 }
 131 /*** EOF ***/
 132